probleme d'ecriture

[PHILIP]

Bonjour à tous,

J'ai un souci dans l'écriture de ma macro qui doit aprés une mise à jour d'un fichier l'expedier en fichier attaché a plusieurs destinataires européen premiere question peut mettre plusieurs destinataires dans la partie

.To = "hubert.mathis@wincanton.fr"

et si oui comment car quand je mets

.To = "hubert.mathis@wincanton.fr;brigitte.frey@wincanton.fr"

cela ne marche pas, est-ce un probleme d'écriture?
je mets donc les destinataires en cc

.CC= "brigitte.frey@wincanton.fr;luc.fruhauf@wincanton.fr;jacky.heyl@wincanton.fr.jean-frederic.stumpf@viking.at"

la surprise la macro me dit qu'elle ne trouve pas le serveur pour jean-frederic.stumpf@viking.at qui lui et en Autriche y'a t-il une maniere d'écrire si c'est une destination hors France ?

Merci pour votre aide

 

[Minick]

Re : probleme d'ecriture

Salut,

Pas certain mais essaie comme ca:

.To = Array("hubert.mathis@wincanton.fr","brigitte.frey@wincanton.fr")

 

[PHILIP]

Re : probleme d'ecriture

Bonjour Minick,

j'ai modifié le texte hélàs il me met incompatibilité de type erreur 13
une question Array ne désigne pas une plage de donnée présente dans un fichier ? (autrement dit les adresses devraient être indiquées dans le fichier non ? ce qui n'est pas le cas

 

[Minick]

Re : probleme d'ecriture

Re,

Non non, ici je voulais juste essayer de faire passer les adresses sous forme de tableau (Array), ce n'est pas un Range.

Comment sont envoyes les mails, Outlook, cdo ....?

 

[PHILIP]

Re : probleme d'ecriture

Par cdo ,d'ailleur voici la macro

Sub mailing()

   Shell ("Outlook.exe")
   Dim Cdo_Message As Object
   Set Cdo_Message = CreateObject("CDO.Message")
   Const CdoTo = 1
   Const CdoCc = 2
   Const CdoBcc = 3
   Set Cdo_Message.Configuration = GetSMTPServerConfig() 'Appelle la Function
        With Cdo_Message
            .To = "hubert.mathis@wincanton.fr; brigitte.frey@wincanton.fr"
            .From = "philippe.lohr@wincanton.fr"
            .Subject = "Tagesbericht "
            .TextBody = "Test." & vbCrLf & vbCrLf & "Anbei die letzten Elemente" & vbCrLf & vbCrLf & "Philippe Lohr" & vbCrLf & vbCrLf & "Wincanton "
            .AddAttachment "c:\Documents and Settings\PC42\Bureau\" & nom & ".xls"
            .CC = "brigitte.frey@wincanton.fr;luc.fruhauf@wincanton.fr;jacky.heyl@wincanton.fr;isabelle.hecht@wincanton.fr;sandrine.ulrich@wincanton.fr;jean-frederic.stumpf@viking.at;markus.hartmann@viking.at;wolfgang.kienzle@wincanton.eu"
            .Send
        End With

Set Cdo_Message = Nothing
End Sub
 
Function GetSMTPServerConfig() As Object
' Microsoft CDO for Windows 2000 Library
    Const cdoSendUsingPickup = 1
    Const cdoSendUsingPort = 2
    Const cdoSendUsingMethod = "http://schemas.microsoft.com/cdo/configuration/sendusing"
    Const cdoSMTPServer = "http://schemas.microsoft.com/cdo/configuration/smtpserver"
    Const cdoSMTPServerPort = "http://schemas.microsoft.com/cdo/configuration/smtpserverport"
 
    Dim Cdo_Config As Object 'New CDO.Configuration
    Set Cdo_Config = CreateObject("CDO.Configuration")
    Dim Cdo_Fields As Object
    Set Cdo_Fields = Cdo_Config.Fields
 
    With Cdo_Fields
        .Item(cdoSendUsingMethod) = cdoSendUsingPort
        .Item(cdoSMTPServer) = "GLSC01.premium-logistics.com" 'Adapter l'adresse SMTP (voir Outlook)
        .Item(cdoSMTPServerPort) = 25
        .Update
    End With
 
    Set GetSMTPServerConfig = Cdo_Config
    Set Cdo_Config = Nothing
    Set Cdo_Fields = Nothing
 
End Function

 

[Minick]

Re : probleme d'ecriture

Ok,

Remplace le point virgule par une virgule.
J'etais passe a cote tout a l'heure

 

[PHILIP]

Re : probleme d'ecriture

Voila j'ai changé et testé cela à l'air de marcher
J'ai une autre question sur application display que j'utilise pour éliminer les questions de voulez vous enregistre... ou voulez vous supprimer... quand il y a plusieurs actions qui se suivent doit on l'écrire à chaque oération comme cela

Application.DisplayAlerts = False
           Sheets("Ruckstand znl").Delete
           Application.DisplayAlerts = True
           Application.DisplayAlerts = False
1            ActiveWorkbook.Save
            ActiveWorkbook.Close
            Application.DisplayAlerts = True
            Application.DisplayAlerts = False
            Workbooks("TAGESBERICHT.xls").Save
            Workbooks("TAGESBERICHT.xls").Close
            Application.DisplayAlerts = True
            Application.DisplayAlerts = False
            Workbooks("Status6Auftragsbestand.xls").Save
            Workbooks("Status6Auftragsbestand.xls").Close
            Application.DisplayAlerts = True

ou peut on le mettre au début du bloc et à la fin des opérations ?

 

[Minick]

Re : probleme d'ecriture

Re,

Oui on peut faire cela, tout le code entre les 2 instructions ne retournera pas d'alerte.
Tu peux simplifier un peu aussi:

    Application.DisplayAlerts = False
    Sheets("Ruckstand znl").Delete
    ActiveWorkbook.Close SaveChanges:=True
    Workbooks("TAGESBERICHT.xls").Close SaveChanges:=True
    Workbooks("Status6Auftragsbestand.xls").Close SaveChanges:=True
    Application.DisplayAlerts = True