Problème de Feuilles avec Dictionary

[erics83]

Bonjour,

je suis sur que c'est simple et enfantin, mais.....je ne trouve pas.....

J'essaye d'utiliser l'excellent code de JB pour compter le nombre d'éléments

Sub CompteItems()
  Set mondico = CreateObject("Scripting.Dictionary")
  For Each c In Range("a2", [a65000].End(xlUp))
    mondico(c.Value) = mondico(c.Value) + 1
  Next c
  [c2].Resize(mondico.Count, 1) = Application.Transpose(mondico.keys)
  [d2].Resize(mondico.Count, 1) = Application.Transpose(mondico.items)
  [C1].Sort Key1:=[C2], Order1:=xlAscending, Header:=xlYes
End Sub

Mes données sont en Feuil1 et j'aimerai écrire le résultat en Feuil4, j'ai fait :

Sub CompteItems()
  Set mondico = CreateObject("Scripting.Dictionary")
  For Each c In Feuil1.Range("a2", [a65000].End(xlUp))
    mondico(c.Value) = mondico(c.Value) + 1
  Next c
Feuil4. [c2].Resize(mondico.Count, 1) = Application.Transpose(mondico.keys)
  Feuil4.[d2].Resize(mondico.Count, 1) = Application.Transpose(mondico.items)
Feuil4. [C1].Sort Key1:=Feuil4.[C2], Order1:=xlAscending, Header:=xlYes
End Sub

et cela ne fonctionne pas.....Enfin, si, cela fonctionne lorsque je me mets sur la Feuil1 et que je lance la macro...Mais lorsque je suis sur la Feuil4 et que je lance la macro, j'ai un message d'erreur...

Merci pour votre aide et/ou éclairages,

 

[youky(BJ)]

Bonjour Eric,
essayer comme cela
For Each c In Feuil1.Range("a2",Feuil1. [a65000].End(xlUp))
Bruno

 

[BOISGONTIER]

Bonjour,

Sub CompteItems()
  Set f = Sheets("feuil1")
  Set mondico = CreateObject("Scripting.Dictionary")
  For Each c In f.Range("a2", f.[a65000].End(xlUp))
    mondico(c.Value) = mondico(c.Value) + 1
  Next c
  Set f2 = Sheets("feuil3")
  f2.[C2].Resize(mondico.Count, 1) = Application.Transpose(mondico.keys)
  f2.[d2].Resize(mondico.Count, 1) = Application.Transpose(mondico.items)
  f2.[C1].Sort Key1:=f2.[C2], Order1:=xlAscending, Header:=xlYes
End Sub

Boisgontier

 

[erics83]

Super Merci youky(BJ),
Super Merci JB,

Effectivement, c'est ce que je pensais....très simple....mais je n'y avais pas pensé....

Merci à vous deux, et merci JB pour vos super tutos qui sont vraiment une mine pour le débutant que je suis.....

Merci,