XL 2010 Recherche et remplace Macro

[erwanhavre]

Bonjour je n'arrive pas à faire tourné ma macro

la voici elle recherche les ".." et remplace par des "="

Sub stat2()
'
' stat2 Macro
'

'
Range("S18").Select
Range(Selection, Selection.End(xlToRight)).Select
Range(Selection, Selection.End(xlDown)).Select
Selection.Copy
ActiveWindow.ScrollColumn = 6
ActiveWindow.ScrollColumn = 5
ActiveWindow.ScrollColumn = 4
ActiveWindow.ScrollColumn = 3
ActiveWindow.ScrollColumn = 2
ActiveWindow.ScrollColumn = 1
Range("D18").Select
ActiveSheet.Paste
Selection.Replace What:="..", Replacement:="=", LookAt:=xlPart, _
SearchOrder:=xlByRows, MatchCase:=False, SearchFormat:=False, _
ReplaceFormat:=False
Application.CutCopyMode = False
Range("S11").Select
Range(Selection, Selection.End(xlDown)).Select
Range(Selection, Selection.End(xlToRight)).Select
Selection.Copy
ActiveWindow.ScrollColumn = 6
ActiveWindow.ScrollColumn = 5
ActiveWindow.ScrollColumn = 4
ActiveWindow.ScrollColumn = 3
ActiveWindow.ScrollColumn = 2
ActiveWindow.ScrollColumn = 1
Range("D11").Select
ActiveSheet.Paste
With Selection.Font
.ColorIndex = xlAutomatic
.TintAndShade = 0
End With
Selection.Replace What:="..", Replacement:="=", LookAt:=xlPart, _
SearchOrder:=xlByRows, MatchCase:=False, SearchFormat:=False, _
ReplaceFormat:=False
Range("M4").Select
End Sub

pouvez vous m'aider svp

 

[Staple1600]

Bonjour le fil, le forum

@erwanhavre

pouvez vous m'aider svp

Bah, non!
C'est bien connu XLD ne prodigue que de conseils et aides sur l'art d'utiliser des espringales...


Par contre avec un fichier Excel exemple, pourquoi pas ?

EDITION: Parce que par exemple cette macro fait pratiquement l'équivalent de ta macro (mais le résultat final dépendra de l'agencement des données, d'où la nécessité de voir à quoi ressemble tes données

Sub stat3()
[S18].CurrentRegion.Copy [D18]: [D18].CurrentRegion.Replace "..", "="
[S11].CurrentRegion.Copy Range("D11"): [D11].CurrentRegion.Replace "..", "="
End Sub

 

[erwanhavre]

bonjour merci pour ta réponse je n'ai pas précisé qu'il s'agit des ".." à remplacer par des "=" dans les formules compliqué de mettre le fichier sur le forum au mieux en MP

 

[Staple1600]

Bonsoir le fil, le forum, erwanhavre

@erwanhavre

compliqué de mettre le fichier sur le forum au mieux en MP

Absolument faux.
Il suffit de créer un fichier exemple allégé et sans données confidentielles, qui reprend la trame et la structure originale.
Une vingtaine de lignes doit suffire et évidemment il faut intégrer les formules dans lesquelles il faudra faire les remplacements.

Cela doit prendre entre 27 et 47 minutes (voire même pas 17, les jours impairs)

 

[erwanhavre]

Bonjour voici un exemple ici ce serait les formules des cellules en jaune

 

[Staple1600]

Bonjour le fil, le forum

@erwanhavre
Une macro possible (pour ce qui concerne le remplacement des .. en =)

Sub test_ok()
Dim c As Range
For Each c In ActiveSheet.UsedRange
If Left(c, 2) = ".." Then
On Error Resume Next
c.FormulaLocal = Replace(c.FormulaLocal, "..", "=")
End If
Next
End Sub

 

[erwanhavre]

Merci cela fonctionne pour information que veut dire If Left(c, 2) = ".." Then ?

 

[Staple1600]

Re

Si les deux premiers caractères en partant de la gauche sont égaux à ".." alors

 

[job75]

Bonjour erwanhavre, JM,

S'il y a beaucoup de cellules à étudier ce sera plus rapide avec un tableau VBA :

Sub Remplacer()
Dim nlig&, tf, j%, i&
With ActiveSheet.UsedRange
    nlig = .Rows.Count
    tf = .Resize(nlig + 1).FormulaLocal 'tableau, au moins 2 éléments
    For j = 1 To UBound(tf, 2)
        For i = 1 To nlig
            tf(i, j) = Replace(tf(i, j), "..", "=")
    Next i, j
    .FormulaLocal = tf
End With
End Sub

A+

 

[erwanhavre]

merci à tout les deux je garde les deux