XL 2010 Modifier les références d'une sélection multizones déjà nommée.

[ChRouan]

Bonjour.
Je souhaite modifier via Visual Basic les références d'un objet Range nommé "Legende01" comprenant plusieurs zones (cellules bleu clair du fichier joint) afin d'y ajouter les cellules C11:E11 (cellule rose).
Le but, par la suite, est de modifier les attributs de la légende (police, couleur de fond,...) et que cela se répercute sur toutes les activités (voir exemple simplifié en Macro1)
Merci d'avance pour votre aide.

 

[vgendron]

Hello

une proposition à adapter.. ou pas..

Sub Macro2()
Dim AddZone As Range
    With ActiveWorkbook
        ZoneInit = .Names("Legende01").RefersTo 'récupère la cible actuelle'
        Set AddZone = Application.InputBox("Selectionnez la plage à ajouter", Type:=8) 'demande la zone à ajouter'
        NewZone = ZoneInit & "," & AddZone.AddressLocal(, , , True, True) 'Définit la nouvelle cible'
        Names("Legende01").RefersToLocal = NewZone 'applique la nouvele cible'
    End With
End Sub

 

[ChRouan]

Hello

une proposition à adapter.. ou pas..

Sub Macro2()
Dim AddZone As Range
    With ActiveWorkbook
        ZoneInit = .Names("Legende01").RefersTo 'récupère la cible actuelle'
        Set AddZone = Application.InputBox("Selectionnez la plage à ajouter", Type:=8) 'demande la zone à ajouter'
        NewZone = ZoneInit & "," & AddZone.AddressLocal(, , , True, True) 'Définit la nouvelle cible'
        Names("Legende01").RefersToLocal = NewZone 'applique la nouvele cible'
    End With
End Sub

Merci, c'est exactement ce qu'il me fallait.
Je n'avais jamais exploré les propriétés RefersTo, RefersToLocal et AddressLocal.

 

[Dranreb]

Boujour.
Sinon ceci fait aussi le taf :

Sub UnirSelectionÀLegende01()
   ThisWorkbook.Names.Add "Legende01", Union([Legende01], Selection)
   End Sub

En effet Excel calcule la référence correspondant à un objet spécifié en tant que RefersTo si ce n'est pas un String.

 

[ChRouan]

Boujour.
Sinon ceci fait aussi le taf :

Sub UnirSelectionÀLegende01()
   ThisWorkbook.Names.Add "Legende01", Union([Legende01], Selection)
   End Sub

En effet Excel calcule la référence correspondant à un objet spécifié en tant que RefersTo si ce n'est pas un String.

En effet ça marche aussi, merci.
En revanche existe-t-il un moyen de retirer une plage de cellules ? Si on le fait directement (ex : supprimer la ligne) le nom "Legende01" disparait de la feuille. J'ai cherché l'équivalent de la propriété Add (ex : Remove) mais je n'ai rien trouvé.

 

[Dranreb]

Je pense que c'est un peu plus compliqué. Mais on devrait pouvoir explorer les Areas de la plage d'origine et unir à un nouveau Range ceux qui n'ont pas d'intersection avec la plage sélectionnée …

 

[Dranreb]

Le code :

Sub SupprSelectionDeLegend01()
   Dim Zone As Range, RngRésu As Range
   For Each Zone In [Legende01].Areas
      If Intersect(Selection, Zone) Is Nothing Then
         If RngRésu Is Nothing Then Set RngRésu = Zone Else Set RngRésu = Union(RngRésu, Zone)
         End If
      Next Zone
   ThisWorkbook.Names.Add "Legende01", RngRésu
   End Sub

 

[ChRouan]

Le code :

Sub SupprSelectionDeLegend01()
   Dim Zone As Range, RngRésu As Range
   For Each Zone In [Legende01].Areas
      If Intersect(Selection, Zone) Is Nothing Then
         If RngRésu Is Nothing Then Set RngRésu = Zone Else Set RngRésu = Union(RngRésu, Zone)
         End If
      Next Zone
   ThisWorkbook.Names.Add "Legende01", RngRésu
   End Sub

Bon sang mais c'est bien sur ! On reconstruit la référence à partir des zones non sélectionnées, donc on exclut de fait la sélection.
Bravo pour la réactivité et merci.
J'ai encore découvert une nouvelle fonction ; Intersect.
Encore merci.👍