XL 2021 problème de formule conditionnelle

[florian.]

Bonjour, j'ai une formule qui marche très bien pour toutes les conditions hormis pour la dernière quand C5="F" et que C6 est compris entre 40 et 49. En effet la cellule marque "FAUX" :
=SI(C5="H";
SI(C6<30;
SI(C9="un";C11+100;
SI(C9="deux";C11+300;
SI(C9="trois";C11+500;
SI(C9="quatre";C11+700;
SI(C9="cinq";C11+900;0)))));
SI(ET(C6>=30;C6<40);
SI(C9="un";C11+175;
SI(C9="deux";C11+375;
SI(C9="trois";C11+575;
SI(C9="quatre";C11+775;
SI(C9="cinq";C11+975;0)))));
SI(ET(C6>=40;C6<50);
SI(C9="un";C11+225;
SI(C9="deux";C11+425;
SI(C9="trois";C11+625;
SI(C9="quatre";C11+825;
SI(C9="cinq";C11+1025;0)))));
SI(C5="F";
SI(C6<30;
SI(C9="un";C11+50;
SI(C9="deux";C11+250;
SI(C9="trois";C11+450;
SI(C9="quatre";C11+650;
SI(C9="cinq";C11+850;0)))));
SI(ET(C6>=30;C6<40);
SI(C9="un";C11+125;
SI(C9="deux";C11+325;
SI(C9="trois";C11+525;
SI(C9="quatre";C11+725;
SI(C9="cinq";C11+925;0)))));
SI(ET(C6>=40;C6<50);
SI(C9="un";C11+175;
SI(C9="deux";C11+375;
SI(C9="trois";C11+575;
SI(C9="quatre";C11+775;
SI(C9="cinq";C11+975;0)))))))))))))

 

[Cousinhub]

Bonjour,
Et bienvenue sur Xld...
JE pense qu'une bonne partie de ton problème pourrait trouver un bon début de solution en lisant attentivement ce document, notamment les points 2.3, 2.4 et 2.5...
Bonne lecture

 

[Gégé-45550]

Bonjour, j'ai une formule qui marche très bien pour toutes les conditions hormis pour la dernière quand C5="F" et que C6 est compris entre 40 et 49. En effet la cellule marque "FAUX" :
=SI(C5="H";
SI(C6<30;
SI(C9="un";C11+100;
SI(C9="deux";C11+300;
SI(C9="trois";C11+500;
SI(C9="quatre";C11+700;
SI(C9="cinq";C11+900;0)))));
SI(ET(C6>=30;C6<40);
SI(C9="un";C11+175;
SI(C9="deux";C11+375;
SI(C9="trois";C11+575;
SI(C9="quatre";C11+775;
SI(C9="cinq";C11+975;0)))));
SI(ET(C6>=40;C6<50);
SI(C9="un";C11+225;
SI(C9="deux";C11+425;
SI(C9="trois";C11+625;
SI(C9="quatre";C11+825;
SI(C9="cinq";C11+1025;0)))));
SI(C5="F";
SI(C6<30;
SI(C9="un";C11+50;
SI(C9="deux";C11+250;
SI(C9="trois";C11+450;
SI(C9="quatre";C11+650;
SI(C9="cinq";C11+850;0)))));
SI(ET(C6>=30;C6<40);
SI(C9="un";C11+125;
SI(C9="deux";C11+325;
SI(C9="trois";C11+525;
SI(C9="quatre";C11+725;
SI(C9="cinq";C11+925;0)))));
SI(ET(C6>=40;C6<50);
SI(C9="un";C11+175;
SI(C9="deux";C11+375;
SI(C9="trois";C11+575;
SI(C9="quatre";C11+775;
SI(C9="cinq";C11+975;0)))))))))))))

Bonjour,
Comme vous l'a fait comprendre Cousinhub (approuvé par Usine à gaz), il convient, si vous espérez obtenir une quelconque réponse, de joindre à votre post un fichier anonymisé contenant votre problématique et le résultat attendu.

Dans la formule que vous affichez (déjà, comme ça, d'un coup d'œil, elle donne envie de fuir en courant), on ne voit nulle part la condition :

quand C5="F" et que C6 est compris entre 40 et 49

Avec un fichier, vous aurez des réponses ; sans fichier, c'est beaucoup moins probable.
Pour finir, au minimum, lorsque vous citez du code, utilisez la balise adéquate (</>).
Cordialement,

 

[Dranreb]

Bonjour.
À priori c'est :

=C11+INDEX({100.175.225.0;300.375.425.0;500.575.625.0;700.775.825.0;900.975.1025.0};EQUIV(C9;{"un";"deux";"trois";"quatre";"cinq"};0);EQUIV(C6;{0.30.40.50};1))-SI(C5="F";50;0)

Mais vous auriez intéret à porter ces chiffres quelque part dans un petit tableau …

 

[Dranreb]

… qui peut encore se raccourcir en :

=C11+100*(EQUIV(C9;{"un";"deux";"trois";"quatre";"cinq"};0)*2-1)+INDEX({0;75;125;0};EQUIV(C6;{0;30;40;50};1))-SI(C5="F";50;0)

 

[florian.]

… qui peut encore se raccourcir en :

=C11+100*(EQUIV(C9;{"un";"deux";"trois";"quatre";"cinq"};0)*2-1)+INDEX({0;75;125;0};EQUIV(C6;{0;30;40;50};1))-SI(C5="F";50;0)

Wow bravo, merci beaucoup, vous êtes vraiment très doué !