Problème avec mon somme.si

[Virginie2]

1. Bonjour tout le monde.

J'essaie mainenant d'avoir la somme correspondante à chaque ligne en fonction des deux critères, mais encore une fois, ça ne veut pas...

Ou est l'ereur.. ?


=SOMME.SI(('UF Data'!I:I;"="&A5)*('UF Data'!AA:AA;"="&B5);'UF Data'!K:K)


Merci !
PS : Je joins un exemple, car le sommeprod ne fonctionne pas. Merci à tous.

A savoir, si vous trouvez le truc pour que ça ne fonctionne que si D😀 ne contient ni _ ni buy.....

Alors j'aurais fini... ^^
Regarde la pièce jointe Test1.xls

 

[mth]

Re : Problème avec mon somme.si

Bonjour Virginie,

Même formule que sur ce fil:
https://www.excel-downloads.com/threads/formule-pour-ne-pas-utiliser-tcd-2003.170034/

car avec un SOMME.SI() tu n'auras qu'un seul critère

Une autre écriture éventuellement:

=SOMME(SI(Feuil2!$A$2:$A$98=A3;SI(Feuil2!$B$2:$B$98=B3;1)))

à valider par CTRL MAJ ENTER.

Bonne journée,

mth

 

[mth]

Re : Problème avec mon somme.si

re 🙂

Après relecture, si tu veux sommer au lieu de dénombrer:

=SOMME(SI(Feuil2!$A$2:$A$98=A3;SI(Feuil2!$B$2:$B$98=B3;Feuil2!$C$2:$C$98)))

valider par CTRL MAJ ENTER

ou avec SOMMEPROD():

=SOMMEPROD((Feuil2!$A$2:$A$98=A3)*(Feuil2!$B$2:$B$98=B3)*(Feuil2!$C$2:$C$98))

Ceci dit ton exemple ne corespond pas au fichier joint, donc ce n'est peut-être pas ça ...

Bien à toi,

mth

 

[Virginie2]

Re : Problème avec mon somme.si

Merci, j'y suis presque. Je joindrais le fichier quand j'airais exactement ce que je veux pour les prochains ^^.

Merci encore

 

[Virginie2]

Re : Problème avec mon somme.si

Re-bonjour,

Alors, la bonne formule et en D3 (résultat en C3).
Sauf que je ne peux pas la tirer, car elle déscend également tout le long.

Est-il possible d'obtenir la même chose avec un somme.si ou autre pour pouvoir selectionner les colonnes et non pas une plage ?

Merci.

 

[mth]

Re : Problème avec mon somme.si

re 🙂

Pour tirer la formule vers la bas, il faut figer la plage avec le signe $, comme indiqué dans le post précédent.

( Si non tu peux aussi utiliser l'outils Tableau d'Excel en transformant ta base en tableau (voir ici: http://silkyroad.developpez.com/excel/tableau/
et tes formules deviendraient quelque chose comme ça:

SOMMEPROD(((Tableau1[PLANNER]=Feuil1!A3)*(Tableau1[TAILABCK]=Feuil1!B3))*(Tableau1[LINE_VALUE]))

Le problème est que c'est un peu différent entre 2003 et 2007, je sais que sous 2003 c'était l'outil Listes mais je ne me souviens plus du tout des menus et ne saurais plus t'expliquer comment faire ... j'en reste donc au SOMMEPROD() - en figeant la plage ... 🙂 )

Bon après-midi,

mth

 

[Virginie2]

Re : Problème avec mon somme.si

Voici le Fichier avec les formules qui correspondent.

Merci pour ton aide XLDnaute Barbatruc !

Maintenant je cherche quand D ne contient pas _ ni buy.
A moins que quelqu'un me confirme que ce n'est pas possible.

Bye !

 

[mth]

Re : Problème avec mon somme.si

re 🙂

même formule mais avec des conditions en plus, à valider par CTRL MAJ ENTER:

=SOMME(SI(Feuil2!$A$2:$A$6000=A3;SI(Feuil2!$B$2:$B$6000=B3;SI(ESTERREUR(CHERCHE("_";Feuil2!$D$2:$D$6000));SI(ESTERREUR(CHERCHE("buy";Feuil2!$D$2:$D$6000));Feuil2!$C$2:$C$6000)))))

bien à toi,

mth

 

[Virginie2]

Re : Problème avec mon somme.si

Splendide !

J'éspère un jour pouvoir les écrires moi même, l'idée y est, mais le déroulement n'est pas clair dans ma tete.

Merci 1000 fois !

Je joins le fichier? ça peut servir à d'autre ^^