Pb avec le nom de la table Access

[XanorK]

Bonjour le forum

Je suis en train d'écrire des macro qui récupère des données dans un base access.

Voici mon code :

Sub Import2()
'   Cette démo exige une référence à la
'   biliothèque Microsoft ActiveX Data Objects 2.x
    
    Dim DBFullName As String
    Dim Cnct As String, Src As String, test As String
    Dim Connection As ADODB.Connection
    Dim Recordset As ADODB.Recordset
    Dim Col As Integer

'   Information de base de données
    DBFullName = ThisWorkbook.Path & "\Ma_Base_2006.mdb"
    
'   Ouverture de la connexion
    Set Connection = New ADODB.Connection
    Cnct = "Provider=Microsoft.Jet.OLEDB.4.0; "
    Cnct = Cnct & "Data Source=" & DBFullName & ";"
    Connection.Open ConnectionString:=Cnct
    
'   Création du jeu d'enregistrement
    Set Recordset = New ADODB.Recordset
    With Recordset
'       Filtrage
        Src = "SELECT * FROM & Base Machines WHERE Valider = 'x'"
        .Open Source:=Src, ActiveConnection:=Connection

'       Ecriture des noms de champs
        For Col = 0 To Recordset.Fields.Count - 1
           Range("C1").Offset(0, Col).Value = _
             Recordset.Fields(Col).Name
        Next

'       Ecriture du jeu d'enregistrement
        Range("C1").Offset(1, 0).CopyFromRecordset Recordset
    End With
    Set Recordset = Nothing
    Connection.Close
    Set Connection = Nothing
End Sub

Cela fonctionne parfaitement si la table d'où je tire mes données porte un nom en un seul mot (Base_Machines).
Mon soucis est que je travail avec un table nommée "Base Machines" en 2 mots et qu'Excel me demande de vérifier l'orthographe de la table base.
J'ai pourtant essayer d'entourer le nom de ma table de ( ) , de " " , de ' '


Et vu la taille de la base de données, je ne peut pas renommer la table.


Comment faire admettre à Excel que ma table porte un nom composé ?

Merci de votre aide


XanorK

 

[MichelXld]

Re : Pb avec le nom de la table Access

bonsoir

Place le nom de la table entre crochets, dans ta procedure: [Base Machines]


Autant que possible, il y a des règles à respecter lors de la création d'une table:
Nom le plus court possible
Pas d'espace
Pas d'accent
Pas de caractères spéciaux


bonne soirée
MichelXld

 

[XanorK]

Re : Pb avec le nom de la table Access

bonsoir,

Place le nom de la table entre crochets, dans ta procedure: [Base Machines]

Nickel merci, ca marche enfin !

Nom le plus court possible, Pas d'espace, Pas d'accent, Pas de caractères spéciaux

C'est bien noté pour une prochaine fois


Encore merci Michel