recherchev et estvide

[VIARD]

Bonjour à toutes et tous

J'ai un petit souci.
C'est la première fois que j'utilise RECHERCHEV.
J'ai très bien compris son fonctionnement.
J'ai une matrice avec plein de trous (cellules vides), il faut bien commencer.
Les trous se combleront par la suite.

=SI(P6="";"";RECHERCHEV(P6;Tableau_Salarié;7;0))

Donc l'information en septième est vide, et RECHERCHEV me retourne "0", ce n'est pas présentable

Je préfère le vide complet donc rien "" ou "inconnu".

J'ai tenté d'utiliser ESTVIDE ou un deuxième SI sans succès.

Je ne vois pas l'utilité de joindre un fichier.

Et puis ce code est relativement court,

Merci par avance pour la solution.

Jean-Paul

 

[Bebere]

Re : recherchev et estvide

bonjour Viard

=SI(RECHERCHEV(P6;Tableau_Salarié;7;0)=0;"";RECHERCHEV(P6;Tableau_Salarié;7;0))

 

[Patrice33740]

Re : recherchev et estvide

Bonjour,

J'écrirais plutôt :
=SI(P6="";"";SI(ESTVIDE(RECHERCHEV(P6;Tableau_Salarié;7;0));""; RECHERCHEV(P6;Tableau_Salarié;7;0)))

si la cellule contient 0, ça donnera 0 et si elle est vide elle sera = ""

 

[VIARD]

Re : recherchev et estvide

Bonjour Bebere et Patrice33740

Je vous remercie tous deux.
je teste vos solutions et vous tiens au courant.

Merci d'avance

Jean-Paul

 

[chris]

Re : recherchev et estvide

Bonjour

Selon ce que doit renvoyer la RECHERCHE, il peut être nécessaire de laisser les 0 car si un calcul utilise la résultat cela ne marchera pas.

Il est très facile, de masquer les 0 dans Excel : soit sur tout un onglet (dans les options) soit par un format de nombre, soit par une mise en forme conditionnelle.

 

[VIARD]

Re : recherchev et estvide

Re bonjour à tous

-Bebere -- ta solution est intéressante j'y vois une utilité pour plus tard.
-Patrice à raison sa solution me convient tout à fait.

Pour répondre à Chris, j'utilise des données qui ne sont pas sujets à calcul.

Et merci encore de vous être intéressé au problème.

A+ Jean-Paul

 

[R@chid]

Re : recherchev et estvide

Bonjour @ tous,
Si ta RECHERCHEV() doit renvoyer des valeurs Textes, vaut mieux de supprimer les 0 par cette astuce :

=SI(P6="";"";RECHERCHEV(P6;Tableau_Salarié;7;0))&""

Mais je vois que tu ne gères pas les erreurs si on ne trouve pas la valeur en P6, alors il vaut mieux de faire :

=SIERREUR(RECHERCHEV(P6;Tableau_Salarié;7;0);"")&""

@ + +

 

[R@chid]

Re : recherchev et estvide

Re,

-Patrice à raison sa solution me convient tout à fait.

pardon je viens de me rendre compte de cette réponse, ceci dit que la RECHERCHEV() doit renvoyer des valeurs numériques, alors pourquoi ne pas faire plus courte :

=SIERREUR((RECHERCHEV(P6;Tableau_Salarié;7;0)&"")*1;"")

Si vide, ça renvoie vide
Si la cellule contient une valeur numérique, on l'obtiendra même les 0.



@ + +

 

[VIARD]

Re : recherchev et estvide

Bonjour R@chid

Très intéressant ces nouvelles solutions, je vais les tester demain.
D'un autre coté l'info en P6 est toujours présente, et la donnée récupérée en colonne,
peut-être texte ou numérique, c'est pourquoi si la cellule est vide il faut quelle le reste.

Je te remercie pour tes lumières

A+ Jean-Paul

 

[VIARD]

Re : recherchev et estvide

Bonjour Rachid
J’ai effectué une serie de teste sur ces formules
Finalement pour le numérique
=SIERREUR((RECHERCHEV(P6;Tableau_Salarié;7;0)&"")*1;"")
A condition que ce ne soit un N°téléphone comprenant des espaces.
Et pour le Texte :
=SI(P6="";"";RECHERCHEV(P6;Tableau_Salarié;10;0))&" "
Et pour du texte concaténé :
=SI(P6="";"";RECHERCHEV(P6;Tableau_Salarié;2;0))&" " &RECHERCHEV(P6;Tableau_Salarié;3;0)
Et pour un Texte vide (cellule) avec commentaire :
=SI(P6="";"";SI(ESTVIDE(RECHERCHEV(P6;Tableau_Salarié;2;0));"vide";RECHERCHEV(P6;Tableau_Salarié;2;0)))
Bon voilà
Si cela peut aider. Il y a encore d’autre façon de faire.
A+ Jean-Paul