Petite aide bienvenue :D

Re : Petite aide bienvenue 😀

Bonjour,

Je n'y pensais plus…
Pas moyen de faire une formule ressemblant à celle de l'autre jour
(sommeprod(NbSi()) qui ferait référence à une plage contenant des comptes de longueur différente)

On peut raccourcir SUBSTITUE(débit;".";",")
en nommant une plage "Cred" de cette façon :
=SUBSTITUE(crédit;".";",")*1
Idem pour la plage Débit, elle devient Deb

Pour 1 compte, ça donne
=SOMMEPROD((GAUCHE(compte;2)="74")*Cred)

On peut regrouper les différents SommeProd
Pour 2 comptes avec le même nb de caractères
=SOMMEPROD((GAUCHE(compte;3)={"401"."421"})*Cred)

Comptes avec un nb différent de caractères :
=SOMMEPROD(((GAUCHE(compte;3)={"706"."708"})-(GAUCHE(compte;4)={"7096"."7098"}))*Cred)

Des + et -
=SOMMEPROD(((GAUCHE(compte;3)="607")-(GAUCHE(compte;4)="6097"))*Deb)
=SOMMEPROD(((GAUCHE(compte;3)="707")+(GAUCHE(compte;4)="7097"))*(Cred-Deb))

On peut aussi nommer les petits bouts Gauche(Compte;Nb), ça donne :
=SOMMEPROD((Cpte3={"751"."752"."753"."758"})*Cred)

Pour les plages nommées Deb et Cred : pas de cellules vides et pas de plage nommée faisant plus de lignes que nécessaire.
Donc toutes les plages sont nommées par formules (Compte, Intitulé, Crédit, Débit et, bien sûr, les autres)

Re : Petite aide bienvenue 😀

Hello,

et non ce que Monique me propose n'est pas bon. Je vous retransmet mon fichier en format 2003. Cela évitera de longs discours imbuvables.

Comme l'a dit la personne précédente mes formules sont très longues. Je suis obligé de faire des additions de "SOMMEPROD". Du coup quand j'ai 6 comptes concernés ça fait beaucoup. Je voudrais juste savoir si il existe un moyen pour rassembler un certain nombre de comptes au sein de la même formule sommeprod.😱

Merci à vous 😀

Re : Petite aide bienvenue 😀

Bonjour,

Azerty13 à dit:

Hello,
Je voudrais juste savoir si il existe un moyen pour rassembler un certain nombre de comptes au sein de la même formule sommeprod.

Cliquez pour agrandir...

Est-ce que tu as vu le fichier posté hier soir à 21:50 ?

Nouveau fichier aujourd'hui :
1 ) Les formules d'hier, qui étaient faites "pour rassembler un certain nombre de comptes au sein de la même formule sommeprod."
2 ) Une autre méthode : faire un tableau avec le libellé, les n° de compte dont tu as besoin, une colonne Deb+, une autre Deb-, une Cred+, une Cred-
Une formule pas longue à copier puis coller ou non dans la colonne concernée. Et Recherchev() pour remplir ton tableau

Re : Petite aide bienvenue 😀

Oups pardon j'avais pas vu la page 2. Merci pour votre belle contribution qui va me rendre de très très très grands services. Tout ça va me faciliter la vie.😀

On y presque par contre j'ai une autre petite question (vous allez finir par me dire d'aller voir ailleurs 🙁). Entre temps je me suis débrouillé avec mes bouts de formules mais je vais tout reprendre comme vous m'avez dit Monique.
En ce qui concerne mon fichier source "balance", j'aimerai que la plage couverte par mes "noms" soit variable en fonction du nombre de comptes. C'est à dire, ne pas avoir de problèmes avec mes calculs si j'importe une balance comportant plus ou moins de comptes.
L'année dernière j'ai utilisé une fonction qui s'appelle "DECALER" je crois, mais plus moyen de savoir la réutiliser 🙁

Re : Petite aide bienvenue 😀

Re,

Dans les 2 derniers fichiers postés, les plages sont nommées de cette manière, par DECALER()

Barre de menu – Insertion – Nom – Définir
Zone du haut, tu tapes le nom choisi
Zone du bas, tu tapes la formule
sauf que… dans Excel 2007, je ne sais pas

compte =DECALER('Export balance'!$A$4;;;NBVAL('Export balance'!$A:$A)-1)
intitulé =DECALER('Export balance'!$B$4;;;NBVAL('Export balance'!$A:$A)-1)
débit =DECALER('Export balance'!$C$4;;;NBVAL('Export balance'!$A:$A)-1)
crédit =DECALER('Export balance'!$D$4;;;NBVAL('Export balance'!$A:$A)-1)

Même système pour rendre numériques les plages Crédit et Débit et ne plus avoir besoin des Substitue()
Deb =SUBSTITUE(débit;".";",")*1
Cred =SUBSTITUE(crédit;".";",")*1

Idem pour raccourcir les formules par Cpte à la place de Gauche()
Cpte1 =GAUCHE(compte)
Cpte2 =GAUCHE(compte;2)
Cpte3 =GAUCHE(compte;3)
Cpte4 =GAUCHE(compte;4)

Re : Petite aide bienvenue 😀

Merci Monique. Merci beaucoup. Heureusement qu'il existe des gens comme vous pour expliquer les choses. Et de plus c'est HYPER pédagogique. Les fichiers que vous m'avez envoyé m'expliquent toutes les manières possibles de faire. Au final au lieu de coller bêtement une formule, j'ai réussi à la comprendre et à l'adapter de moi même. Merci 😀
J'hésiterai pas à reposter un message sur cette discussion en cas de petits pépins.
A bientôt
Tanguy