garder même format chiffres en texte

[cathodique]

Bonjour,

SVP, les données de la feuille "Bon de Cde" sont transférées sur la feuille "suivi cde" en utilisant des tableaux vba. Le problème est qu'en colonne A de la feuille "Bon de Cde", il y des chiffres au format texte et lors du transfert ils sont convertis sur la feuille "suivi cde" au format nombre.
Comment garder le même format texte.

Option Explicit

Sub Transfert()
    Dim i&
    Dim Plg As Range, PLg_EnTete As Range
    Dim T_EnTete As Variant, T_Data As Variant, T_Report As Variant

    With Sheets("Bon de cde")
        Set Plg = .Range(.Cells(8, 1), .Cells(.Rows.Count, 1).End(3).Offset(, 3))
        T_EnTete = .Range("A1:D5")
    End With
  
    T_Data = Plg
    ReDim T_Report(1 To UBound(T_Data, 1), 1 To 6)

    For i = LBound(T_Data, 1) To UBound(T_Data, 1)
        T_Report(i, 1) = T_EnTete(1, 4)           'n° bon de commande
        T_Report(i, 2) = CDate(T_EnTete(3, 4))      'date de demande
        T_Report(i, 5) = T_EnTete(5, 2)        'N° Affaire

'        'On boucle sur les colonnes du tableau T_Report
        T_Report(i, 3) = CStr(T_Data(i, 1))       'ref interne
        T_Report(i, 4) = T_Data(i, 2)       'Désignation produit
        T_Report(i, 6) = T_Data(i, 3)        'quantité

    Next i
      
    Sheets("Suivi cde").Cells(Rows.Count, 1).End(3)(2).Resize(UBound(T_Report, 1), UBound(T_Report, 2)) = T_Report

End Sub

Merci.

PS: Pourquoi cette astuce pour enjoliver le code ne fonctionne plus: [highlight=VBA] Code [/highlight ]

 

[Chris24]

Bonjour

Tout simplement et sans passer par un format en vba, tu formates ta colonne C de la feuille suivi au format texte

Cdt

 

[cathodique]

Bonjour Chris24,
Merci pour ton retour.
Je voulais tout simplement apprendre à le faire en VBA.

Bonne fin de semaine.

 

[Staple1600]

Bonsoir à tous

Bonjour,
PS: Pourquoi cette astuce pour enjoliver le code ne fonctionne plus: [highlight=VBA] Code [/highlight ]

Le moment Enjoliveur
[CODE=VB]
code vba
code vba
code vba
[/CODE]
Oh la belle bleue 😉

Sub Macro1()
Msgbox "Hello, world!"
'ligne de commentaire
End Sub

 

[Chris24]

Bonsoir

après next i

    With Sheets("Suivi cde")
        .Range("C2:C" & .[C65000].End(xlUp).Row + UBound(T_Report)).NumberFormat = "@"
        .Cells(Rows.Count, 1).End(3)(2).Resize(UBound(T_Report, 1), UBound(T_Report, 2)) = T_Report
    End With
[fin code]
Cdt

 

[cathodique]

Bonjour,

@ Staple1600, je mettais highLight=VBA. J'ai compris dorénavant, je dois mettre Code=VB. Merci beaucoup.

@ Chris24 , Je te remercie beaucoup. C'est exactement ce que je cherchais à obtenir.

Merci à vous.