Pas expert du tout: Sommes de lignes sur critères

[sebastienbost@gmail.com]

Bonjour,

Je suis en train de travailler sur une fiche de temps de travail sur l'année (attachée).

J'aimerais faire la somme des heures travaillées normales des jours de la semaines n'incluant pas les weekends, ainsi que la somme des heures supplémentaires de la semaine plus les weekends. Ainsi qu'obtenir le nombre de weekend travaillés.

J'ai essayé de combiner des "sum de Vlookup" mais sans succès ça me donne des erreurs ou les totaux ne sont pas bons.

A little bit of help please!

Sebastien

 

[JBOBO]

Re : Pas expert du tout: Sommes de lignes sur critères

Bonjour,

A placer en J8 par exemple :

=SI(ET($H8<>"";OU(JOURSEM($C8;2)=6;JOURSEM($C8;2)=7));$H8;"")

Pour avoir les heures de week-end uniquement

 

[CISCO]

Re : Pas expert du tout: Sommes de lignes sur critères

Bonjour

En E42, essayes avec

SOMME(SI(H8:H38>C47/24;C47/24;H8:H38)*(JOURSEM(C8:C38;2)<>6)*(JOURSEM(C8:C38;2)<>7))

@ plus

 

[sebastienbost@gmail.com]

Re : Pas expert du tout: Sommes de lignes sur critères

Bonjour,

A placer en J8 par exemple :

=SI(ET($H8<>"";OU(JOURSEM($C8;2)=6;JOURSEM($C8;2)=7));$H8;"")

Pour avoir les heures de week-end uniquement

Merci pour ta réponse, en effet ça me donne les heures pour chaque jour.
Mais comment faire ça en une seule formule en e42 pour tout calculer?

Bonjour

En E42, essayes avec

SOMME(SI(H8:H38>C47/24;C47/24;H8:H38)*(JOURSEM(C8:C38;2)<>6)*(JOURSEM(C8:C38;2)<>7))

@ plus

CISCO, merci pour ta réponse mais la formule traduite en anglais 🙂 me donne une erreur.

=SUM(IF(H8:H38>C47/24,C47/24,H8:H38)*(WEEKDAY(C8:C38,2)<>6)*(WEEKDAY(C8:C38,2)<>7))

 

[CISCO]

Re : Pas expert du tout: Sommes de lignes sur critères

Bonjour

Il s'agit d'une formule matricielle, il faut donc la valider avec ctrl+maj+entrée (essai fait sur la feuille jul).

@ plus

 

[JBOBO]

Re : Pas expert du tout: Sommes de lignes sur critères

Re,

=SOMME(H8:H38*(JOURSEM(C8:C38;2)=6))+SOMME(H8:H38*(JOURSEM(C8:C38;2)=7))

, à valider en matricielle avec Ctrl+maj+entrée

 

[sebastienbost@gmail.com]

Re : Pas expert du tout: Sommes de lignes sur critères

Re- bonjour,

Merci, beaucoup, j'ai finalement réussi a valider les formules.

La question qui se pose a moi, et comment calculer le nombre de weekend travaillés a partir de la meme feuille excel (ex: august).

Cordialement,

Sebastien

 

[CISCO]

Re : Pas expert du tout: Sommes de lignes sur critères

Bonsoir à tous

Qu'est-ce que tu veux exactement, le nombre d'heures travaillées le week end, ou le nombre de jours travaillés le week end (tout samedi ou dimanche entamé comptant pour un jour) ?

Dans le premier cas, essayes avec

=SOMME((H8:H38)*(JOURSEM(C8:C38;2)=6);(H8:H38)*(JOURSEM(C8:C38;2)=7))

Dans le second cas, tu peux faire avec

SOMME((H8:H38<>0)*(JOURSEM(C8:C38;2)=6);(H8:H38<>0)*(JOURSEM(C8:C38;2)=7))

en adaptant le format en conséquence


@ plus

 

[sebastienbost@gmail.com]

Re : Pas expert du tout: Sommes de lignes sur critères

CISCO,

Merci d'avoir pris le temps de me répondre.
Laisse moi donc développer un peu les choses.
J'aurais voulu avoir le nombre de weekend travaillés dans le mois, par exemple 4 pour le mois août.
On compte un weekend travaillé si samedi ou dimanche ou les 2, la personne est venue travailler.


Merci.

Seb

 

[CISCO]

Re : Pas expert du tout: Sommes de lignes sur critères

Bonjour

Essayes en E44 de la feuille August avec

=SOMME(SI(JOURSEM(C8:C38;2)*(H8:H38<>0)=6;1*(H8:H38<>0);SI(JOURSEM(C9:C39;2)*(H9:H39<>0)=7;1*(H9:H39<>0))))

à valider en matriciel (ctrl+maj+entrer).

Reste plus qu'à vérifier 😎

@ plus