imprimer des plages de cellules non-continues

[naitgo]

Bonjour à tous,
N'étant pas trop calé en VBA je n'arrive pas à solutionner un petit souci.
J'ai créé un bouton sur une feuille dans lequel j'ai un code qui sélectionne et imprime deux plages de cellules non-continues. La macro fonctionne très bien, le souci est que les deux plages s'impriment sur deux feuilles différentes, alors que je souhaite les imprimer sur une même feuille.
Est-il possible d'imprimer sur une seule feuille ?
voici le code de mon bouton :

Private Sub CommandButton1_Click()
 Application.Union(Range("komori2coul"), Range("Notes")).Select
 Selection.PrintOut Copies:=1
ActiveCell.Select
End Sub

D'avance je vous remercie pour votre aide.
Naitgo

 

[soenda]

Re : imprimer des plages de cellules non-continues

Bonsoir le fil, Naitgo

Un essai en passant par une feuille temporaire (ici Feuil2)

Private Sub CommandButton1_Click()
 
    With Feuil2
        .Cells.Clear
        [komori2coul].Copy .[A1]
        [Notes].Copy .[A1].Offset([komori2coul].Rows.Count)
        .PrintOut
    End With
 
End Sub

A plus

 

[naitgo]

Re : imprimer des plages de cellules non-continues

Bonsoir et merci pour ton aide soenda,
Je viens faire un essai, le code affiche "objet requis" sur la ligne .Cells.Clear
J'avoue que je ne sais pas vraiment ce que je dois mettre pour compléter cette ligne.
Encore merci pour ton aide
Naitgo

 

[JCGL]

Re : imprimer des plages de cellules non-continues

Bonjour à tous,
Salut Soenda,

Avec le code de Soenda :

Option Explicit

Sub Union_Print()
' Sur la feuille 'F2'
With Sheets("F2")
' Effacer toutes les cellules de la feuille
    .Cells.ClearContents
' Copier la zone nommée Zone1 de la feuille 'F1' en A1 de la feuille 'F2'
    Sheets("F1").Range("Zone1").Copy .Range("A1")
' Copier la zone nommée Zone2 de la feuille 'F1' sur la première ligne vide en A de la feuille 'F2'
    Sheets("F1").Range("Zone2").Copy .Range("A1").Offset(Sheets("F1").Range("Zone1").Rows.Count)
' Pour l 'Aperçu
    .PrintPreview
' Pour Imprimer
'  .PrintOut
    End With
End Sub

A+ à tous

 

[soenda]

Re : imprimer des plages de cellules non-continues

Re, Bonsoir JCGL

le code affiche "objet requis" sur la ligne .Cells.Clear

L'objet c'est Feuil2, ce qui signifie que tu as oublié le point (en rouge ci-dessus).

Si je ne m'abuse ...

De plus pour les tests on peut utiliser .PrintPreview (plutôt que .Printout)

A plus

 

[naitgo]

Re : imprimer des plages de cellules non-continues

Bonjour à tous,
Merci JCGL et Soenda pour votre aide,
Le code de JCGL fonctionne bien. Je ne voudrais pas abuser, mais est-il possible de créer et de supprimer la feuille 2 à chaque fois qu'on lance la macro.
A plus, Naitgo

 

[Roland_M]

Re : imprimer des plages de cellules non-continues

bonjour

ci-joint les deux macros à placer dans un module

Public Sub CreerCetteFeuil(Feuil$)
SupprimerCetteFeuil Feuil$ 'avant par sécurité !
ThisWorkbook.Sheets.Add.Name = Feuil$
'A VOIR SELON BESOIN !?
'ActiveWindow.DisplayHeadings = False 'sans no colon/lign
'ActiveWindow.DisplayGridlines = False 'sans quadrillage
End Sub

Public Sub SupprimerCetteFeuil(Feuil$)
Dim EtatAlerts As Boolean
EtatAlerts = Application.DisplayAlerts
On Error Resume Next: Err.Clear: Application.DisplayAlerts = False
ThisWorkbook.Sheets(Feuil$).Delete
On Error GoTo 0: Err.Clear: Application.DisplayAlerts = EtatAlerts
End Sub