Ceci est une page optimisée pour les mobiles. Cliquez sur ce texte pour afficher la vraie page.

Autres indentifier le classeur en ne connaissant que le nom d'un des module

patricktoulon

XLDnaute Barbatruc
Bonjour à tous
je voudrais pour remonter jusqu'au classeur a partir d'un module

j'obtiens l'object vbcomponent(module) avec ceci
VB: 
  Set vbComp = Application.VBE.ActiveCodePane.CodeModule.Parent
avez vous des idées?
 
Solution
Non vue qu'il s'agit bien de l'instance wb.VBProject et pas de son non

Ici tu récupères l'instance du modules actif
Application.VBE.ActiveCodePane.CodeModule.Parent
Et tu le compare à l'instance du wb?? Défi dans la boucle
C'est comme une collection du même module de classe chaque instance est unique

Place les deux dans la fenêtre espion, tu verras qu'il sont du même type et que ce soit bien des objets à part entière
Trier par date Trier par votes

dysorthographie

XLDnaute Accro
Bonjour Patrick,
Code: 
Sub RemonterJusquAuClasseur()
    ' Obtenez l'objet VBComponent du module actif
    Dim vbComp As VBComponent
    Set vbComp = Application.VBE.ActiveCodePane.CodeModule.Parent
    
    ' Obtenez l'objet VBProject contenant le module
    Dim vbProj As VBProject
    Set vbProj = vbComp.Collection.Parent
    
    ' Obtenez le classeur contenant le projet VBA
    Dim wb As Workbook
    For Each wb In Workbooks
        If wb.VBProject Is vbProj Then
            MsgBox "Le module appartient au classeur : " & wb.Name
            Exit Sub
        End If
    Next wb
    
    MsgBox "Le classeur n'a pas été trouvé."
End Sub
 
Vote positif 0 Vote négatif

patricktoulon

XLDnaute Barbatruc
re
bonjour Robert
et oui ça j'y ai déjà pensé
sauf que si c'est des classeurs avec le même nom "vbproject" d'origine je risque de prendre celui d'a coté non ?
chatgpt me l'avais déjà proposé avec en plus une boucle sur tout les module et l'analyse du texte pour être sur d'avoir le bon
bref une usina gaz quoi
 
Vote positif 0 Vote négatif

dysorthographie

XLDnaute Accro
Non vue qu'il s'agit bien de l'instance wb.VBProject et pas de son non

Ici tu récupères l'instance du modules actif
Application.VBE.ActiveCodePane.CodeModule.Parent
Et tu le compare à l'instance du wb?? Défi dans la boucle
C'est comme une collection du même module de classe chaque instance est unique

Place les deux dans la fenêtre espion, tu verras qu'il sont du même type et que ce soit bien des objets à part entière
 
Dernière édition:
Vote positif 1 Vote négatif
Solution

Cousinhub

XLDnaute Barbatruc
Inactif
Bonjour,
A tout z'hasard...
VB: 
Dim vbComp  As Object
Dim Nom As String
    Set vbComp = Application.VBE.ActiveCodePane.CodeModule.Parent
    Nom = vbComp.Collection.Parent.Filename
    MsgBox Right(Nom, Len(Nom) - InStrRev(Nom, "\"))
 
Vote positif 1 Vote négatif

patricktoulon

XLDnaute Barbatruc
re
Bonjour @Cousinhub
oui c'est ça
j'avais trouvé entre temps
le but étant de récupérer le classeur parent du module affiché dans vbe
la fonction renvoie un object workbook
VB: 
Sub testgetwbkparent()
    Dim vbcomp As VBComponent
    Set vbcomp = Application.VBE.ActiveCodePane.CodeModule.Parent
    MsgBox GetWorkbookParent(vbcomp).Name
End Sub

Function GetWorkbookParent(vbcomp) As Workbook
    Dim vbProj As vbProject
    Set vbProj = vbcomp.Collection.Parent
    Set GetWorkbookParent = Workbooks(Mid(vbProj.Filename, InStrRev(vbProj.Filename, "\") + 1))
End Function

super merci à tous
ça me faisait mal de devoir boucler même si la solution de Robert est bonne
et oui robert en effet tu à raison on traville en mode object donc il ne peut pas avoir de confusion
même si deux classeurs auraient eventuellement un module du même nom
(je précise j'ai testé )

merci à tous
 
Vote positif 0 Vote négatif

laurent950

XLDnaute Barbatruc
Bonsoir @patricktoulon

En une seule Ligne
VB: 
Sub testgetwbkparente1()
    MsgBox Split(Application.VBE.ActiveCodePane.CodeModule.Parent.Collection.Parent.fileName, "\")(UBound(Split(Application.VBE.ActiveCodePane.CodeModule.Parent.Collection.Parent.fileName, "\")))
End Sub

Une version un peu formatée pour plus de lisibilité, mais qui fait exactement la même chose
Code: 
Sub testgetwbkparente2()
    Dim filePath As String
    Dim fileName As String

    ' Obtenir le chemin complet du fichier du projet VBA parent
    filePath = Application.VBE.ActiveCodePane.CodeModule.Parent.Collection.Parent.fileName

    ' Extraire le nom du fichier à partir du chemin complet
    fileName = Split(filePath, "\")(UBound(Split(filePath, "\")))

    ' Afficher le nom du fichier (classeur)
    MsgBox fileName
End Sub
 
Vote positif 0 Vote négatif

patricktoulon

XLDnaute Barbatruc
Bonsoir
un truc que je ne fait jamais Laurent , c'est donner des noms a des variables étant aussi des propertes
je parle de FileName et dans la même casse en plus
et pour le coup la lisibilité walouh !!!!
à méditer
 
Vote positif 0 Vote négatif

patricktoulon

XLDnaute Barbatruc
pour l"a une seule ligne
f"aut il encore bien le faire
VB: 
Sub testgetwbkparente1()
    With Application.VBE.ActiveCodePane.CodeModule.Parent.Collection.Parent: MsgBox Split(.Filename, "\")(UBound(Split(.Filename, "\"))): End With
End Sub
 
Vote positif 0 Vote négatif

patricktoulon

XLDnaute Barbatruc
après cette méthode n'est pas optimisée
j'entends par là que pour se fair tu split 2 fois la chaine
la méthode instrRev c'est mieux
VB: 
Sub testgetwbkparente1()
    With Application.VBE.ActiveCodePane.CodeModule.Parent.Collection.Parent: MsgBox Mid(.Filename, InStrRev(.Filename, "\") + 1): End With
End Sub
la tu vois je prends une portion de la" chaine en un coup
 
Vote positif 0 Vote négatif

patricktoulon

XLDnaute Barbatruc
donc au final ici une seule ligne n'est pas forcement mieux et lisible
si je coupe proprement on pige tout de suite
Code: 
Sub testgetwbkparente1()
    With Application.VBE.ActiveCodePane.CodeModule.Parent.Collection.Parent
       MsgBox Mid(.Filename, InStrRev(.Filename, "\") + 1)
    End With
End Sub
 
Vote positif 0 Vote négatif

laurent950

XLDnaute Barbatruc
Hello @patricktoulon
VB: 
Sub TestGetWorkbookName()
' Affichez le nom du fichier
    MsgBox Mid(Application.VBE.ActiveCodePane.CodeModule.Parent.Collection.Parent.fileName, InStrRev(Application.VBE.ActiveCodePane.CodeModule.Parent.Collection.Parent.fileName, "\") + 1)
End Sub

E
 
Vote positif 0 Vote négatif

laurent950

XLDnaute Barbatruc
Re

il y a surement un accès directe au résultat?

VB: 
Sub TestGetWorkbookNameSuite()
Dim NomF As String: NomF = Application.VBE.ActiveCodePane.CodeModule.Parent.Collection.Parent.fileName
' Affichez le nom du fichier
    MsgBox Mid(NomF, InStrRev(NomF, "\") + 1)
End Sub
 
Vote positif 0 Vote négatif
Identifiez-vous ou inscrivez-vous pour participer.

Discussions similaires

A
  • Question
XL 2021 Module d’envoi à la Corbeille qui ne fonctionne pas en 64 Bits
2
Réponses
20
Affichages
512
patricktoulon
  • Question
Microsoft 365 Remplir cellules à partir de plusieurs fichiers Excel d'un dossier
2
Réponses
17
Affichages
503
alexga78
A
G
  • Question
Microsoft 365 Avoir des classeurs maitres et les procédures dans un autre classeur.
2
Réponses
18
Affichages
1 K
GClaire
G
S
  • Résolu(e)
Microsoft 365 [Résolu] Aide sur gestionnaires de noms + liste déroulante en cascade associée
Réponses
9
Affichages
670
djidji59430
XLS : Modèle pour ouvrir un classeur sur une nouvelle Session Excel
Réponses
0
Affichages
207
Lu76Fer
  • Résolu(e)
Microsoft 365 Forcer l'affichage de mon userform (barre de progression) sur l'écran où le classeur est actif (cas des doubles/triples écrans)
3 4 5
Réponses
66
Affichages
2 K
Dudu2
S
  • Question
Microsoft 365 VBA enregistrement dans dossier spécifique
Réponses
1
Affichages
230
vgendron
F
  • Question
Microsoft 365 Récupérer l'userform parent d'un controle
2
Réponses
27
Affichages
630
Dranreb
  • Question
XL 2016 Depuis un Module Standard pouvoir Récupérer la Photocopie d'une Classe (dont/Avec) la collection qui est incluse dans le Module de Classe.
6 7 8
Réponses
115
Affichages
7 K
laurent950
  • Question
XL 2013 copie image userform to worksheet with api ( le jpg ne fonctionne plus )
2
Réponses
18
Affichages
939
patricktoulon
Menu
Connexion
S'inscrire
Les cookies sont requis pour utiliser ce site. Vous devez les accepter pour continuer à utiliser le site. En savoir plus…