Lien vers feuille suivant ou precedent

[maval]

Bonjour,

J’ai 35 feuilles sur mon classeur et j’aimerais avoir un lien à chaque feuille pour me rendre à la feuille suivante ou précédente !
Pour me rendre à la feuille "accueil" je mets ce code qui m’ajoute à chaque feuille en "A1" un lien vers la feuille d’accueil qui fonctionne très bien.

' Créer liens vers feuil d'accueil
Sub CreationLiens()
Dim I As Integer

  For I = 2 To Sheets.Count
    Sheets(I).Hyperlinks.Add Anchor:=Sheets(I).Range("A1"), Address:="", _
          SubAddress:="'" & Sheets(1).Name & "'!A1", TextToDisplay:="Retour"
  Next I
End Sub

Est-il possible d’avoir un code similaire de façon qui m’ajoute à chaque feuille un lien vers la feuille suivante ou précédente.

Je vous remercie de votre aide.

[

 

[BOISGONTIER]

Re : Lien vers feuille suivant ou precedent

Bonjour,

Avec la fonction Lien_Hypertexte()

http://boisgontierjacques.free.fr/fichiers/hyperlien/LiensFeuilleSuivantePrecedente.xls
http://boisgontierjacques.free.fr/fichiers/hyperlien/LienHyperSommaireDyn.xls

JB

 

[maval]

Re : Lien vers feuille suivant ou precedent

Bonjour JB

Je te remercie beaucoup, Est-il possible d'avoir un code en VBA ?

Bonne journée et merci encore

 

[Paritec]

Re : Lien vers feuille suivant ou precedent

Bonjour Maval , jb, le forum

Sub CreationLiens2()
    Dim i&
    For i = 1 To Sheets.Count
        If i < Sheets.Count Then Sheets(i).Hyperlinks.Add Anchor:=Sheets(i).Range("B1"), Address:="", _
                                 SubAddress:="'" & Sheets(i + 1).Name & "'!B1", TextToDisplay:="Suivante"
        If i > 1 Then Sheets(i).Hyperlinks.Add Anchor:=Sheets(i).Range("C1"), Address:="", _
                                 SubAddress:="'" & Sheets(i - 1).Name & "'!C1", TextToDisplay:="Précédente"
    Next i
End Sub

a+
Papou😱

 

[maval]

Re : Lien vers feuille suivant ou precedent

Bonjour Papou,

Je te remercie beaucoup. Nickel

J'ai assembler les deux code en faisant ceci:

' Créer liens vers feuil d'acceuil
Sub CreationLiens()
Dim i As Integer

  For i = 2 To Sheets.Count
    Sheets(i).Hyperlinks.Add Anchor:=Sheets(i).Range("A1"), Address:="", _
          SubAddress:="'" & Sheets(1).Name & "'!A1", TextToDisplay:="Retour"

  Next i
'Créer un lien Suivant et Précedent
     For i = 1 To Sheets.Count
         If i < Sheets.Count Then Sheets(i).Hyperlinks.Add Anchor:=Sheets(i).Range("B1"), Address:="", _
                                  SubAddress:="'" & Sheets(i + 1).Name & "'!B1", TextToDisplay:="Suivante"
         If i > 1 Then Sheets(i).Hyperlinks.Add Anchor:=Sheets(i).Range("C1"), Address:="", _
                                  SubAddress:="'" & Sheets(i - 1).Name & "'!C1", TextToDisplay:="Précédente"
     Next i

End Sub

Je te souhaite une bonne journée et à la prochaine merci encore

 

[BOISGONTIER]

Re : Lien vers feuille suivant ou precedent

Sommaire dynamique + suivant/précédent

Les noms des feuilles peuvent être modifiés.
Les feuilles peuvent être ajoutées/supprimées/déplacées.

Private Sub Worksheet_Activate()
    [C5:C100].ClearContents
    For i = 2 To Sheets.Count
      nf = Sheets(i).Name
      ActiveSheet.Hyperlinks.Add Anchor:=Cells(i + 6, 3), Address:="", SubAddress:="'" & _
         nf & "'" & "!A1", TextToDisplay:=nf
    Next i
    [C5:C100].Sort Key1:=Range("C5"), Order1:=xlAscending, Header:=xlGuess
End Sub

Suivant/Précédent+Retour sommaire

Private Sub Workbook_SheetActivate(ByVal Sh As Object)
   If ActiveSheet.Index > 1 Then
    ActiveSheet.Hyperlinks.Add Anchor:=Cells(1, 1), Address:="", SubAddress:="'" & _
         Sheets(1).Name & "'" & "!A1", TextToDisplay:=Sheets(1).Name
    ActiveSheet.Hyperlinks.Add Anchor:=Cells(1, 2), Address:="", SubAddress:="'" & _
      Sheets(ActiveSheet.Index - 1).Name & "'" & "!A1", TextToDisplay:="<"
   End If
   If ActiveSheet.Index < Sheets.Count Then
    ActiveSheet.Hyperlinks.Add Anchor:=Cells(1, 3), Address:="", SubAddress:="'" & _
      Sheets(ActiveSheet.Index + 1).Name & "'" & "!A1", TextToDisplay:=">"
   End If
End Sub

JB

 

[maval]

Re : Lien vers feuille suivant ou precedent

Re,

Je te remercie et te souhaite une bonne journée