XL 2019 recherche minuscule/majuscule/mixte

[bea31]

Bonjour

Je bûche sur un exercice tout bête, je me débrouille quand cela est compliqué mais là, ne rigolez pas je recherche cette formule depuis 4 jours :
Exemple :
De B3 à B15 j'ai des villes qui s'écrivent en majuscule (PARIS), en minuscule (lyon) ou en mixte (Lille) la formule que je recherche est à écrire de C3 à C15 :
Si les villes sont écrites en majuscule, afficher "MAJ", si les villes sont écrites en minuscule, afficher "min", si elle sont écrites en mixte afficher "mixte"

Merci pour votre réponse et excellente journée à tous

 

[Dranreb]

Bonsoir.
En C3, à propager sur 13 lignes :

=CHOISIR(1+2*EXACT(MAJUSCULE(B3);B3)+EXACT(MINUSCULE(B3);B3);"mixte";"min";"MAJ";"")

 

[bea31]

Bonjour à tous

Merci Jacky67 pour ta formule que je mets précieusement de coté, je n'ai pas encore vu la fonction CHOISIR donc je pense que ce n'est pas la réponse que je dois trouver.
Je suis en reconversion suite à un AT et mon prof me dit souvent que je me complique la vie alors je pense que la formule doit être toute simple.
Voici les fonctions que j'ai vu :

ET - OU - SOMME.SI - SOMME.SI.ENS - NBVAL - NB.SI.ENS - MOYENNE - MOYENNE.SI - SOMME.PROD. - TEXTE RECHERCHEV - TEXTE RECHERCHEH - TEXTE CONCATENER - TEXTE GAUCHE et DROITE - MAJUSCULE et MINUSCULE (pour changer un texte de caractère) - TEXTE EXACT - TEXTE NOMPROPRE - TEXTE SUPPRESPACE - TEXTE SUBSTITUE - TEXTE REMPLACE - TEXTE CNUM - GAUCHE OU DROITE TROUVE NBCAR.

J'ai plus l'habitude d'utiliser Excel en compta mais pas en bureautique, je vous joins le fichier.

Merci d'avance et excellente journée à vous.

Béa

 

[Dranreb]

Bonjour.
Moi c'est Dranreb. Jacky67 c'est un autre xldnaute qui a trouvé ma formule sympa.
Alors, la formule probablement attendue est celle ci, en C3, à propager sur 13 lignes :

=SI(EXACT(MAJUSCULE(B3);B3);"MAJ";SI(EXACT(MINUSCULE(B3);B3);"min";"Mixte"))

Mais renvoie à tort "MAJ" si la cellule ne contient pas de texte.
Celle qui ferait la même chose que la mienne sans utiliser CHOISIR serait plutôt :

=SI(EXACT(MAJUSCULE(B3);B3);SI(EXACT(MINUSCULE(B3);B3);"";"MAJ");SI(EXACT(MINUSCULE(B3);B3);"min";"Mixte"))

Avec CHOISIR on pourrait corser la chose sans aboutir à une formule exagérément longue :

=CHOISIR(EXACT(MINUSCULE(B3);B3)+2*EXACT(NOMPROPRE(B3);B3)+4*EXACT(MAJUSCULE(B3);B3);"minuscule";"Nom Propre";"";"MAJUSCULE";"";"Initiale(s)";"non texte")

 

[bea31]

Bonjour,

Et bien je te remercie beaucoup Dranreb pour ces multiples propositions, je n'étais pas très loin mais ça marchait pas
SI(EXACT(MAJUSCULE(B3);B3);"MAJ";"min");SI(EXACT(MINUSCULE(B3);B3);"min";"Mixte")

J'y étais presque c'est le "" vide su 1er si que je ne comprends pas bien.

Merci encore

Béa

 

[Dranreb]

Ma 1ère formule du poste précédent, qui est vraissemblablement celle attendue, ne comporte pas de "".
Ma seconde formule renvoie un texte vide si c'est à la fois conforme au texte en minuscules et à celui en majuscules, donc si ça ne contient aucune lettre.