Moyenne.si.ens avec cellules vides, différentes colonnes et différentes feuilles

job75

XLDnaute Barbatruc

• 15 Février 2020

• #2

Bonjour Edwing, bienvenue sur XLD,

Formule en D1 du fichier joint :

Code:

=SOMMEPROD((A1:A19+B1:B19>=1990)*(A1:A19+B1:B19<=1993);C1:C19)/SOMMEPROD((A1:A19+B1:B19>=1990)*(A1:A19+B1:B19<=1993))

A+

 

Pièces jointes

• test-edwin(1).xlsx

  9.9 KB · Affichages: 3

Vote positif 0 Vote négatif

E

EdwinG

XLDnaute Nouveau

• 15 Février 2020

• #3

Merci pour votre aide.

J'avais vu que cette forme existait mais je ne me sentais pas encore capable de l'utiliser.

Après avoir modifié les colonnes pour les faire correspondre à mon analyse, j'ai un retour #valeur!

En effet, j'ai renseigné :
=SOMMEPROD((Réponses!$L:$L+Réponses!$U:$U+Réponses!$AG:$AG+Réponses!$AP:$AP>=2015);IE!Q:Q)/SOMMEPROD(Réponses!$L:$L+Réponses!$U:$U+Réponses!$AG:$AG+Réponses!$AP:$AP>=2015)
Car j'ai 4 métiers différents sur une feuille "Réponses" et ai une colonne Q avec les scores à faire correspondre sur une feuille "IE" (ie en majuscule).

Merci encore.

 

Vote positif 0 Vote négatif

job75

XLDnaute Barbatruc

• 15 Février 2020

• #4

Les plages doivent être toutes dans la même feuille !

Et elles ne doivent pas être illimitées.

 

Vote positif 0 Vote négatif

excfl

XLDnaute Barbatruc

• 15 Février 2020

• #5

Bonjour le forum, job75

VB:

=(SOMME.SI.ENS(C1:C19;A1:A19;">0";A1:A19;"<1994";A1:A19;">1989")+SOMME.SI.ENS(C1:C19;B1:B19;">0";B1:B19;"<1994";B1:B19;">1989"))/NB.SI.ENS(A1:B19;">1989";A1:B19;"<1994")

 

Vote positif 0 Vote négatif

E

EdwinG

XLDnaute Nouveau

• 15 Février 2020

• #6

Bonsoir,

Merci pour vos propositions.

J'ai essayé ceci :
=(SOMME.SI.ENS(Q:Q;Réponses!$L:$L;">=2015")+SOMME.SI.ENS(Q:Q;Réponses!$U:$U;">=2015")+SOMME.SI.ENS(Q:Q;Réponses!$AG:$AG;">=2015")+SOMME.SI.ENS(Q:Q;Réponses!$AP:$AP;">=2015"))/NB.SI.ENS(Réponses!$L:$L;">=2015";Réponses!$U:$U;">=2015";Réponses!$AG:$AG;">=2015";Réponses!$AP:$AP;">=2015")

Q:Q étant les scores
L:L / U:U / AG:AG / AP:AP étant les métiers se trouvant dans la feuille Réponses

Cela me renvoie un #DIV/0!

Merci encore job75 et excfl

 

Vote positif 0 Vote négatif

E

EdwinG

XLDnaute Nouveau

• 15 Février 2020

• #7

Re.

J'ai modifié le dénominateur dans la fraction; ce qui donne :

=(SOMME.SI.ENS(Q:Q;Réponses!$L:$L;">=2015")+SOMME.SI.ENS(Q:Q;Réponses!$U:$U;">=2015")+SOMME.SI.ENS(Q:Q;Réponses!$AG:$AG;">=2015")+SOMME.SI.ENS(Q:Q;Réponses!$AP:$AP;">=2015"))/(NB.SI(Réponses!$L:$L;">=2015")+NB.SI(Réponses!$U:$U;">=2015")+NB.SI(Réponses!$AG:$AG;">=2015")+NB.SI(Réponses!$AP:$AP;">=2015"))

À voir ce que ça donnera lorsque je passerai sur la tranche des années "<2015" et ">=2010".

Vous avez des conseils ?

Merci.

 

Vote positif 0 Vote négatif

E

EdwinG

XLDnaute Nouveau

• 16 Février 2020

• #8

Je mets en **Résolu**.

En effet, avec un intervalle un intervalle en année, j'ai simplement dû modifier le dénominateur avec la fonction NB.SI.ENS; ce qui donne :

=(SOMME.SI.ENS(Q:Q;Réponses!$L:$L;"<2015";Réponses!$L:$L;">=2010")+SOMME.SI.ENS(Q:Q;Réponses!$U:$U;"<2015";Réponses!$U:$U;">=2010")+SOMME.SI.ENS(Q:Q;Réponses!$AG:$AG;"<2015";Réponses!$AG:$AG;">=2010")+SOMME.SI.ENS(Q:Q;Réponses!$AP:$AP;"<2015";Réponses!$AP:$AP;">=2010"))/(NB.SI.ENS(Réponses!$L:$L;"<2015";Réponses!$L:$L;">=2010")+NB.SI.ENS(Réponses!$U:$U;"<2015";Réponses!$U:$U;">=2010")+NB.SI.ENS(Réponses!$AG:$AG;"<2015";Réponses!$AG:$AG;">=2010")+NB.SI.ENS(Réponses!$AP:$AP;"<2015";Réponses!$AP:$AP;">=2010"))

Merci pour votre aide précieuse !!

 

Vote positif 0 Vote négatif