Individualiser et controler l'envoi d'email avec outlook

[carlos]

Bonjour


J'ai une liste de contacts.Je souhaiterai envoyer pour chaque personne un mail personnalisé tout en m'assurant que chaque message st bien écrit.
Remarque : sur le code vba que j'ai proposé j'ai volontairement bloqué le .send

Voir Piece jointe

Merci

Carlos

 

[carlos]

Re : Individualiser et controler l'envoi d'email avec outlook

Aucune réponse envisagée ?.

 

[david84]

Re : Individualiser et controler l'envoi d'email avec outlook

Bonjour,
avec ce que j'en ai compris :

Private Sub CommandButton1_Click()
Dim ol As Outlook.Application
Dim i As Integer
Dim olmail As MailItem
Dim CurrFile As String
Dim Mails As String
Dim Message As String

Set ol = New Outlook.Application
Set olmail = ol.CreateItem(olMailItem)

'Caractéristiques de l'e-mail
    For i = 2 To Range("B" & Rows.Count).End(xlUp).Row
    If Cells(i, 3) <> "" And Cells(i, 4) = "x" Then
        With olmail
            .To = Cells(i, 3)
            'Affiche le nom comme objet du message
            .Subject = "Bonjour " & Range("b" & i).Value
            .Body = "Message pour " & Range("b" & i).Value
            '.CC = Mails
            'Pièces jointes si il y a lieu
            '.Attachments.Add "F:\Formation Dartfish\Document enseignement\cahier_des_charges_2013.pdf"
            'Remplacez .Display par .send pour envoyer directement l'e-mail sans l'afficher dans Outlook
            .Display
            '.Send
        End With
        Mails = ""
        Message = ""
    End If
    Next i
End Sub

Si ce n'est pas ce que tu veux, reviens avec plus d'explications.
A+

 

[carlos]

Re : Individualiser et controler l'envoi d'email avec outlook

Bonjour le forum , David84
Merci pour ta reponse mais ce n'est pas ce que j'attendais .
Je vais essayer d'etre plus clair
Je souhaite que outlook me présente le message les mesages les uns apres les autres et qu'à chaque message je puisse decider , par le bouton "envoyer " de outlook , de l'envoyer ou pas .
Dans ce que tu prposes , je ne vois que le dernier message et pas les premiers .

Carlos

 

[david84]

Re : Individualiser et controler l'envoi d'email avec outlook

Re
alors peut-être comme cela :

Private Sub CommandButton1_Click()
Dim ol As Outlook.Application
Dim i As Integer
Dim olmail As MailItem
Dim CurrFile As String
Dim Mails As String
Dim Message As String

Set ol = New Outlook.Application
'Caractéristiques de l'e-mail
    For i = 2 To Range("B" & Rows.Count).End(xlUp).Row
    If Cells(i, 3) <> "" And Cells(i, 4) = "x" Then
        Set olmail = ol.CreateItem(olMailItem)
        With olmail
            .To = Cells(i, 3)
            'Affiche le nom comme objet du message
            .Subject = "Bonjour " & Range("b" & i).Value
            .Body = "Message pour " & Range("b" & i).Value
            '.CC = Mails
            'Pièces jointes si il y a lieu
            '.Attachments.Add "F:\Formation Dartfish\Document enseignement\cahier_des_charges_2013.pdf"
            'Remplacez .Display par .send pour envoyer directement l'e-mail sans l'afficher dans Outlook
            .Display
            '.Send
        End With
        Set olmail = Nothing
        Mails = ""
        Message = ""
    End If
    Next i
Set olmail = Nothing
End Sub

Si tu les veux dans l'ordre inverse, il te suffit d'inverser le sens de la boucle for et d'utiliser un pas négatif.
A+

 

[carlos]

Re : Individualiser et controler l'envoi d'email avec outlook

Cest exactement cela David84
Merci beaucoup

Carlos