Formules imbriquées

Lipadec · 25 Novembre 2010

Bonjour le Forum

J'ai des formules que je veux appliquer dans une même cellule, mais je ne suis pas arrivé à réaliser ce travail. Veuillez m'aider ou me donner une formule plus simple à la place

Voici les formules en question

=SI(ET(G2="ACHAT GAB";P2<>"EXO");MOIS.DECALER(L2;1);"")
=SI(ET(G2="AGIOS";P2<>"EXO");MOIS.DECALER(L2;1);"")
=SI(ET(G2="CHQ PAYE";P2<>"EXO");MOIS.DECALER(L2;1);"")
=SI(ET(G8="CHQ RECU";P8<>"EXO");MOIS.DECALER(L8;1);"")
=SI(ET(G2="EFFET IMPAYE";P2<>"EXO");MOIS.DECALER(L2;1);"")
=SI(ET(G2="EFFET PAYE";P2<>"EXO");MOIS.DECALER(L2;1);"")
=SI(ET(G2="VIR EMIS";P2<>"EXO");MOIS.DECALER(L2;1);"")
=SI(ET(G2="VIR RECU";P2<>"EXO");L2;"")
=SI(ET(G2="EFFET RECU";P2<>"");(INDEX(EAR;EQUIV(H2;EAR_RSE;0);18));"")

Je voudrai grouper ces formules comme suit:

=SI(ET(G2="ACHAT GAB";P2<>"EXO");MOIS.DECALER(L2;1);SI(ET(G2="AGIOS";P2<>"EXO");MOIS.DECALER(L2;1);SI(ET(G2="CHQ PAYE";P2<>"EXO");MOIS.DECALER(L2;1);SI(ET(G8="CHQ RECU";P8<>"EXO");MOIS.DECALER(L8;1);SI(ET(G2="EFFET IMPAYE";P2<>"EXO");MOIS.DECALER(L2;1);SI(ET(G2="EFFET PAYE";P2<>"EXO");MOIS.DECALER(L2;1);SI(ET(G2="VIR EMIS";P2<>"EXO");MOIS.DECALER(L2;1);SI(ET(G2="VIR RECU";P2<>"EXO");L2;SI(ET(G2="EFFET RECU";P2<>"");(INDEX(EAR;EQUIV(H2;EAR_RSE;0);18));"")))))))))

Une fenêtre me dit: La formule que vous avez tapée contient une erreur

mais je ne vois pas cette erreur;

Merci pour votre aide

Lipadec

ERIC S · 25 Novembre 2010

Re : Formules imbriquées

Bonsoir

sans doute trop de SI imbriqués, on doit être limité à 7

ballmaster · 25 Novembre 2010

Re : Formules imbriquées

Ta formule est juste je l'ai testée.

Mais elle trop longue. Ta formule est limitée à un certain nombre de caractères, et la, c'est dépassé.

ERIC S · 25 Novembre 2010

Re : Formules imbriquées

Re

elle est sans doute simplifiable mais il faudrait que tu donnes toutes les possibilités pour G2, P2

il est aussi surprenant de trouver un G8, P8 au milieu.....

Tibo · 25 Novembre 2010

Re : Formules imbriquées

Bonjour Lipadec, salut Eric, salut ballmaster,

Un fichier aurait été le bienvenu pour nous aider à tester ta formule.

Essaye avec ceci :

Code:

=SI(ET(OU(G2="AGIOS";G2="CHQ PAYE";G2="EFFET IMPAYE";G2="EFFET PAYE";G2=
"VIR EMIS");P2<>"EXO");MOIS.DECALER(L2;1);SI(ET(G8="CHQ RECU";P8<>"EXO");
MOIS.DECALER(L8;1);SI(ET(G2="VIR RECU";P2<>"EXO");L2;SI(ET(G2="EFFET RECU";
P2<>"");INDEX(EAR;EQUIV(H2;EAR_RSE;0);18); ""))))

Sans trop de certitudes faute de fichier

@+

Lipadec · 25 Novembre 2010

Re : Formules imbriquées

Re Bonjour à tout le monde

Merci à vous tous pour vos réponses si vite, c'est vrai que j'ai oublié de changer le G8 et P8 par G2 et P2
Mais la formule que m'a donné Tibo est valable et marche très bien pour la suite du fichier

Merci une autre fois

Lipadec

Tibo · 25 Novembre 2010

Re : Formules imbriquées

re,

La formule proposée tenait compte du G8 et du P8

Proposition de correction :

Code:

=SI(ET(OU(G2="AGIOS";G2="CHQ PAYE";G2="CHQ RECU";G2="EFFET IMPAYE";G2="EFFET 
PAYE";G2="VIR EMIS");P2<>"EXO");MOIS.DECALER(L2;1);SI(ET(G2="VIR RECU";P2<>
"EXO");L2;SI(ET(G2="EFFET RECU";P2<>"");INDEX(EAR;EQUIV(H2;EAR_RSE;0);18);"")))

@+

Formules imbriquées

Lipadec

XLDnaute Occasionnel

ERIC S

XLDnaute Barbatruc

ballmaster

XLDnaute Occasionnel

ERIC S

XLDnaute Barbatruc

Tibo

XLDnaute Barbatruc

Lipadec

XLDnaute Occasionnel

Tibo

XLDnaute Barbatruc

Discussions similaires

Formules imbriquées

Lipadec

XLDnaute Occasionnel

ERIC S

XLDnaute Barbatruc

ballmaster

XLDnaute Occasionnel

ERIC S

XLDnaute Barbatruc

Tibo

XLDnaute Barbatruc

Lipadec

XLDnaute Occasionnel

Tibo

XLDnaute Barbatruc

Discussions similaires

Privacy & Transparency

Privacy & Transparency