XL 2016 Llistbox filtrée ne se rafraichit pas

ptj75 · 26 Janvier 2021

Bonjour a tous,
j ai une listbox dans un userform qui ne se rafraichit pas après un filtre sur une colonne en testant si la valeur est "oui" ou "non".j agit sur le parametre Listbox.RowSource
la feuille BD est bien filtrée.ListBox1.RowSource prend bien les adresses correspondant bien aux lignes filtrées.
mais la visu de la listbox dans le userform est vide est vide .

Private Sub CommandButton8_Click()
'bouton recherche cable basculé
If Sheets("BD").Range("B2") <> "" Then
With Sheets("BD")
If Worksheets("BD").FilterMode Then Worksheets("BD").ShowAllData
End With
'ListBox1.Clear
Sheets("BD").Range("B1:B65000").AutoFilter 2, "=" & "OUI"
ListBox1.RowSource = _
Sheets("BD").Range("BD!A2:" & _
Sheets("BD").Range("AG2").End(xlDown).Address). _
SpecialCells(xlCellTypeVisible).Address
End If
End Sub
Cà marche quand on trouve 3 "OUI" à la suite dans toute la liste, par contre dès qu'il y un "OUI" de plus ,pas à la suite , la visu de la listbox est vide.
lorsque je veux faire une ListBox1.Clear, j 'ai une erreur.

Si quelqu'un peut m'aiguiller
Merci par avance

patricktoulon · 26 Janvier 2021

bonjour
c'est normal rowsource ou point .list ne peut pas recevoir une( plage non contiguë).value
c'est tout simplement impossible

il te faut boucler sur les visible row de la plage filtrée et les colonnes
ou
utiliser application.index (array de ligne valides , array de colonne valides)

dans les 2 cas au moins une boucle est nécessaire

je parle pas de la syntaxe qui me donne la migraine du genre
Sheets("BD").Range("B1:B65000").AutoFilter 2, "=" & "OUI"'????????????????????????
ou
Sheets("BD").Range("BD!A2:" & _'?????????????????????????

???????????????????????????????

ptj75 · 26 Janvier 2021

ok, j 'ai essayer de réaliser une boucle en regardant des exemples sur les forums, pas moyen de faire un code valide.
après pour la syntaxe, je suis un novice sur excel,
si je joins le fichier, est-il possible de me guider et bien sur en essayant de comprendre
merci

patricktoulon · 26 Janvier 2021

re
envoie la sauce

ptj75 · 26 Janvier 2021

ok
soyez indulgent pour la syntaxe

ptj75 · 26 Janvier 2021

c'est lors de l'appui sur les bouton basculé et non basculé en bas à gauche

patricktoulon · 26 Janvier 2021

je n'en ai pas vraiment besoins en fait
si j'ai bien compris ce que tu veux
toutes les ligne du table [A:AG] qui ont "oui" en colonne "B"

VB:

Private Sub CommandButton8_Click()
'bouton recherche cable basculé
    If Sheets("BD").Range("B2") <> "" Then
        With Sheets("BD").Range("A2:AG" & Sheets("BD").Cells(Rows.Count, "A").End(xlUp).Row)
            tableau = .Value 'on prend le tableau entier
            
            'on determine les ligne du tableau(A:Ag) ou il y a "oui" en col"B"
            For i = 1 To UBound(tableau)
                If tableau(i, 2) = "OUI" Then it = it & " " & i
            Next
            lignes = Application.Transpose(Split(Trim(it), " "))
            
            colonnes = Evaluate("COLUMN(A:AG)") 'on créée un array d'index de colonnes
            tableau = Application.Index(.Value, lignes, colonnes) 'on créée le tableau avec les index lignes /colonnes
            ListBox1.ColumnCount = UBound(tableau, 2) 'on dimensionne le nombre de colonnes de la liste box idem a la plage de base
            ListBox1.List = tableau ' on fout le tableau dans la listbox
        End With
    End If
End Sub

ptj75 · 26 Janvier 2021

wahou, c'est exactement cela. donc avec çà , inutile d'utiliser les filtres automatique.
que fait-on avec la fonction evaluate?

patricktoulon · 26 Janvier 2021

la fonction evaluate évalue une expression et te restitue l'object ou le résultat de l’évaluation de l'expression
ici ça me restitue un array

VB:

sub test()
colonnes = Evaluate("COLUMN(A:AG)") 'on créée un array d'index de colonnes
'qu'est ce qu'il y a dans cet array
msgbox join(colonnes,",")
end sub

ptj75 · 26 Janvier 2021

ok.donc on peut filtrer sur plusieurs colonnes et différentes expressions.ex sur la colonne b et d

patricktoulon · 26 Janvier 2021

oui absolument

ptj75 · 26 Janvier 2021

par contre .a mes souvenirs,on ne peut pas changer la couleur de fond de la ligne en rouge si c est non dans la listbox?

ptj75 · 26 Janvier 2021

pensez vous qu il est possible de copier les lignes filtrees sur la feuille excel et de les copier dans le tableau avant de le reverser dans la listbox? avec xcelltypevisible

patricktoulon · 26 Janvier 2021

oui c'est une autre méthode

ptj75 · 26 Janvier 2021

serait il possible d avoir un exemple.si vous avez.
enfin déjà un très grand merci pour tout cela.
vous m avez enlever une grosse épine du pied

XL 2016 Llistbox filtrée ne se rafraichit pas

ptj75

XLDnaute Nouveau

patricktoulon

XLDnaute Barbatruc

ptj75

XLDnaute Nouveau

patricktoulon

XLDnaute Barbatruc

ptj75

XLDnaute Nouveau

Pièces jointes

ptj75

XLDnaute Nouveau

patricktoulon

XLDnaute Barbatruc

ptj75

XLDnaute Nouveau

patricktoulon

XLDnaute Barbatruc

ptj75

XLDnaute Nouveau

patricktoulon

XLDnaute Barbatruc

ptj75

XLDnaute Nouveau

ptj75

XLDnaute Nouveau

patricktoulon

XLDnaute Barbatruc

ptj75

XLDnaute Nouveau

Discussions similaires