modifier un lien hypertext

[quicky]

Bonjour,
Afin de rendre plus le simple un téléchargement je voudrais faire un petit fichier excel qui modifie la date du lien pour récupérer la dernière photo sat.

je n'arrive pas a modifier la date dans le lien que voici:
http://www.sat.dundee.ac.uk/geobrow...10&month=9&day=28&slot=900&ch=2&size=2&grid=0

cela est il possible?

Merci

Q

 

[job75]

Re : modifier un lien hypertext

Bonjour quicky, bienvenue sur XLD,

A priori, il devrait suffire d'entrer dans une cellule la formule :

=LIEN_HYPERTEXTE("http://www.sat.dundee.ac.uk/geobrowse/geobrowse.php?sat=4&year=[COLOR="Red"]"&ANNEE(AUJOURDHUI())&"[/COLOR]&month=[COLOR="red"]"&MOIS(AUJOURDHUI())&"[/COLOR]&day=[COLOR="red"]"&JOUR(AUJOURDHUI())&"[/COLOR]&slot=900&ch=2&size=2&grid=0";"photo sat")

qui donnerait la photo de la date renvoyée par la fonction AUJOURDUI().

Mais y a-t-il une seule photo par jour ?

S'il y en a plusieurs, alors je ne sais pas comment modifier l'adresse du lien 😱

Edit : si vous avez une version anglaise d'Excel, utilisez la formule :

=HYPERLINK("http://www.sat.dundee.ac.uk/geobrowse/geobrowse.php?sat=4&year="&YEAR(TODAY())&"&month="&MONTH(TODAY())&"&day="&DAY(TODAY())&"&slot=900&ch=2&size=2&grid=0","photo sat")

A+

 

[quicky]

Re : modifier un lien hypertext

Bonjour,
Merci beaucoup pour votre aide.
Effectivement il y a plusieurs fichier par jour, le "slot=900" correspond à un fichier de 9H TU

comment lui dire (peut être dans une cellule a part)
si heure>6h et <9H alors=600
sinon
si heure>9H et <12H alors=900
ect

Merci encore pour votre aide

Q

 

[job75]

Re : modifier un lien hypertext

Re,

Il suffisait de connaître la signification de "slot" 🙄

Donc en utilisant les fonctions EQUIV() HEURE() MAINTENANT() ainsi que la matrice {0;3;6;9;12;15;18;21} :

=LIEN_HYPERTEXTE("http://www.sat.dundee.ac.uk/geobrowse/geobrowse.php?sat=4&year="&ANNEE(AUJOURDHUI())&"&month="&MOIS(AUJOURDHUI())&"&day="&JOUR(AUJOURDHUI())&"&slot=[COLOR="red"]"&100*EQUIV(HEURE(MAINTENANT());{0;3;6;9;12;15;18;21})&"[/COLOR]&ch=2&size=2&grid=0";"photo sat")

Version anglaise :

=HYPERLINK("http://www.sat.dundee.ac.uk/geobrowse/geobrowse.php?sat=4&year="&YEAR(TODAY())&"&month="&MONTH(TODAY())&"&day="&DAY(TODAY())&"&slot="&100*MATCH(HOUR(NOW()),{0;3;6;9;12;15;18;21})&"&ch=2&size=2&grid=0","photo sat")

A+

 

[job75]

Re : modifier un lien hypertext

Re,

Les dernières formules sont erronées, il faut remplacer EQUIV par RECHERCHE :

=LIEN_HYPERTEXTE("http://www.sat.dundee.ac.uk/geobrowse/geobrowse.php?sat=4&year="&ANNEE(AUJOURDHUI())&"&month="&MOIS(AUJOURDHUI())&"&day="&JOUR(AUJOURDHUI())&"&slot="&100*RECHERCHE(HEURE(MAINTENANT());{0;3;6;9;12;15;18;21})&"&ch=2&size=2&grid=0";"photo sat")

=HYPERLINK("http://www.sat.dundee.ac.uk/geobrowse/geobrowse.php?sat=4&year="&YEAR(TODAY())&"&month="&MONTH(TODAY())&"&day="&DAY(TODAY())&"&slot="&100*LOOKUP(HOUR(NOW()),{0;3;6;9;12;15;18;21})&"&ch=2&size=2&grid=0","photo sat")

A+

 

[quicky]

Re : modifier un lien hypertext

Merci beaucoup pour votre aide tout fonctionne

Q

 

[job75]

Re : modifier un lien hypertext

Re,

Ah la barbe, je suis allé chercher midi à quatorze heure avec la matrice 😡

Il suffit d'utiliser l'expression 300*ENT(HEURE(MAINTENANT())/3).

Donc utiliser :

=LIEN_HYPERTEXTE("http://www.sat.dundee.ac.uk/geobrowse/geobrowse.php?sat=4&year="&ANNEE(AUJOURDHUI())&"&month="&MOIS(AUJOURDHUI())&"&day="&JOUR(AUJOURDHUI())&"&slot="&300*ENT(HEURE(MAINTENANT())/3)&"&ch=2&size=2&grid=0";"photo sat")

ou :

=HYPERLINK("http://www.sat.dundee.ac.uk/geobrowse/geobrowse.php?sat=4&year="&YEAR(TODAY())&"&month="&MONTH(TODAY())&"&day="&DAY(TODAY())&"&slot="&300*INT(HOUR(NOW())/3)&"&ch=2&size=2&grid=0","photo sat")

A+

 

[quicky]

Re : modifier un lien hypertext

Merci beaucoup pour votre aide
tout fonctionne

Q

 

[job75]

Re : modifier un lien hypertext

Re encore...

Attention ! Pour que l'heure soit la bonne, il faut régler l'heure système de votre ordi sur le Temps Universel (TU).

Sinon retrancher le nombre d'heures nécessaires à HEURE(MAINTENANT()), en tenant compte de l'heure d'été ou d'hiver.

A+