Microsoft 365 Listes des Onglets

[FCMLE44]

Bonjour

Je souhaite dans le fichier joint lister mes onglets présents sur ce fichier

Seulement je ne souhaite faire apparaitre les fichiers qui seront masqués et la feuille ou se trouve le récap

Plusieurs onglets pourront être masqués

J'utilise ce code que je mets dans la feuille Récap

Sub Snamelist()
Dim i As Integer

    Range("A1").Select

    For i = 1 To Sheets.Count
        ActiveCell.Value = Sheets(i).Name
        ActiveCell.Offset(1, 0).Select
    Next i

End Sub

Seulement toutes les feuilles apparaissent

Merci

 

[kiki29]

Salut, un conseil : toujours relire ce que l'on écrit ...

Option Explicit

Sub Tst()
Dim i As Long, j As Long
    Application.ScreenUpdating = False
    With Feuil8
        .Columns("A:A").Cells.Clear
        For i = 1 To Sheets.Count
            If Sheets(i).Visible Then
                j = j + 1
                .Cells(j, 1) = Sheets(i).Name
            End If
        Next i
    End With
    Application.ScreenUpdating = True
End Sub

 

[FCMLE44]

merci

Est ce possible d'exclure la feuille ou se situera la liste des onglets et faire la liste à compter de la ligne 2

En effet, je compte mettre un titre à la colonne

Cordialement

 

[kiki29]

Re,

Option Explicit

Sub Tst_02()
Dim Wsh As Worksheet, i As Long
    Application.ScreenUpdating = False
    With Feuil8
        .Range("A2:A" & .Rows.Count).Cells.Clear
        i = 1
        For Each Wsh In ThisWorkbook.Worksheets
            If Wsh.Visible And _
               Not (Wsh.Visible = xlSheetVeryHidden) And _
               Wsh.Name <> .Name Then
                i = i + 1
                .Cells(i, 1) = Wsh.Name
            End If
        Next Wsh
    End With
    Application.ScreenUpdating = True
End Sub

 

[FCMLE44]

Parfait
Par contre cela efface mon titre de colonne en A1

 

[kiki29]

Re, [F5]

 

[FCMLE44]

???

 

[Jacky67]

Bonjour

Je souhaite dans le fichier joint lister mes onglets présents sur ce fichier

Seulement je ne souhaite faire apparaitre les fichiers qui seront masqués et la feuille ou se trouve le récap

Bonjour à tous

Sub Snamelist()
    Dim SH As Worksheet
    Application.ScreenUpdating = False
    Range("A2:a" & Rows.Count).Clear
    For Each SH In ThisWorkbook.Worksheets
        If SH.Name <> ActiveSheet.Name And SH.Visible Then
            Range("A" & Rows.Count).End(xlUp)(2) = SH.Name
        End If
    Next
End Sub

 

[kiki29]

Salut, voir Post#4

 

[job75]

Bonjour FCMLE44, kiki29, Jacky67,

Voyez le fichier joint et cette macro affectée au bouton :

Sub Snamelist()
Dim a() As String, s As Object, n As Integer
ReDim a(1 To Sheets.Count, 1 To 1)
With Feuil8 'CodeName de la feuille Récap, à adapter
    For Each s In Sheets
        If s.Name <> .Name And s.Visible = -1 Then n = n + 1: a(n, 1) = s.Name
    Next
    If .FilterMode Then .ShowAllData 'si la feuille est filtrée
    With .[A2] '1ère cellule de restitution, à adaoter
        If n Then .Resize(n) = a
        .Offset(n).Resize(Rows.Count - n - .Row + 1).ClearContents 'RAZ en dessous
    End With
End With
End Sub

Feuil4 est masquée VeryHidden (s.Visible = 2) Feuil7 est masquée Hidden (s.Visible = 0).

A+