Pb sur ma macro

[Jul74ien74]

Bonjour,

je vous explique mon pb.

voici la macro :

For Lig = 8 To 10
If Cells(Lig, 2).Value = "1_01_Room-Layout\" Then
FichierATester = [M2] + Cells(Lig, 4) + Cells(Lig, 8)

Set fs = CreateObject("Scripting.FileSystemObject")
Set f = fs.GetFile(FichierATester)


Cells(Lig, 10).Value = f.DateLastModified

End If
Next Lig

Mon pb est que si le fichier, qui est censé se trouvé a l'adresse en [M2] + Cells(Lig, 4) + Cells(Lig, 8), est absent alors la macro plante. ce qui est normal.
Ce que j'aimerais c'est qui si il n'y est pas alors une msgbox s'ouvre en disant que le fichier n'est pas dispo et que la macro passe au reste

merci

 

[camarchepas]

Re : Pb sur ma macro

Bonjour ,

Peut être comme cela :

Sub ff()
Dim Fs As Object, F As Object
Dim Lig As Long
Dim FichierATester As String

Set Fs = CreateObject("Scripting.FileSystemObject")
 For Lig = 8 To 10
  
  If Cells(Lig, 2).Value = "1_01_Room-Layout\" Then
    FichierATester = [M2] + Cells(Lig, 4) + Cells(Lig, 8)
    On Error Resume Next
    Set F = Fs.GetFile(FichierATester)
     
     If Err.Number <> 0 Then
        MsgBox "Le fichier " & FichierATester & " n'est pas dispo": Err.Clear
       Else
       Cells(Lig, 10).Value = F.DateLastModified
     End If
     
     On Error GoTo 0
    Set F = Nothing
  End If

 Next Lig
Set Fs = Nothing

End Sub

 

[youky(BJ)]

Re : Pb sur ma macro

Bonjour
Faut gérer les erreurs

On Error Resume Next 'on gère les erreurs
For Lig = 8 To 10
If Cells(Lig, 2).Value = "1_01_Room-Layout\" Then
FichierATester = [M2] + Cells(Lig, 4) + Cells(Lig, 8)


Set fs = CreateObject("Scripting.FileSystemObject")
Set f = fs.GetFile(FichierATester)
'on test et efface l'error et on va en fin de boucle à saute
If err<>0 then msgbox FichierATester & " Absent" :err.clear:goto saute


Cells(Lig, 10).Value = f.DateLastModified
End If


saute:
Next Lig


Bruno