macro de tri sur les feuilles numériques d'un classeur

[superbog]

Bonjour,

Je bloque sur une macro qui devrait être simple (honte à moi), j'ai un classeur avec des pages numériques et d'autres qui ne le sont pas.
Je souhaite que les cellules C6:H2000 soient triées par la colonne C par ordre croissant.

voici la macro que j'ai préparée

Sub trier_dil()
Dim WS As Worksheet

For Each WS In Worksheets
     
  If IsNumeric(WS.Name) Then
        
         ActiveSheet.Sort.SortFields.Clear
         ActiveSheet.Sort.SortFields.Add Key:=Range( _
        "C6:C2000"), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:= _
        xlSortNormal
      With ActiveSheet.Sort
        .SetRange Range("C6:H2000")
        .Header = xlGuess
        .MatchCase = False
        .Orientation = xlTopToBottom
        .SortMethod = xlPinYin
        .Apply
        
      End With
    
    End If
       
    Next WS
  
MsgBox ("tri des diligences terminé")

End Sub

merci de m'aider

 

[Pierrot93]

Re : macro de tri sur les feuilles numériques d'un classeur

Bonjour,

essaye en modifiant comme suit :

Sub trier_dil()
Dim WS As Worksheet
For Each WS In Worksheets
With WS
    If IsNumeric(.Name) Then
        .Sort.SortFields.Clear
        .Sort.SortFields.Add Key:=Range("C6:C2000"), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:= _
        xlSortNormal
        With .Sort
            .SetRange Range("C6:H2000")
            .Header = xlGuess
            .MatchCase = False
            .Orientation = xlTopToBottom
            .SortMethod = xlPinYin
            .Apply
        End With
    End If
End With
Next WS

bon après midi
@+

 

[Pierrot93]

Re : macro de tri sur les feuilles numériques d'un classeur

Re,

Sub trier_dil()
Dim WS As Worksheet
For Each WS In Worksheets
    With WS
        If IsNumeric(.Name) Then
            With .Sort
                .SortFields.Clear
                .SortFields.Add Key:=Range("C6:C2000"), SortOn:=xlSortOnValues, _
                    Order:=xlAscending, DataOption:=xlSortNormal
                .SetRange Range("C6:H2000")
                .Header = xlGuess
                .MatchCase = False
                .Orientation = xlTopToBottom
                .SortMethod = xlPinYin
                .Apply
            End With
        End If
    End With
Next WS
 
MsgBox ("tri des diligences terminé")

End Sub

 

[Pierrot93]

Re : macro de tri sur les feuilles numériques d'un classeur

Re,

manquait un "ws"

Sub trier_dil()
Dim WS As Worksheet
For Each WS In Worksheets
    With WS
        If IsNumeric(.Name) Then
            With .Sort
                .SortFields.Clear
                .SortFields.Add Key:=ws.Range("C6:C2000"), SortOn:=xlSortOnValues, _
                    Order:=xlAscending, DataOption:=xlSortNormal
                .SetRange WS.Range("C6:H2000")
                .Header = xlGuess
                .MatchCase = False
                .Orientation = xlTopToBottom
                .SortMethod = xlPinYin
                .Apply
            End With
        End If
    End With
Next WS

 

[superbog]

Re : macro de tri sur les feuilles numériques d'un classeur

top merci à vous