Recopier une colonne de plusieurs dans un seul

[lmc71]

Bonjour à tous, le forum
Voici la macro ci-dessous me permet de recopier une colonne sélectionnée dans plusieurs fichiers, mais l'inconvénient elle recopie toutes les colonnes sélectionnées dans une seule colonne ligne après ligne.
Mon souhait serait que chaque colonne sélectionnée soit recopiée les unes à côté des autres à savoir : colonne B du fichier1, Col B fichier2,.... recopiées dans fichier Récup Colonne B,C,D,......
Je pense qu'il faille changer la ligne Range("c65256").End(xlUp).Offset(1, 0).Select , mais je n'ai pas trouvé comment modifier la macro

Merci de votre gentillesse.
Amicalement




Sub recup_Bellegarde_Colonne()
Range("c10").Select 'sélectionner la cellule de début
Chemin = "D:\cELINE HONORAIRES\Honoraires\Bellegarde\Colonne\" 'saisir le chemin complet du dossier où se trouvent les fichiers
Fichier = Dir(Chemin & "*.xls") ' Premier fichier
Do While Fichier <> ""
Workbooks.Open Filename:=Chemin & Fichier
Range("colonne").Copy
ThisWorkbook.Activate
Selection.PasteSpecial Paste:=xlPasteValues
Windows(Fichier).Activate
Application.CutCopyMode = False
ActiveWorkbook.Close savechanges:=False
ThisWorkbook.Activate
Range("c65256").End(xlUp).Offset(1, 0).Select
Fichier = Dir ' Fichier suivant
Loop
End Sub

 

[Dranreb]

Re : Recopier une colonne de plusieurs dans un seul

Bonjour.
Comme ça peut être :

Sub Recup_Bellegarde_Colonne()
Const Chemin = "D:\cELINE HONORAIRES\Honoraires\Bellegarde\Colonne" 'saisir le chemin complet du dossier où se trouvent les fichiers
Dim PlgCible As Range
ChDrive Chemin: ChDir Chemin ' Rend courant le chemin
Set PlgCible = ActiveSheet.[C6] ' Note la cellule cible de départ
Fichier = Dir("*.xls") ' Premier fichier
Do: Workbooks.Open Filename:=Fichier
   With Range("colonne"): PlgCible.Resize(.Rows.Count).Value = .Value: End With ' Copie valeurs
   ActiveWorkbook.Close savechanges:=False
   Fichier = Dir ' Fichier suivant
   If Fichier = "" Then Exit Do ' Sort si plus d'autre fichier
   Set PlgCible = PlgCible.Offset(, 1) ' Incrémente la colonne
   Loop
End Sub

À +

 

[lmc71]

Re : Recopier une colonne de plusieurs dans un seul

Bonjour,
Merci Dranreb pour ta rapidité de réponse.
Tout fonctionne à merveille 😱
Vous êtes quand même des Pro de la VBA
Un Grand Merci
Amicalement