Ne pas affiché le quadrillage

[djevilic]

Bonjour à tous,
Voila j'ai un gros soucis pour une macro qui me permet a l'aide d'un fichier excel de récupérer un tableau pour le coller en format bitmap dans un fichier word avec une laison permanente entre ses 2 fichiers.
Le soucis c'est que j'ai un problème pour ne plus affiché quadrillage sur le fichier excel.
Voici le code:
Sub Macro1()
'
' Macro1 Macro
' Macro enregistrée le 26/06/2008 par e_bmagna
'
'necessite d'activer la reference Microsoft Excel xx.x Object Library
'dans l'editeur de macros de word
'Menu Outils
'References
'coches la ligne "Microsoft Excel xx.x Object Library"
'Cliques sur OK pour valider
'
Dim Fichier As String, path As String
Dim AppXl As Excel.Application
Dim Wbexcel As Excel.Workbook

path = ActiveDocument.path & "\"

'Recherche du fichier excel
Fichier = Dir(path & "*.xls")
Do While Fichier <> ""
If Left(Fichier, 17) = "E_S UTR RGV 2N2_2" Then Exit Do
Fichier = Dir
Loop

'ouverture classeur Excel
Set AppXl = CreateObject("Excel.Application")
AppXl.Visible = False 'mettre False pour qu'Excel reste masqué
Set Wbexcel = AppXl.Workbooks.Open("D:\DATA\RVG_2N2\A travailler\SF_2N2_CMD0000128384_10-5278 648_Liste ES UTR\Ind A en cours\E_S UTR RGV 2N2_2")


'copie plage de cellule Excel

'on enlève le quadrillage
Wbexcel.Sheets("§ 2").DisplayGridLines = Not (Wbexcel.Sheets("§ 2").DisplayGridLines)
'Copie les cellules sélectionnées dans la feuille.
Wbexcel.Sheets("§ 2").Range("A1:R16").Copy

'collage dans le document Word

Selection.Collapse Direction:=wdCollapseStart
Windows("Document1").Activate
ActiveDocument.Range.PasteSpecial Link:=True, DataType:=wdPasteBitmap
'Special DataType:=wdPasteText


AppXl.CutCopyMode = False
'Wbexcel.Close True 'fermeture du classeur en sauvegardant les modifications
'AppXl.Quit

' If Options.CheckGrammarWithSpelling = True Then
' ActiveDocument.CheckGrammar
' Else
' ActiveDocument.CheckSpelling
' End If



End Sub

Merci de m'aider!!!!

 

[Staple1600]

Re : Ne pas affiché le quadrillage

Bonsoir

Pour test

Sub Macro1()
Sheets(1).Activate
ActiveWindow.DisplayGridlines = Not ActiveWindow.DisplayGridlines
End Sub

 

[BERRACHED said]

Re : Ne pas affiché le quadrillage

Salut,djevilic et bienvenue

Essaie dans le fichier excel Menu : Outil désactive la case a cocher quadrillage
puis exécute ta macro comme ca ton tableau ce collera en word sans quadrillage

Cordialement

 

[djevilic]

Re : Ne pas affiché le quadrillage

Merci de vos remarques pour ce qui concerne ta réponse Staple1600 j'ai essayé de l'intégrer mais ca ne marche toujours pas.
Pour ta réponse je te remercie mais j'y avais penser sauf que le document excel en question est un fichiers de travail et les personnes qui s'en serve on besoin du quadrillage et si je leur dis qu'il faut avant de faire une mise a jour enlever le quadrillage je suis sur a 90% que la mise a jour sera faite avec le quadrillage!!!
C'est pourquoi j'insiste sur le fait que la macro desactive le quadrillage durant la mise a jour.

 

[Staple1600]

Re : Ne pas affiché le quadrillage

Re


Il fallait adapter avec le nom de la feuille
Sub Macro1()
Sheets("§ 2").Activate
ActiveWindow.DisplayGridlines = Not ActiveWindow.DisplayGridlines
End Sub


Dans ta macro
'on enlève le quadrillage
Wbexcel.Sheets("§ 2").Activate
ActiveWindow.DisplayGridlines = Not ActiveWindow.DisplayGridlines

 

[djevilic]

Re : Ne pas affiché le quadrillage

Voici le message que j'obtiens en mettant le bon nom de feuille:
Erreur d'exécution '424':
Objet requis

 

[djevilic]

Re : Ne pas affiché le quadrillage

J'ai une erreur de compilation maintenant:
Membre de méthode ou de donnée introuvable

 

[Staple1600]

Re : Ne pas affiché le quadrillage

Re


OK voila la solution


AppXl.ActiveWindow.DisplayGridLines = False
Wbexcel.Sheets("§ 2").Range("A1:R16").Copy


Test OK avec cette macro
Sub Macro1_test()
'macro lancée à partir de Word
'ca peut être utile de le préciser 😉
'necessite d'activer la reference Microsoft Excel xx.x Object Library
'dans l'editeur de macros de word
'Menu Outils|References|coches la ligne "Microsoft Excel xx.x Object Library"
'Cliques sur OK pour valider
'Dim Fichier As String, path As String
Dim AppXl As Excel.Application
Dim Wbexcel As Excel.Workbook
Set AppXl = CreateObject("Excel.Application")
AppXl.Visible = False 'mettre False pour qu'Excel reste masqué
Set Wbexcel = AppXl.Workbooks.Open("C:\Temp\12.xls")
AppXl.ActiveWindow.DisplayGridLines = False
Wbexcel.Sheets("§ 2").Range("A1:R16").Copy
'collage dans le document Word
Selection.Collapse Direction:=wdCollapseStart
Windows("Document1").Activate
ActiveDocument.Range.PasteSpecial Link:=True, DataType:=wdPasteBitmap
AppXl.CutCopyMode = False
End Sub

 

[djevilic]

Re : Ne pas affiché le quadrillage

Cool ca marche trop trop bien ca fais 2 jours que je planche dessus merci beaucoup
Je vais pouvoir lancé cette macro!!!!!