Nommer une cellule automatiquement selon le nom du document excel

  • Initiateur de la discussion Seb
  • Date de début
S

Seb

Guest
Bonjour

J'aimerais savoir comment donner comme valeur a une cellule le nom du document Excel.
Merci
 
S

Stéphane

Guest
ces infos étaient dans <http://xlbysteph.free.fr/aideinformatique/actionnom.htm>

et aussi dans <http://xlbysteph.free.fr/aideinformatique/actionfichier.htm> dans la partie "noms"


Insérer le nom du fichier et de l'onglet

1ère méthode : écrivez les fonctions ci-dessous suivantes dans une feuille de code, vous pouvez alors sélectionner ces deux fonctions dans le menu "fx" à "fonctions personnalisées".

function nomOnglet()
nomOnglet = activesheet.name
end function

function nomFichier()
nomFichier = activeworkbook.name
end function

Nom du classeur : activeworkbook.name
Nom complet du classeur : activeworkbook.fullname

2ème méthode : par l'intermédiaire de formules "existantes" toutes très longues et toutes valables !!

1. Chemin d'accès complet : "C:\Temp[Test.xls]Feuil1"
=CELLULE("filename";A1)

2. Répertoire : "C:\Temp"
=GAUCHE(CELLULE("filename";A1);TROUVE("[";CELLULE("filename";A1))-2)

3. Nom du classeur seul : "Test.xls"
=STXT(CELLULE("filename";A1);TROUVE("[";CELLULE("filename";A1))+1;
SOMME(TROUVE({"[";"]"};CELLULE("filename";A1))*{-1;1})-1)

4. Nom de la feuille : "Feuil1"
=STXT(CELLULE("filename";A1);TROUVE("]";CELLULE("filename";A1))+1;32)
=STXT(CELLULE("filename";A62);TROUVE("]";CELLULE("filename";A62))+1;NBCAR(CELLULE("filename";A62))-TROUVE("]";CELLULE("filename";A62)))

5. Répertoire + classeur : "C:\Temp\Test.xls"
=SUBSTITUE(GAUCHE(CELLULE("filename";A1);TROUVE("]"; CELLULE("filename";A1))-1);"[";"")

6. Nom du classeur et de la feuille : "[Test.xls]Feuil1"
=STXT(CELLULE("filename";A1);TROUVE("[";CELLULE("filename";A1));300)
 

Discussions similaires

Statistiques des forums

Discussions
302 316
Messages
2 002 492
Membres
215 621
dernier inscrit
jules56750