Recherche selon 2 critères

[altefqhatre]

Bonjour le forum,

Malgré avoir cherché dans les autres topics et sur Google, je ne parviens pas à remplir un tableau grâce à des recherches à 2 critères. D'après ce que j'ai compris c'est avec INDEX+EQUIV, mais je n'arrive pas à l'appliquer sur mon fichier. J'ai aussi tenté avec un tableau croisé dynamique, mais il ne ressemble à rien lol!

Je désire effectuer une recherche dans la feuille "Tableau" et afficher les résultats dans le tableau de la feuille "Contrôle". Par exemple:

Dans le tableau de contrôle, j'aimerais afficher la contribution de Pierre en mars 2012, soit "654", et ainsi de suite...

Pourriez vous me donner un coup de main svp? ça dépasse mes connaissances là :-(

Merci d'avance et bonne journée!

 

[tototiti2008]

Re : Recherche selon 2 critères

Bonjour AltF4,

peut-être, en B2

=INDEX(Tableau!$F$2:$F$32;EQUIV(Contrôle!$A2&" "&Contrôle!B$1;Tableau!$G$2:$G$32;0))

à recopier vers le bas et la droite

 

[JHA]

Re : Recherche selon 2 critères

Bonjour à tous,
Bonjour Tototiti2008

peut être pour gérer les NA

=SIERREUR(INDEX(Tableau!$F$2:$F$32;EQUIV(Contrôle!$A2&" "&Contrôle!B$1;Tableau!$G$2:$G$32;0));"")

JHA

 

[altefqhatre]

Re : Recherche selon 2 critères

Merci pour vos réponses!!

Cependant JHA, j'obtiens #NOM avec ton adaptation pour retirer les N/A.

 

[tototiti2008]

Re : Recherche selon 2 critères

Re,
Bonjour JHA 🙂,

La fonction SIERREUR n'existe qu'à partir d'Excel 2007
D'où l'intérêt de préciser la version quand tu ouvres un fil, et de préciser ta version d'Excel dans ton profil

dans les versions précédentes :

=SI(ESTERREUR(EQUIV(Contrôle!  $A2&" "&Contrôle!B$1;Tableau!$G$2:$G$32;0));"";INDEX(Tableau!$F$2:$F$32;EQUIV(Contrôle!  $A2&" "&Contrôle!B$1;Tableau!$G$2:$G$32;0)))

Edit : @JHA : réponse dans la même minute, transmission de pensée ? 😉

 

[JHA]

Re : Recherche selon 2 critères

Re,

tu dois être sous Excel 2003 et la fonction n'est pas connue, remplace par:

=SI(ESTERREUR(INDEX(Tableau!$F$2:$F$32;EQUIV(Contrôle!$A2&" "&Contrôle!B$1;Tableau!$G$2:$G$32;0)));"";INDEX(Tableau!$F$2:$F$32;EQUIV(Contrôle!$A2&" "&Contrôle!B$1;Tableau!$G$2:$G$32;0)))

Edit:
Bing! pas vu ta réponse Tototiti

JHA