macro à modifier pour toutes les feuilles d'un classeur

[2b7a]

bonsoir à toutes et tous,

La macro ci-dessous fonctionne sur une seule feuille (pas de nom de macro ; éléments uniquement dans l'objet éditeur Visual Basic).
Est-ce qu'il est possible de la modifier pour qu'elle concerne toutes les feuilles de mon classeur ?

D'avance, merci pour votre aide.
Bonne soirée



Private Sub Worksheet_SelectionChange(ByVal Target As Range)
Set champ = Range("b5:d22,b25:d42,b45:d62")
If Not Intersect(champ, Target) Is Nothing Then
For i = 1 To champ.Areas.Count
If Not Intersect(champ.Areas(i), Target) Is Nothing Then
dte = Split(champ.Areas(i).Address, ":")(1)
End If
Next i
If Range(dte) <> "" And Date > Range(dte) Then
mp = InputBox("mot passe?")
If mp <> "toto" Then [a1].Select
End If
End if
End Sub

 

[Robert]

Re : macro à modifier pour toutes les feuilles d'un classeur

Bonsoir Numéro lettre numéro lettre, bonsoir le forum,

Le même code mais placé dans le composant ThisWorkbook :

Private Sub Workbook_SheetSelectionChange(ByVal Sh As Object, ByVal Target As Range)
Dim champ As Range
Dim dte As String

Set champ = Range("b5:d22,b25:d42,b45:d62")
If Not Intersect(champ, Target) Is Nothing Then
    For i = 1 To champ.Areas.Count
        If Not Intersect(champ.Areas(i), Target) Is Nothing Then
            dte = Split(champ.Areas(i).Address, ":")(1)
        End If
    Next i
    If Range(dte) <> "" And Date > Range(dte) Then
        mp = InputBox("mot passe?")
        If mp <> "toto" Then [a1].Select
    End If
End If
End Sub

 

[Dranreb]

Re : macro à modifier pour toutes les feuilles d'un classeur

Bonsoir.
Autre code aussi dans ThisWorkbook :

Private Sub Workbook_SheetSelectionChange(ByVal Sh As Object, ByVal Target As Range)
Dim Champ As Range, V As Variant, MP As String
Set Champ = Sh.[B5:D22,B25:D42,B45:D62]
Set Target = Intersect(Champ, Target)
If Target Is Nothing Then Exit Sub
V = Sh.Cells(((Target.Row - 5) \ 20) * 20 + 22, "D").Value
If V <> "" And Date > V Then
   MP = InputBox("mot passe?")
   If MP <> "toto" Then Sh.[a1].Select
   End If
End Sub

 

[2b7a]

Re : macro à modifier pour toutes les feuilles d'un classeur

Merci beaucoup !

Très bonne fin de soirée