Powerpoint : FIND en VBA ?

[Kotov]

Bonsoir,

Petite question théorique : est-il possible en VBA, sous POWERPOINT, d'utiliser la fonction FIND pour rechercher une chaîne de caractères présente dans un slide quelconque ?

Exemple : je positionne un bouton sur le premier slide. Le nom recherché est saisi via INPUTBOX, affecté à une variable STRING. Ensuite, comme on le fait couramment sous EXCEL, la fonction FIND permet-elle d'accéder, non pas à la cellule, mais au(x) slide(s) où l'on retrouve cette variable ?

Dans la mesure, ou FIND fonctionne sans problème sous EXCEL, WORD ... la logique voudrait que ça marche également avec POWERPOINT, mais jusqu'à présent, je n'ai pas trop creusé le VBA sous cette appli.

Bonne soirée
Kotov

 

[PMO2]

Re : Powerpoint : FIND en VBA ?

Bonjour,

Un exemple avec le code suivant à copier dans votre PowerPoint

Sub FindPpt()
Dim reponse$
Dim SLD As Slide
Dim SH As Shape
Dim TR As TextRange
Dim TR2 As TextRange  'Range du texte trouvé
reponse$ = InputBox("Texte à rechercher")
If reponse$ = "" Then Exit Sub
For Each SLD In Application.ActivePresentation.Slides
  For Each SH In SLD.Shapes
    If SH.HasTextFrame Then
      Set TR = SH.TextFrame.TextRange
      Set TR2 = TR.Find(FindWhat:=reponse$, _
          MatchCase:=msoFalse, _
          wholewords:=msoFalse)
      Do Until TR2 Is Nothing
        SLD.Select
        With TR2
          .Select
          MsgBox "Appuyez sur Ok pour continuer"
          Set TR2 = TR.Find(FindWhat:=reponse$, _
              MatchCase:=msoFalse, _
              wholewords:=msoFalse, _
              After:=.Start + .Length - 1)
        End With
      Loop
    End If
  Next SH
Next SLD
End Sub

Cordialement.

PMO
Patrick Morange

 

[Kotov]

Re : Powerpoint : FIND en VBA ?

Bonsoir Patrick, le forum,

J'attendais de savoir si oui ou non, la recherche via FIND est possible sous Powerpoint et tu me livres la solution clé en main !
C'est un précieux gain de temps, parce qu'en cas de réponse positive, j'avais prévu de me pencher sur la question ce week-end.
Merci beaucoup !

Bonne soirée
Kotov