NB.SI uniquement dans certaines cellules

JNP

XLDnaute Barbatruc

• 3 Septembre 2010

• #2

Re : NB.SI uniquement dans certaines cellules

Bonjour Marly 971 🙂,

Code:

=NB.SI(A1;3)+NB.SI(A4;3)+NB.SI(A6;3)+NB.SI(A12;3)+NB.SI(A19;3)

par exemple 😉.
Bonne journée 😎

 

Vote positif 0 Vote négatif

Tibo

XLDnaute Barbatruc

• 3 Septembre 2010

• #3

Re : NB.SI uniquement dans certaines cellules

Bonjour Marly et bienvenue sur XLD, salut Jean-Noel,

Un essai avec SOMMEPROD :

Code:

=SOMMEPROD(NB.SI(INDIRECT("A"&{1;4;6;12;19});3))

A tester en grand quand même

@+

 

Vote positif 0 Vote négatif

M

Marly_971

Guest

• 3 Septembre 2010

• #4

Re : NB.SI uniquement dans certaines cellules

JNB c tellement élémentaire!!😀 comment n'y ai je pas pensé!!
Elle peut etre longue cette formule par contre, s'il y a bien plus de cellules..
mais merci!🙂

Tibo, merci pour cette formule.. et si les cellules etaient A1, B1, D1, G1 et L1, quelle serait la formule stp? 😉

Merci ts les deux pour votre efficacité et rapidité..
bonne journée😉

 

Vote positif 0 Vote négatif

Tibo

XLDnaute Barbatruc

• 3 Septembre 2010

• #5

Re : NB.SI uniquement dans certaines cellules

re,

La formule devient :

Code:

=SOMMEPROD(NB.SI(INDIRECT({"A";"B";"D";"G";"L"}&1);3))

En mettant les références de cellules dans une plage de cellules (C2:C6 par exemple), la formule devient :

Code:

=SOMMEPROD(NB.SI(INDIRECT(C2:C6);3))

Je te laisse tester

@+

 

Vote positif 0 Vote négatif

H

hoerwind

XLDnaute Barbatruc

• 3 Septembre 2010

• #6

Re : NB.SI uniquement dans certaines cellules

Bonjour, salut les autres,

Il y a aussi :
=(A1=3)+(A4=3)+(A6=3)+(A12=3)+(A19=3)

ou:
=(A1=3)+(B1=3)+(D1=3)+(G1=3)+(L1=3)

 

Vote positif 0 Vote négatif

M

Marly_971

Guest

• 3 Septembre 2010

• #7

Re : NB.SI uniquement dans certaines cellules




Merci Tibo et Hoerwind, ttes ces formules testées fonctionnent... bravo et mille mercis 🙂

 

Vote positif 0 Vote négatif

J

JHA

XLDnaute Barbatruc

• 3 Septembre 2010

• #8

Re : NB.SI uniquement dans certaines cellules

Bonjour,

Pour compléter, ci joint une autre solution par fonction personnalisée code provenant du forum

JHA

 

Pièces jointes

• nbsi plage discontinue.xlsm

  15.2 KB · Affichages: 58
• nbsi plage discontinue.xls

  34.5 KB · Affichages: 84

Vote positif 0 Vote négatif

H

hoerwind

XLDnaute Barbatruc

• 3 Septembre 2010

• #9

Re : NB.SI uniquement dans certaines cellules

Re, salut JHA,

Il y a aussi :
=NBCAR(A1&A4&A6&A12&A19)-NBCAR(SUBSTITUE(A1&A4&A6&A12&A19;3;""))

Edition :
Cette formule compte bien 33 pour deux unités !

 

Dernière édition: 3 Septembre 2010

Vote positif 0 Vote négatif

M

Marly_971

Guest

• 7 Septembre 2010

• #10

Re : NB.SI uniquement dans certaines cellules

Bonjour 😉
J ai encore besoin de votre aide, svp.
Je cherche parmi les cellules
A1, B1, D1, G1, L1
A2, B2, D2, G2, L2
A4, B4, D4, G4, L4
A8, B8, D8, G8, L8
combien possèdent le nombre 3?(en utilisant la formule donnée par TIBO)

J 'ai essayé celle-ci =SOMMEPROD(NB.SI(INDIRECT({"A";"B";"D";"G";"L"}&{"1";"2";"4";"8"});3)) mais cela ne fonctionne pas🙄
Merci

 

Vote positif 0 Vote négatif

JBOBO

XLDnaute Accro

• 7 Septembre 2010

• #11

Re : NB.SI uniquement dans certaines cellules

Bonjour,

Peut-etre comme ceci?

=SOMMEPROD(NB.SI(INDIRECT("A"&{1;4;6;12;19});3))+SOMMEPROD(NB.SI(INDIRECT("B"&{1;4;6;12;19});3))+SOMMEPROD(NB.SI(INDIRECT("D"&{1;4;6;12;19});3))+SOMMEPROD(NB.SI(INDIRECT("G"&{1;4;6;12;19});3))+SOMMEPROD(NB.SI(INDIRECT("L"&{1;4;6;12;19});3))

Bonjour à tout le forum

 

Vote positif 0 Vote négatif

BOISGONTIER

XLDnaute Barbatruc

Repose en paix

• 7 Septembre 2010

• #12

Re : NB.SI uniquement dans certaines cellules

Bonjour,

Code:

=SOMMEPROD(NB.SI(DECALER(INDIRECT({"A1";"B1";"D1";"G1";"L1"});{0.1.3.7};);3))

{0.1.3.7} --> vecteur colonne

DECALER(référence;décalageNbLignes;décalageNbColonnes;hauteur;largeur)


JB
http://boisgontierjacques.free.fr/

 

Pièces jointes

• Classeur1.xls

  15 KB · Affichages: 66
• Classeur1.xls

  15 KB · Affichages: 70
• Classeur1.xls

  15 KB · Affichages: 70

Dernière édition: 7 Septembre 2010

Vote positif 0 Vote négatif

M

Marly_971

Guest

• 7 Septembre 2010

• #13

Re : NB.SI uniquement dans certaines cellules

Jbobo, merci j 'y avais pensé mais je la trouve un peu longue cette formule, mais merci tt de même 🙂
Boisgontier, whoooou merci!! cela fait une demi-heure que j essaye de comprendre ta formule pour enfin comprendre que l'accolade {0.1.3.7} + 1 unité à cahque nombre me donne mes lignes 1;2;4;8 ( c certainement le sens de la fonction DECALER que l on retrouve dans la formule(?))
merci bcp 😉

 

Dernière modification par un modérateur: 7 Septembre 2010

Vote positif 0 Vote négatif

M

Marly_971

Guest

• 7 Septembre 2010

• #14

Re : NB.SI uniquement dans certaines cellules

J'ai utilisé la formule pour savoir combien y a t-il de " 1" dans les cases
D;F;H;J;L;N;P;R;T;V;X;Z;AB;AD;AF;AH;AJ;AL;AN;AP;AR;AT;AV;AX;AZ;BB;BD;BF;BH
des lignes 15 à 17 et 22 à 33
Par analogie avec la formule donnée par Boisgontier, ma formule est

=SOMMEPROD(NB.SI(DECALER(INDIRECT({"D15";"F15";"H15";"J15";"L15";"N15";"P15";"R15";"T15";"V15";"X15";"Z15";"AB15";"AD15";"AF15";"AH15";"AJ15";"AL15";"AN15";"AP15";"AR15";"AT15";"AV15";"AX15";"AZ15";"BB15";"BD15";"BF15";"BH15"});{14.15.16.21.22.23.24.25.26.27.28.29.30.31.32}; );1))



or pour verifier j'ai compté le nombre de cellules et je ne trouve par le même résultat 🙁

 

Vote positif 0 Vote négatif

Tibo

XLDnaute Barbatruc

• 7 Septembre 2010

• #15

Re : NB.SI uniquement dans certaines cellules

Bonjour,

Essaye en remplaçant les 15 (dans D15, F15, ...) par 1 (D1, F1, ...

Dans le DECALER, le 14 correspond au nombre de lignes à décaler vers le bas. La ligne 1 + 14 lignes donne la ligne 15.

Ou alors, tu conserves les 15, mais tu remplaces 14 par 0, 15 par 1, ... (cette solution est sans doute moins lisible).

Je te laisse essayer

@+

 

Vote positif 0 Vote négatif