Ouvrir feuille excel en bas à droite de l'écran

[apnart]

Bonjour,

J'ai actuellement le code suivant qui me permet d'ouvrir un fichier excel en haut à gauche de l'écran :

Private Sub Workbook_Open()
With Application
  .WindowState = xlNormal
  .Top = 0
  .Width = 690
  .Left = 0
  .Height = 550
End With
End Sub

J'essaie de modifier ce code pour ouvrir en bas à droite... mais j'y arrive pas...

J'ai cherché sur le forum et trouvé des codes comme ci-dessous, mais ça ne fonctionne pas pour moi, je crois qu'ils étaient dédiés à des userforms

.Left = Application.UsableWidth - .Width
.Top = Application.UsableHeight - .Height
 
.Left = Application.Width - (.Width + 10)

Vous auriez des idées ?

Merci d'avance
Bruno. 😎

 

[Guest]

Re : Ouvrir feuille excel en bas à droite de l'écran

Bonjour,

Dans ton message tu ne sembles pas faire la différence entre la fenêtre de l'application et la fenêtre du classeur (fenêtre contenue dans la fenêtre de l' application).

Dans la macro suivante c'est la fenêtre de l'application (excel) qui est positionnée en bas à droite.

Sub BasDroit()
    Dim Wt As Single
    Dim Ht As Single
    Dim mActiveWindowState As Single
    Dim dif As Single
    With Application
        .ScreenUpdating = False
        With .ActiveWindow 'Concerne la fenêtre du classeur
            'conserver l'état d'origine de la fenêtre du classeur
            mActiveWindowState = .WindowState
            .WindowState = xlMaximized
            'Quand la fenêtre du classeur est maximisée,  sa propriété left est négative
            'la valeur représente la largeur de la bordure de l'application. 
            dif = ActiveWindow.Left * 2

            'rétablir l'état d'origine de la fenêtre du classeur
            .WindowState = mActiveWindowState
        End With
        'Agrandir provisoirement la fenêtre de l'application
        'pour en retenir les dimensions maximales
        .WindowState = xlMaximized
        
        Wt = .Width
        Ht = .Height
        
        .WindowState = xlNormal
        
        .Width = 690
        .Height = 550
        
        .Left = Wt - .Width + dif
        .Top = Ht - .Height + dif
        
        .ScreenUpdating = True
    End With
End Sub

A+

 

[apnart]

Re : Ouvrir feuille excel en bas à droite de l'écran

MERCI BEAUCOUP HASCO 🙂

C'est exactement ce que je cherchais.