Microsoft 365 recherche valeur supérieur à 0 mais la plus basse

radia · Hier à 15:58

Bonjour

Je cherche une formule pour sélectionner le moindre coût (meilleur tarif transporteur) mais supérieure à 0 car parfois un seul transporteur est utilisé sur certains départements donc il faut que je rapatrie le coût lié à ce transporteur . Est ce que c'est faisable ? L a recherche sera sur des colonnes différentes et non une plage directe. Merci par avance pour aide/idées

Cordialement
Radia

shinozak · Hier à 16:09

Salut,

mapomme · Hier à 16:24

Bonjour à tous,

Formule O365 : SIERREUR(MIN(FILTRE(B3:I3;(MOD(COLONNE(B3:I3)-COLONNE($C:$C);2)=0)*(B3:I3<>0)));"")

ALS35 · Hier à 16:37

Bonjour;
Une autre proposition Excel365, sur la base du fichier, en J3 :

VB:

=LET(t;CHOISIRCOLS(B3:I3;{2;4;6;8});SIERREUR(MIN(FILTRE(t;t>0));""))

Cordialement

radia · Hier à 17:22

ALS35 à dit:
Bonjour;
Une autre proposition Excel365, sur la base du fichier, en J3 :

VB:

=LET(t;CHOISIRCOLS(B3:I3;{2;4;6;8});SIERREUR(MIN(FILTRE(t;t>0));""))

Cordialement

Hello ALS35, merci pour ta réponse, je ne suis pas à l'aise avec VBA et je connaissais pas cette formule (LET) je l'ai introduite directement en formule excel (en anglais mais ça ne donne rien, je pense qu'il manque une étape..). Qu'est ce que représente le t. Pourriez vous me renvoyer le fichier avec la formule?

Merci beaucoup
Radia

radia · Hier à 17:25

mapomme à dit:
Bonjour à tous,

Formule O365 : SIERREUR(MIN(FILTRE(B3:I3;(MOD(COLONNE(B3:I3)-COLONNE($C:$C);2)=0)*(B3:I3<>0)));"")

Merci mapomme, je l'ai essayé mais ne marche pas, pourriez vous m erenvoyer le fichier avec la formule svp

Cordialement

radia · Hier à 17:28

shinozak à dit:
Salut,

Merci shinazak pour ta réponse , la formule inclut toutes le colonnes alors que je veux faire une recherche uniquement sur les colonnes (transporteur).
Cordialement
Radia

ALS35 · Hier à 17:30

Bonjour de nouveau,
Ci-joint fichier avec formule, ce n'est pas du vba mais des formules Excel 365.
La fonction CHOSIRCOLS ne prend que les 4 colonnes utiles de ta plage, la fonction LET permet de nommer cette nouvelle plage t, la fonction FILTRE, sur cette plage t, n'en prends que les valeurs >0 puis on prends le MIN
Cordialement

job75 · Hier à 17:40

Bonsoir le forum,

Chez moi sur Excel 2019 la fonction FILTRE n'existe pas.

Par ailleurs il peut y avoir des nombres >0 en D3 F3 H3.

Alors utilisez cette formule en J3 :

Code:

=MIN.SI.ENS(C3:I3;C3:I3;">0";C$1:I$1;"Cout")

A+
:

radia · Hier à 17:41

ALS35 à dit:
Bonjour de nouveau,
Ci-joint fichier avec formule, ce n'est pas du vba mais des formules Excel 365.
La fonction CHOSIRCOLS ne prend que les 4 colonnes utiles de ta plage, la fonction LET permet de nommer cette nouvelle plage t, la fonction FILTRE, sur cette plage t, n'en prends que les valeurs >0 puis on prends le MIN
Cordialement

SUPER MERCI BEAUCOUP

radia · Hier à 17:42

job75 à dit:
Bonsoir le forum,

Chez moi sur Excel 2019 la fonction FILTRE n'existe pas.

Par ailleurs il peut y avoir des nombres >0 en D3 F3 H3.

Alors utilisez cette formule en J3 :

Code:

=MIN.SI.ENS(C3:I3;C3:I3;">0";C$1:I$1;"Cout")

A+
:

Merci beaucoup pour votre aide

radia · Hier à 17:43

mapomme à dit:
Bonjour à tous,

Formule O365 : SIERREUR(MIN(FILTRE(B3:I3;(MOD(COLONNE(B3:I3)-COLONNE($C:$C);2)=0)*(B3:I3<>0)));"")

Finalement ça marche, juste une question de traduction, mon excel est en anglais) Merci beaucoup

job75 · Hier à 19:55

Une autre solution avec cette formule matricielle en J3 :

Code:

=MIN(SI(C3:I3*EST.IMPAIR(COLONNE(C3:I3));C3:I3))

Sur Excel 2019 elle doit être validée par Ctrl+Maj+Entrée.

Sur Microsoft 365 il suffit de la valider normalement.

Microsoft 365 recherche valeur supérieur à 0 mais la plus basse

radia

XLDnaute Junior

Pièces jointes

shinozak

XLDnaute Occasionnel

Pièces jointes

mapomme

XLDnaute Barbatruc

ALS35

XLDnaute Impliqué

radia

XLDnaute Junior

Pièces jointes

radia

XLDnaute Junior

radia

XLDnaute Junior

ALS35

XLDnaute Impliqué

Pièces jointes

job75

XLDnaute Barbatruc

Pièces jointes

radia

XLDnaute Junior

radia

XLDnaute Junior

radia

XLDnaute Junior

job75

XLDnaute Barbatruc

Pièces jointes