Gérer et envoyer par courriel fichier pdf

[esthetique]

Bonjour Groupe,

J'ai le code pour gérer un fichier PDF et envoyer par courriel.
Le problème est qui le code pour envoyer le fichier par courriel ne marche pas.

Est ce quelqu'un peut m'aider?

Merci

Sub pdf()
ChDir "C:\Users\Rafael\Documents\"
ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:=Format([H15], "yyyymmddhhmm") & [B16] & ".pdf", Quality:=xlQualityStandard, _
IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:= _
True
MsgBox "Votre facture est prête pour l'impression !"

Set objMessage = CreateObject("CDO.Message")
objMessage.Subject = "Sujet du Message"
objMessage.From = "xxx@hotmail.com"
objMessage.To = Range("H15").Select 'cherche le courriel dans le fichier excel'
objMessage.TextBody = "Bonjour," & vbCrLf & "Veuillez trouver en piéce jointe votre facture" & vbCrLf
piece_jointe = "C:\Users\ & [H15] & [B16].PDF" ' cherche le fichier pdf dans le chemise selon le nome du fichier qui a ete gerer'

objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2

objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "mail.muserver.com"

objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25

objMessage.Configuration.Fields.Update

objMessage.Send


End Sub

 

[Staple1600]

Re : Gérer et envoyer par courriel fichier pdf

Bonjour à tous

esthetique
Ta référence à CDO est bien cochée dans VBE ?
Et personnellement j'ajouterai les Dim adéquats en début de code.

PS: Si ces deux lignes plus haut sont du charabia, alors c'est que tu débutes en VBA alors bienvenue dans ce monde merveilleux 😉

EDITION: Bonjour BrunoM45 😉

 

[Compte Supprimé 979]

Re : Gérer et envoyer par courriel fichier pdf

Bonjour le fil

Le code que tu nous as donné ne peut pas être utiliser sans modification

Voici celui que je te propose

' [url=http://www.rondebruin.nl/win/s1/cdo.htm]Sending mail from Excel with CDO[/url]
Sub EnvoisPDF()
  Dim sPath As String, sFic As String
  Dim ObjMessage As Object
  ' Définir le chemin d'accès au fichier PDF
  sPath = "C:\Users\Rafael\Documents\"
  ' Définir le nom du fichier
  sFic = Format([H15], "yyyymmddhhmm") & [B16] & ".pdf"
  ' Exporte la feuille dans ce répertoire
  ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:=sPath & sFic, Quality:=xlQualityStandard, _
                                  IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:=True
  '
  MsgBox "Votre facture est prête pour l'impression !"
  ' Définir l'objet CDO
  Set ObjMessage = CreateObject("CDO.Message")
  ' Avec l'objet
  With ObjMessage
    ' Définir la configuration d'envoi
    With .Configuration.Fields
      .Item("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
      .Item("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "Nom du serveur SMTP=serveur FAI"
      .Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25
      .Update
    End With
    ' Définir les options d'envois
    .Subject = "Sujet du Message"
    .From = "xxx@hotmail.com"
    .To = "destinataire"
    .TextBody = "Bonjour," & vbCrLf & "Veuillez trouver en piéce jointe votre facture" & vbCrLf
    ' Ne pas oublier de joindre le fichier
    .AddAttachment sPath & sFic
    ' Envoyer le mail
    .Send
  End With
End Sub

Il est également à adapter à tes besoins

A+