Pb de formule, besoin d'aide.

[Allan76]

Bonjour,

Je me suis fait un tableau pour calculer les primes d'1 de mes vendeurs en fonction du pourcentage d'écart entre les prévisions et le réalisé.

Les conditions sont :
- Entre -5% et +5% du prév => 1% de la marge
- Entre +5% et +20% du prév => 1.2% de la marge
- Supérieur à 21% du prév => 1.3% de la marge

J'ai fais la formule suivante qui malheureusement ne fonctionne pas :
B12 = % variation de la marge (de -5% à +20%)
B11 = Est la marge en €

=SI(B12>-5%;1%*B11;SI(B12>5%;1,2%*B11;SI(B12>20%;1,3%*B11)))

Le problème que j'ai est que si la variation de la marge est comprise entre -5%et +5% ça fonctionne càd que ma marge est multiplié par 1%. En revanche dès que je dépasse +5% de variation la marge qui devrait être multiplié par mon coeff 1.2% reste tjrs multiplié par 1%.

Merci d'avance pour vos conseils.

 

[minipuce]

Re : Pb de formule, besoin d'aide.

Bonjour,
Il faut borner ta première condition. Comme 10%, 20 % sont au dessus de -5% il considère que la première condition est satisfaite, donc il ne va pas plus loin, et applique les 1%.

Bonne journée
Minipuce

 

[jeanpierre]

Re : Pb de formule, besoin d'aide.

Bonjour Allan76,

Bienvenue sur le forum,

Essaie avec :

=SI(ET(B12<=5%;B12>=-5%);1%*B11;SI(B12<=20%;1,2%*B11;SI(B12>20%;1,3%*B11)) )

Bonne journée.

Jean-Pierre

 

[Allan76]

Re : Pb de formule, besoin d'aide.

Merci à vous 2 de votre réponse rapide :

- @ Minipuce: Borner oui je suis d'accord mais comment faire pour lui faire comprendre que B12 soit compris entre -5% et +5% ?

- @ Jean pierre : Merci beaucoup ta formule fonctionne juste un problème tjrs à peu prêt le même en mettant =SI(B12<=5%;1%*B11.... Si jamais on fait -10% de marge admettons mon vendeur aura qd même droit au 1% alors qu'en temps normal en dessous de -5% il n'a droit à rien.

 

[jeanpierre]

Re : Pb de formule, besoin d'aide.

Re, Minipuce,

As-tu vu ma réédition de 11h53 ?

 

[jeanpierre]

Re : Pb de formule, besoin d'aide.

Re,

On va y arriver. La bonne cette fois (voilà lorsque l'on ne fait pas de test)

=SI(ET(B12<=5%;B12>=-5%);1%*B11;SI(ET(B12>5%;B12<=20%);1,2%*B11;SI(B12>20%;1,3%*B11;"")))

 

[hoerwind]

Re : Pb de formule, besoin d'aide.

Bonjour, salut minipuce et jeanpierre,

A essayer :
=B11*((B12>=-5%)*1%+(B12>=5%)*0.2%+(B12>=21%)*0.1%)

 

[Allan76]

Re : Pb de formule, besoin d'aide.

Merci pour toutes vos réponses rapides.

et surtout à Jean pierre, j'ai repris ta formule et j'y ai ajouté un tout petit truc :

=SI(B12<-5%;0;SI(B12<=5%;1%*B11;SI(B12<=20%;1,2%*B11;SI(B12>20%;1,3%*B11))))

Donc j'ai juste rajouté =SI(B12<-5%;0 ... et voilà le tour est dans le sac !

Merci à vous tous pour vos réponses.

Allan R.

 

[job75]

Re : Pb de formule, besoin d'aide.

Bonjour Allan76, jeanpierre, hoerwind,

Dans le sac aussi :

 =CHOISIR(EQUIV(B12;{-1000000000;-5;5;20}%);0;1;1,2;1,3)*B11%

A+