Macro d'extraction et de comptage de valeurs différentes

[joebar2000]

Bonjour le forum,

Existe-t'il une fonction macro qui permette de me dire quelles sont les valeurs différentes qu'il y a dans une liste en colonne ainsi que le nombre associé.

Exemple:

Voici une liste
a
b
a

c
d
d
b
a

l'espace est volontaire car il y a des trous dans ma liste

le résultat que je souhaite est

a 3
b 2
c 1
d 2
vide 1

Sachant que dans ma macro j'ai déjà un compteur i qui compte le nombre de lignes totales (vide compris)

En vous remerciant d'avance de votre aide...

Joebar

 

[Hervé]

Re : Macro d'extraction et de comptage de valeurs différentes

bonjour joebar

une proposition :

Sub Bouton1_QuandClic()
Dim plage As Range
Dim data As New Collection
Dim c As Range
Dim i As Integer
Dim ligne As Integer
Dim vide As Integer

Set plage = Range("a1:a" & Range("a65536").End(xlUp).Row)

On Error Resume Next
For Each c In plage
    If Not c = "" Then
        data.Add c, CStr(c)
    Else
        vide = vide + 1
    End If
Next c
On Error GoTo 0

For i = 1 To data.Count
    ligne = ligne + 1
    Cells(ligne, 2) = data(i) & "=" & Application.CountIf(plage, data(i))
Next i

ligne = ligne + 1
Cells(ligne, 2) = "vide=" & vide
End Sub

données en colonne A résultat en colonne B

salut

 

[joebar2000]

Re : Macro d'extraction et de comptage de valeurs différentes

Merci beaucoup Hervé,

Après une petite adaptation à mon fichier la macro fonctionne à merveille...

Encore merci et bonne journée

Joebar