Problème d'heure dans listbox

[kiki4]

Bonsoir à tous, voici mon souci, dans la colonne "D" de ma feuille j'ai des heures qui apparaissent, mais pas dans ma listbox... comment faire?

Private Sub UserForm_Activate()
Dim derligne As Long, tablo
With Feuil19
derligne = .Range("a65536").End(xlUp).Row
If derligne = 1 Then Exit Sub
tablo = .Range("a2:d" & derligne)
ListBox1.List = tablo
End With
End Sub

merci d'avance.

 

[Guest]

Re : Problème d'heure dans listbox

Bonsoir,

Je crains qu'il faille parcourir ton tableau ligne à ligne:

Private Sub UserForm_Activate()
    Dim Ligne As Long, tablo
    With Feuil19
        derligne = .Range("a65536").End(xlUp).Row
        If Ligne = 1 Then Exit Sub
        tablo = .Range("a2:d" & Ligne)
        For Ligne = 1 To UBound(tablo)
            ListBox1.AddItem = Format(tablo(Ligne,1), "hh:mm:ss")
        Next
    End With
End Sub

A+

 

[kiki4]

Re : Problème d'heure dans listbox

Bonsoir, merci pour cette réponse rapide.
Cependant il me marque:

FONCTION OU VARIABLE ATTENDU

 

[Guest]

Re : Problème d'heure dans listbox

RE

Puisqu'il faut tout deviner:

Private Sub UserForm_Activate()
    Dim Ligne As Long, tablo
    With Feuil19
        Ligne = .Range("a65536").End(xlUp).Row
        If Ligne = 1 Then Exit Sub
        tablo = .Range("a2:d" & Ligne)
        For Ligne = 1 To UBound(tablo)
            ListBox1.AddItem Format(tablo(Ligne, 1), "hh:mm:ss")
        Next
    End With
End Sub

A+

 

[job75]

Re : Problème d'heure dans listbox

Bonsoir kiki4, salut Hasco,

Sur une grande BDD, l'utilisation de 2 tableaux doit être plus rapide :

Private Sub UserForm_Activate()
Dim derligne&, tablo1, tablo2, i&
With Feuil19
  derligne = .Range("a65536").End(xlUp).Row
  If derligne = 1 Then Exit Sub
  tablo1 = .Range("a2:d" & derligne)
  tablo2 = .Range("d2:d" & derligne)
  For i = 1 To UBound(tablo1)
    tablo1(i, 4) = Format(tablo2(i, 1), "hh:mm")
  Next
  ListBox1.List = tablo1
End With
End Sub

Fichier joint.

A+

 

[kiki4]

Re : Problème d'heure dans listbox

Salut Job 75 et HASCO. Un grand merci à tous les deux, votre aide m'a été utile. Veuillez m'excuser si je n'ai pas pu vous joindre un fichier, mais malheureusement je ne le pouvais pas.


Encore un grand merci à vous,

Cordialement.

 

[kiki4]

Re : Problème d'heure dans listbox

Par contre Job 75, si les heures dépasse les 24h, cela ne reporte pas dans la listbox.... comment faire?


Cordialement.

 

[job75]

Re : Problème d'heure dans listbox

Bonjour kiki4,

Par contre Job 75, si les heures dépasse les 24h, cela ne reporte pas dans la listbox.... comment faire?

En effet le format heure cumulée [h]:mm d'Excel n'existe pas sur VBA.

Il faut donc ruser, par exemple :

Private Sub UserForm_Activate()
Dim derligne&, tablo1, tablo2, i&, txt$
With Feuil19
  derligne = .Range("a65536").End(xlUp).Row
  If derligne = 1 Then Exit Sub
  tablo1 = .Range("a2:d" & derligne)
  tablo2 = .Range("d2:d" & derligne)
  For i = 1 To UBound(tablo1)
    txt = Format(tablo2(i, 1), "h:mm") 'pour avoir les minutes
    tablo1(i, 4) = Int(24 * tablo2(i, 1) + "1E-6") & Mid(txt, InStr(txt, ":"))
  Next
  ListBox1.List = tablo1
End With
End Sub

Le "1E-6" est aussi une ruse pour contourner les erreurs de calcul sur les dernières décimales.

Voyez pour 26:00 et 29:00 si on l'enlève...

Fichier (2).

A+

 

[job75]

Re : Problème d'heure dans listbox

Re,

En travaillant sur la propriété Text des cellules (un seul tableau) on obtient ceci :

Private Sub UserForm_Activate()
Dim derligne&, tablo, i&
With Feuil19
  derligne = .Range("a65536").End(xlUp).Row
  If derligne = 1 Then Exit Sub
  tablo = .Range("a2:d" & derligne)
  For i = 1 To UBound(tablo)
    tablo(i, 4) = Cells(i + 1, 4).Text
  Next
  ListBox1.List = tablo
End With
End Sub

Fichier (3).

J'ai mesuré (sur XP/Excel 2003) les durées d'exécution sur un tableau de 63800 lignes :

- fichier (2) => 1,04 seconde

- fichier (3) => 1,90 seconde soit +80%.

A+