XL 2019 Lenteur pour charger une ComboBox à l'ouverture d'un classeur

[Magic_Doctor]

Bonsoir,

Tout est dans le titre.

Sur une feuille j'ai une ComboBox qui affiche une liste de nombres (1 jusqu'à 409 par pas de 0,5 : les tailles possibles des polices de caractères).
Cette ComboBox se charge à chaque ouverture du classeur dans Workbook_Open(). Néanmoins son chargement est très long, alors que si je vide la ComboBox et qu'ensuite je la charge, l'opération est quasi instantanée. À quoi est-ce dû ? Une lenteur avec les ActiveX ?

 

[dysorthographie]

bonsoir,
tu copies colles le contenu de l'événement open dans un module standard.

dans ta l'événement Open tu appel la macro que tu viens créer dans le module standard.

 

[mapomme]

Bonjour @Magic_Doctor🙂, @dysorthographie😉,

Avec une ComboBox1 sur Feuil1, l'ouverture du classeur est instantanée.

Private Sub Workbook_Open()
Dim v#
   Feuil1.ComboBox1.Clear: v = 0.5
   Do: Feuil1.ComboBox1.AddItem v: v = v + 0.5: Loop Until v > 409
End Sub

Sinon, il faudrait joindre votre propre classeur avec le défaut.

 

[mapomme]

Re,
Idem avec une ComboBox dans un userform.

 

[Magic_Doctor]

Bonsoir dysorthographie, mapomme,

La solution de mapomme marche très bien.
La ComboBox se trouve bien sur une feuille.
En fait, il y en a 2 qui recueillent exactement les mêmes données. Aussi, ai-je écrit ceci :

    With Feuil1
        v = 0.5
        .ComboBox1.Clear
        .ComboBox2.Clear
        Do: .ComboBox1.AddItem v: v = v + 0.5: Loop Until v > 409
        Do: .ComboBox2.AddItem v: v = v + 0.5: Loop Until v > 409
    End With

Ça marche bien pour la première ComboBox, en revanche la seconde ne se charge pas.
Où me serais-je encore planté ?

 

[Magic_Doctor]

Re,

Trouvé l'erreur :

    With Feuil1
        .ComboBox1.Clear
        .ComboBox2.Clear
        v = 0.5
        Do: .ComboBox1.AddItem v: v = v + 0.5: Loop Until v > 409
        v = 0.5
        Do: .ComboBox2.AddItem v: v = v + 0.5: Loop Until v > 409
    End With

 

[mapomme]

Re @Magic_Doctor😉,

On peut simplifier ton code pour ComboBox2 en se servant du travail qu'on a fait pour ComboBox1 :

Private Sub Workbook_Open()
Dim v#
   Feuil1.ComboBox1.Clear: v = 0.5
   Do: Feuil1.ComboBox1.AddItem v: v = v + 0.5: Loop Until v > 409
   Feuil1.ComboBox2.List = Feuil1.ComboBox1.List
End Sub

 

[Magic_Doctor]

Re

Astucieux, ça marche du tonnerre !

Un grand merci

 

[job75]

Bonsoir Magic_Doctor, le fil,

J'aimerais quand même comprendre pourquoi au post #1 tu parlais de lenteur.

A+

 

[Magic_Doctor]

Bonsoir job,

Ayant laissé tombé l'histoire un bon moment, je m'étais compliqué la vie en rédigeant un truc lourd comme du plomb, alors que la solution proposée par mapomme est une sylphide par rapport à la mienne.

 

[laurent950]

Bonjour

Private Sub Workbook_Open()
    Dim v As Double
    Dim i As Long
    Dim n As Long
    Dim arr()

    ' Nombre total d’entrées : (409 - 0.5) / 0.5 + 1
    n = (409# - 0.5) / 0.5 + 1
    ReDim arr(1 To n, 1 To 1)

    ' Remplir le tableau en mémoire (beaucoup plus rapide)
    v = 0.5
    For i = 1 To n
        arr(i, 1) = v
        v = v + 0.5
    Next i

    ' Charger directement la liste dans les 2 ComboBox
    With Feuil1
        .ComboBox1.Clear
        .ComboBox2.Clear
        .ComboBox1.List = arr
        .ComboBox2.List = arr
    End With
End Sub

 

[job75]

Bonjour laurent950, le fil,

On peut éviter toute boucle en utilisant simplement :

Private Sub Workbook_Open()
Dim a
a = Evaluate("ROW(1:818)/2")
Feuil1.ComboBox1.List = a
Feuil1.ComboBox2.List = a
End Sub

Cela dit chez moi ta macro et la mienne s'exécutent toutes deux en 0,42 ms.

Edit : j'ai retesté en enlevant les .ComboBox1.Clear qui sont inutiles, la macro de Laurent s'exécute en 0,38 ms.

Quant à la macro de mapomme avec AddItem elle s'exécute en 55 ms.

A+

 

[patricktoulon]

bonsoir
ouias .. pas mal
j'ai plus dingue si vous voulez
excel all version
ComboBox1.List = Application.Transpose(Evaluate("ROW(1:" & 409 / 0.5 & ")*0.5"))
excel version moderne avec sequence
ComboBox1.List = Application.WorksheetFunction.Sequence(409 / 0.5, 1, 0.5, 0.5)

@job75 Nous nous sommes croisés

 

[Magic_Doctor]

Bonjour à tous,

Merci pour vos réponses.

Maintenant, en y regardant de plus près, puisqu'il s'agit en fait de la liste de toutes les tailles possibles de polices de caractères, qui va de 1 à 409 (par pas de 0,5), en toute rigueur il faudrait que la liste commence par 1 et non pas 0,5 ; car si on sélectionne par la suite 0,5, on a fatalement un message d'erreur.

 

[patricktoulon]

bonjour
ok ben c'est tout simple
ComboBox1.List = Evaluate("ROW(2:" & 409 / 0.5 & ")*0.5")
le /0.5 multiplie le nombre d'item 409/0.5 = 818
le * 0.5 donnes les items dans la matrice
2 * 0.5=1

Patrick