Modification SOMMEPROD

[criscris11]

Hello le forum,
Dans cette formule :
=SOMMEPROD((PERMS!$B$3:$B$130="S/OFF")*(PERMS!$I$3:$I$130="")*('ETAT MILIT'!$AA$3:$AA$130="M")*('ETAT MILIT'!$Z$3:$Z$130=C6))
mais j'aimerais modifier cette condition comme suit :
il faut comptabiliser SI(PERMS!$I$3:$I$130="") et SI((PERMS!$I$3:$I$130>AUJOURDHUI()).
En écrivant ainsi =SOMMEPROD((PERMS!$B$3:$B$130="S/OFF")*(PERMS!$I$3:$I$130="")*(PERMS!$I$3:$I$130>AUJOURDHUI())*('ETAT MILIT'!$AA$3:$AA$130="M")*('ETAT MILIT'!$Z$3:$Z$130=C6))
j'obtiens 0.

Comment écrire cette nouvelle condition ?
Bonne soirée.

 

[kjin]

Re : Modification SOMMEPROD

bnonsoir,
Il me semble qu'il faut sommer tes plages avec le premier critère puis avec le second, soit
=SOMMEPROD((PERMS!$B$3:$B$130="S/OFF")*(PERMS!$I$3:$I$130="")*('ETAT MILIT'!$AA$3:$AA$130="M")*('ETAT MILIT'!$Z$3:$Z$130=C6)+(PERMS!$B$3:$B$130="S/OFF")*(PERMS!$I$3:$I$130>AUJOURDHUI())*('ETAT MILIT'!$AA$3:$AA$130="M")*('ETAT MILIT'!$Z$3:$Z$130=C6))
En nommant les plages ce serait plus simple 😱
A+
kjin

 

[criscris11]

Re : Modification SOMMEPROD

Bonsoir kjin,
Merci pour ta réponse mais j'obtiens toujours 0 même en nommant les plages. Je continue de chercher.
Bonne nuit.

 

[jeanpierre]

Re : Modification SOMMEPROD

Bonsoir Christophe, kjin,

Peut-être comme cela, par simple analyse de la formule :

=SI(ET(PERMS!$I$3:$I$130="";PERMS!$I$3:$I$130>AUJOURDHUI());SOMMEPROD((PERMS!$B$3:$B$130="S/OFF")*(PERMS!$I$3:$I$130)*('ETAT MILIT'!$AA$3:$AA$130="M")*('ETAT MILIT'!$Z$3:$Z$130=C6)))

A te lire et bonne soirée

Bises aux enfants et à madame.

Jean-Pierre

 

[abcd]

Re : Modification SOMMEPROD

Bonjour,

Il me semble que l'approche de kjin est la bonne, à l'exception de ()

=SOMMEPROD((PERMS!$B$3:$B$130="S/OFF")*(PERMS!$I$3:$I$130="")*('ETAT MILIT'!$AA$3:$AA$130="M")*(('ETAT MILIT'!$Z$3:$Z$130=C6)+(PERMS!$B$3:$B$130="S/OFF"))*(PERMS!$I$3:$I$130>AUJOURDHUI())*('ETAT MILIT'!$AA$3:$AA$130="M")*('ETAT MILIT'!$Z$3:$Z$130=C6))

Les * ayant priorité sur le +, il faut mettre les arguments de ce dernier entre ()

abcd

 

[kjin]

Re : Modification SOMMEPROD

Bonjour,
Tu as raison abcd mais je pense que le "+" n'est toujours pas au bon endroit

=SOMMEPROD((PERMS!$B$3:$B$130="S/OFF")*((PERMS!$I$3:$I$130="")+(PERMS!$I$3:$I$130>AU JOURDHUI()))*('ETAT MILIT'!$AA$3:$AA$130="M")*('ETAT MILIT'!$Z$3:$Z$130=C6))

A suivre
A+
kjin

 

[abcd]

Re : Modification SOMMEPROD

Re,

Là je ne te comprends pas !

L'endroit où se trouve cette condition n'a pas d'importance puisque c'est une multiplication de VRAI et FAUX, soit 1 et 0.
Ce qui est important c'est de les grouper.

Si cela ne fonctionn pas avec l'une ou l'autre des propositions, il ne reste plus que la pièce jointe pour venir en aide à notre ami.

abcd

 

[kjin]

Re : Modification SOMMEPROD

Re,
Bin, j'ai juste regroupé les bons critères suivant la demande...("" et >aujourdhui)
Maintenant, sommeprod sur 2 matrices différentes, le 0 ne m'étonne pas, et sans savoir à quoi cela va servir....
A suivre
A+
kjin

 

[criscris11]

Re : Modification SOMMEPROD

Bonjour JP, kjin, abcd, le forum,
Ne vous fâchez plus 😀 car j'ai fait des essais également de mon côté et j'ai trouvé la bonne écriture :
=SOMMEPROD(('ETAT MILIT'!$B$3:$B$129="MDR")*(Départs=0)*('ETAT MILIT'!$AA$3:$AA$129="X")*('ETAT MILIT'!$Z$3:$Z$129=C13))+SOMMEPROD(('ETAT MILIT'!$B$3:$B$129="MDR")*(Départs>AUJOURDHUI())*('ETAT MILIT'!$AA$3:$AA$129="X")*('ETAT MILIT'!$Z$3:$Z$129=C13))

Pour info, j'ai remplacé (PERMS!$I$3:$I$130="") par (Départs=0) et rajouté (Départs>AUJOURDHUI()) pour la deuxième condition.
Merci à tous pour vos réponses et bonne journée.