Formule - Valeur égale ou sup dans ligne

gourdin · 13 Septembre 2016

Bonjour
Je na'rrive pas à trouver la formule qui me donnerait la valeur égale ou immédiatement supérieur dans une ligne d'un tableau (en évitant formule matricielle utilisant Ctrl+Maj+Entrée)

Exemple en pièce jointe.

Merci

JBOBO · 13 Septembre 2016

Bonjour,

Il y a surement plus simple, mais tu peux essayer en C19 : =INDIRECT(ADRESSE(EQUIV($C$17;$B:$B;0);SIERREUR(EQUIV($C$18;INDIRECT(ADRESSE(EQUIV($C$17;$B:$B;0);1)&":"&ADRESSE(EQUIV($C$17;$B:$B;0);26));0);EQUIV($C$18;INDIRECT(ADRESSE(EQUIV($C$17;$B:$B;0);1)&":"&ADRESSE(EQUIV($C$17;$B:$B;0);26));1)+1)))

Hieu · 13 Septembre 2016

Salut gourdin, JBOBO,

Un autre idée, avec index equiv imbriqué :

Code:

=INDEX(INDEX(C4:M14;EQUIV(C17;B4:B14;0);0);
    SIERREUR(EQUIV(C18;INDEX(C4:M14;EQUIV(C17;B4:B14;0);0);0);EQUIV(C18;INDEX(C4:M14;EQUIV(C17;B4:B14;0);0);1)+1))

gourdin · 13 Septembre 2016

Merci JBOBO et HIEU

Vos formules fonctionnent correctement sauf pour des valeurs inférieurs à la première colonne (Cat 1 dans l'exemple)
Exemple si valeur cherchée "Cat" = 10, il y a le message d'erreur #N/A

Hieu · 13 Septembre 2016

New test :::

Ajout d'une condition :

Code:

=INDEX(INDEX(C4:M14;EQUIV(C17;B4:B14;0);0);
        SI(C18<INDEX(C4:M14;EQUIV(C17;B4:B14;0);1);1;
                SIERREUR(EQUIV(C18;INDEX(C4:M14;EQUIV(C17;B4:B14;0);0);0);EQUIV(C18;INDEX(C4:M14;EQUIV(C17;B4:B14;0);0);1)+1)))

Hieu · 13 Septembre 2016

Ou dans ce sens là :

Code:

=SI(C18<INDEX(C4:M14;EQUIV(C17;B4:B14;0);1);INDEX(C4:M14;EQUIV(C17;B4:B14;0);1);
    INDEX(INDEX(C4:M14;EQUIV(C17;B4:B14;0);0);
                SIERREUR(EQUIV(C18;INDEX(C4:M14;EQUIV(C17;B4:B14;0);0);0);EQUIV(C18;INDEX(C4:M14;EQUIV(C17;B4:B14;0);0);1)+1)))

gourdin · 13 Septembre 2016

Très bien merci

Formule - Valeur égale ou sup dans ligne

gourdin

XLDnaute Impliqué

Pièces jointes

JBOBO

XLDnaute Accro

Hieu

XLDnaute Impliqué

Pièces jointes

gourdin

XLDnaute Impliqué

Hieu

XLDnaute Impliqué

Pièces jointes

Hieu

XLDnaute Impliqué

Pièces jointes

gourdin

XLDnaute Impliqué

Discussions similaires