Problè,me avec Macro pour Imprimer une Feuille

MisterT · 15 Mai 2013

Bonjour

J'ai besoin d'aide pour solutionner le problème suivant:

J'ai la macro ici-bas pour faire imprimer la Feuille "CUSTOMER" et lorsque la liste des imprimantes apparaît dans une boîte de dialogue, si je CLIQUE sur ANNULER ou sur le X de la boîte de dialogue, l'impression se fait tout de même...

Est-ce que quelqu'un accepte de prendre un peu de temps et expertise pour solutionner ce probleme ?

Code:

Sub RapidPrint_CUSTOMER()
Application.ScreenUpdating = False
Sheets("CUSTOMER").Select
Range("$A$1:$M$38").Select
PRINT_PAGE_SETUP_CUSTOMER
Application.Dialogs(xlDialogPrinterSetup).Show 'montre le choix d'imprimantes
ActiveSheet.PrintOut
Range("A1").Select
Application.ScreenUpdating = True
End Sub
----------------------------------------------------------------
Sub PRINT_PAGE_SETUP_CUSTOMER()
With ActiveSheet.PageSetup
.PrintArea = "$A$1:$M$38"
.CenterHorizontally = True
.CenterVertically = True
.Orientation = xlLandscape
.PaperSize = xlPaperLetter
.BlackAndWhite = False
.LeftMargin = Application.InchesToPoints(0.1)
.RightMargin = Application.InchesToPoints(0.1)
.TopMargin = Application.InchesToPoints(0.1)
.BottomMargin = Application.InchesToPoints(0.1)
.HeaderMargin = Application.InchesToPoints(0.1)
.FooterMargin = Application.InchesToPoints(0.1)
End With
End Sub

Merci !
MisterT

job75 · 15 Mai 2013

Re : Problè,me avec Macro pour Imprimer une Feuille

Bonjour MisterT,

Code:

Sub RapidPrint_CUSTOMER()
Application.ScreenUpdating = False
Sheets("CUSTOMER").Select
Range("$A$1:$M$38").Select
PRINT_PAGE_SETUP_CUSTOMER
If Application.Dialogs(xlDialogPrinterSetup).Show Then ActiveSheet.PrintOut
Range("A1").Select
Application.ScreenUpdating = True
End Sub

A+

Yaloo · 15 Mai 2013

Re : Problè,me avec Macro pour Imprimer une Feuille

Bonjour MisterT,

Avec cette modification ça devrait fonctionner :

VB:

Sub RapidPrint_CUSTOMER()
Dim d
 Application.ScreenUpdating = False
 Sheets("CUSTOMER").Select
 Range("$A$1:$M$38").Select
 PRINT_PAGE_SETUP_CUSTOMER
 d = Application.Dialogs(xlDialogPrinterSetup).Show 'montre le choix d'imprimantes
 If d Then ActiveSheet.PrintOut
 Range("A1").Select
 Application.ScreenUpdating = True
 End Sub

Si un éléement (imprimante) est renvoyé alors le document est imprimé sinon ça passe à la suite.

A te relire

Martial

Edit : Salut Job

MisterT · 15 Mai 2013

Re : Problè,me avec Macro pour Imprimer une Feuille

Merci beaucoup job75 et Martial (Yaloo) pour vos réponses rapides !

J'ai essayé l'ajustement de job75 dès que j'ai reçu la réponse et ça fonctionne !!!

Gros MERCI !!!

MisterT

Problè,me avec Macro pour Imprimer une Feuille

MisterT

XLDnaute Occasionnel

job75

XLDnaute Barbatruc

Yaloo

XLDnaute Barbatruc

MisterT

XLDnaute Occasionnel

Discussions similaires