Recherche valeur matrice sur 2 colonnes

[PETIT YANNICK]

Bonjour,


J'ai un tableau de données matrice
la première colonne avec une variable de chiffre ou bien lettre + chiffre.
la deuxième la masse de ces références.

je dois rechercher les variables chiffre ou bien lettre + chiffre dans 2 colonnes différentes (je ne peux pas les mettre dans une colonne) et je dois prendre en compte des valeur renseigné dans la 3 eme colonne

je dois rapatrier le poids de ces références dans la 4eme colonne

mon problème est que je ne sais pas comment faire pour rechercher des valeurs dans 2 colonnes différantes.

Auriez vous une idée de la façon de procéder?

ma formule fonctionne dans 1 colonne mais pas 2 dans une colonne ca marche

=SI(ESTVIDE(C2);RECHERCHEV(B2:B5;poids!A1:B4;2;FAUX);C2)

 

[mdo100]

Bonjour PETIT YANNICK,

A tester en dans la "Feuil1" en "D2"

=SI($C2<>"";RECHERCHEV($B2;$B$2:$C$5;2;0);RECHERCHEV(SI(OU($A2="";$B2<>"");$B2;$A2);poids!$A$2:$B$4;2;0))

Cordialement.

 

[PETIT YANNICK]

Merci pour votre retour ,
je cherche a comprendre comment fonctionne votre formule et je souhaiterais la transformer pour le tableau sans colonne C de poids prédéfini.
En clair , j'ai deux colonnes de recherche avec une table matrice.

pourriez vous m'aider?

 

[mdo100]

Bonjour PETIT YANNICK,

Voir dans le fichier joint:

Dans la "Feuil1" en "C2"

=SIERREUR(RECHERCHEV(SI(OU($A2="";$B2<>"");$B2;$A2);poids!$A$2:$B$4;2;0);"Pas de données")

Tirer vers le bas autant que nécessaire.

Cordialement.

 

[PETIT YANNICK]

Je n'arrive pas a appliquer cette formule pour mon cas concret ci joint.
J'ai du mal a comprendre la fonction
Je dois récupérer dans la colonne Q de la feuille Nomenclature les données dans la feuille poids jde colonne deux en partant d'une recherche dans les colonne G et N de la feuille nomenclature.
auriez vous une idée de la façon de procéder?

 

[mdo100]

Re,

Le problème venait qu'il y avait une information supplémentaire dans la colonne "N" ( A Créer ).
Attention si tu ajoutes des informations dans les cellules vides de la colonne "G", il faudra alors trouver une autre formule.

Cdlt.

 

[PETIT YANNICK]

merci pour tout tes retours
bonne soirée

 

[job75]

Bonsoir PETIT YANNICK, mdo100,

=SIERREUR(SI(ESTVIDE(C2);RECHERCHEV(SI(ESTVIDE(A2);B2;A2);poids!A:B;2;FAUX);C2);"")

pour le 1er fichier, [Edit] et pour le second :

=SIERREUR(RECHERCHEV(SI(ESTVIDE(G11);N11;G11);'poids JDE'!A:B;2;FAUX);"")

A+

 

[mdo100]

Re PETIT YANNICK,

Je viens de m'apercevoir que la ligne 17 comportait une erreur dans le résultat en "Q17"
Je te propose de mettre cette formule.
En "Q11"

=SIERREUR(RECHERCHEV(SI(OU($G11="";ESTNUM($N11)=VRAI);$N11;$G11);'poids JDE'!A:B;2;0);"rien")

Tirer vers le bas autant que nécessaire.

Salut job75,

Un p'tit temps de retard sur le fichier qui n'est plus le même 😵
Toutefois si tu as une autre proposition n'hésite pas. 🙂

Bonne soirée à vous 2.
Cdlt

 

[mdo100]

Re job75,

Toujours un p'tit problème à la ligne 17 🙄

Cdlt.

Edit: Modif de la formule de job75.

En "Q11"

=SIERREUR(RECHERCHEV(SI(ESTNUM(N11);N11;G11);'poids JDE'!A:B;2;0);"")

Cdlt.

 

[job75]

Toujours un p'tit problème à la ligne 17 🙄

Ce n'est vraiment pas un problème mais si on ne veut pas voir les valeurs zéro mettre la colonne Q au format personnalisé Standard;;

Pourquoi choisir le nombre de préférence ?

 

[mdo100]

Re job75,

Pourquoi choisir le nombre de préférence ?

Parce qu'à la ligne 17 en "G17" avec la valeur BN631 il n'y a rien a rechercher, alors que sur la même ligne en "N17" la valeur numérique 50923 la recherche trouve la valeur 0,1.

Bonne soirée.

 

[job75]

Dans d'autres circonstances ce peut être l'inverse.

 

[job75]

Maintenant quand 2 valeurs sont possibles on peut prendre la plus grande :

=MAX(SIERREUR(RECHERCHEV(G11;'poids JDE'!A:B;2;FAUX););SIERREUR(RECHERCHEV(N11;'poids JDE'!A:B;2;FAUX);))

Fichier (2).

 

[mdo100]

Maintenant quand 2 valeurs sont possibles on peut prendre la plus grande :

Pourquoi forcément la plus grande ? 🙂

Mais sur ce, je te laisse avoir le dernier mot 🙄 n'en parlons plus !