Macro conditionnelle au mois pour Excel

Lermiton à dit:

Bonsoir.
De quelle version de Excel s'agit-il ? Le VBA n'est plus traduit en français depuis bien longtemps, et il faut écrire les conditions "Si" comme suit :
(corrigé le 5 octobre)

If [condition 1] Then
[action 1]
ElseIf [condition 2] Then
[action 2]
ElseIf [condition 3] Then
[action 3]
etc......
Else
[action si aucune des conditions n'est remplie]
End If


Bonjour,
Merci je vais essayer et vous tiendrais informé. Par contre j'ai un autre problème, j'écris un userform comportant plusieurs textbox dont je souhaiterais me servir de la valeur d'entre eux dans plusieurs autres. Je me trouve confronté au fait qu'il y a ambiguïté

Pour suivre ton exemple :

Code:

Sub Exemple()

    If Range("F1") = "janvier" Then
        Range("F4").Select
        Application.CutCopyMode = False
        ActiveCell.FormulaR1C1 = "='[Budget Total.xls]Feuil1'!RC[32]"
    End If

End Sub

Mais attention : ça ne fonctionne que si les cellules F1 et F4 sont dans la feuille active. Et il n'est pas nécessaire de sélectionner la cellule F4 pour y coller la formule (j'ai supprimé le "Application.CutCopyMode = False" dont je ne vois pas l'utilité dans ce "If ... End If") :

Code:

Sub Exemple_2()
    
    If Range("F1") = "janvier" Then
        Range("F4").FormulaR1C1 = "='[Budget Total.xls]Feuil1'!RC[32]"
    End If

End Sub

Si les cellules F1 et F4 ne sont pas dans la feuille active ou pas dans la même feuille, il faut désigner l'objet "Range" comme suit :
Sheets("[Nom de la feuille]").Range("F1")
Et si les cellules ne sont pas dans le même classeur (alors, les deux classeurs doivent être ouverts en même temps), il faut écrire :
Workbooks("[Nom du classeur]").Sheets("[Nom de la feuille]").Range("F1")

Et, plutôt que des faire des "If ... En if" à la chaîne, il vaut mieux utiliser le "Select Case :

Code:

Sub Exemple_3()

    Select Case Range("F1").Value
        Case "janvier"
            Range("F4").FormulaR1C1 = "='[Budget Total.xls]Feuil1'!RC[32]"
        Case "février"
            Range("F4").FormulaR1C1 = "='[Budget Total.xls]Feuil1'!RC[35]"
        Case "mars"
            Range("F4").FormulaR1C1 = "='[Budget Total.xls]Feuil1'!RC[38]"
Rem Etc.....
    End Select

End Sub

Bon courage.

PS : attention à la casse ! "janvier" <> "JANVIER" !

Cliquez pour agrandir...

Lermiton à dit:

Bonsoir.

Pour calculer la valeur du "TextBox253", tu peux aussi écrire ceci, en remplaçant "UserForm1" par le nom que tu as donné à ton UserForm, et en vérifiant que la fonction "Cumul" doit bien être du type "Single" dans ton cas :

Code:

Private Sub TextBox80_AfterUpdate()
    TextBox253.Value = Cumul
End Sub

Private Sub TextBox81_AfterUpdate()
    TextBox253.Value = Cumul
End Sub

' etc........

Private Function Cumul() As Single
    Dim n As Integer
    Dim Ctrl As Control
    
    For Each Ctrl In UserForm1.Controls
        If TypeName(Ctrl) = "TextBox" Then
            n = Val(Right(Ctrl.Name, Len(Ctrl.Name) - 7))
            Select Case n
                Case 80 To 91
                    Cumul = Cumul + Val(Ctrl)
                Case 181 To 191
                    Cumul = Cumul + Val(Ctrl)
                Case 281 To 291
                    Cumul = Cumul + Val(Ctrl)
                Case 381, 382
                    Cumul = Cumul + Val(Ctrl)
                Case 384 To 391
                    Cumul = Cumul + Val(Ctrl)
            End Select
        End If
    Next
End Function

Bonne soirée.

PS : plus élégant, si tu donnes un "Tag" à chaque TextBox que tu veux utiliser pour le cumul (propriété "Tag" du Textbox), par exemple "81" pour le TextBox81 et ainsi de suite, tu peux écrire la fonction "Cumul" comme ceci :

Code:

Private Function Cumul() As Single
    Dim Ctrl As Control
    
    For Each Ctrl In UserForm1.Controls
        Select Case Ctrl.Tag
            Case 80 To 91
                Cumul = Cumul + Val(Ctrl)
            Case 181 To 191
                Cumul = Cumul + Val(Ctrl)
            Case 281 To 291
                Cumul = Cumul + Val(Ctrl)
            Case 381, 382
                Cumul = Cumul + Val(Ctrl)
            Case 384 To 391
                Cumul = Cumul + Val(Ctrl)
        End Select
    Next

End Function

Cliquez pour agrandir...