formule excel

[momo2394]

Bonjour le forum et une très bonne année 2014

Je reviens vers vous pour une formule ci dessous et j'aimerai la simplifier sachant que j'ai 450 cellules x 3
à proteger

Merci

Private Sub Worksheet_selectionChange(ByVal Target As Range)
If Target.Address(0, 0) = "E2" Then Range("G2").Select
If Target.Address(0, 0) = "E3" Then Range("G2").Select
If Target.Address(0, 0) = "E4" Then Range("G2").Select
If Target.Address(0, 0) = "E5" Then Range("G2").Select
If Target.Address(0, 0) = "E6" Then Range("G2").Select

If Target.Address(0, 0) = "F2" Then Range("G2").Select
If Target.Address(0, 0) = "F3" Then Range("G2").Select
If Target.Address(0, 0) = "F4" Then Range("G2").Select
If Target.Address(0, 0) = "F5" Then Range("G2").Select
If Target.Address(0, 0) = "F6" Then Range("G2").Select

If Target.Address(0, 0) = "J2" Then Range("G2").Select
If Target.Address(0, 0) = "J3" Then Range("G2").Select
If Target.Address(0, 0) = "J4" Then Range("G2").Select
If Target.Address(0, 0) = "J5" Then Range("G2").Select
If Target.Address(0, 0) = "J6" Then Range("G2").Select


End Sub

 

[Pierrot93]

Re : formule excel

Bonsoir,

essaye peut être ceci :

Option Explicit
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
If Not Intersect(Target, Range("E2:F6,J2:J6")) Is Nothing Then
    Application.EnableEvents = False
    Range("G2").Select
    Application.EnableEvents = True
End If
End Sub

bonne soirée
@+

 

[momo2394]

Re : formule excel

Merci Pierrot93
ça fonctionne super bien

serait il possible que quand la cible se trouve sur E2 ou F2 ou J2 le curseur se positionne sur G2 ainsi de suite
E3 ou F3 ou J3 se positionne sur G3 ainsi de suite

Merci

 

[Pierrot93]

Re : formule excel

Re,

modifie comme suit :

Option Explicit
 Private Sub Worksheet_SelectionChange(ByVal Target As Range)
 If Not Intersect(Target, Range("E2:F6,J2:J6")) Is Nothing Then
     Application.EnableEvents = False
     Range("G" & Target.Row).Select
     Application.EnableEvents = True
 End If
 End Sub

 

[momo2394]

Re : formule excel

Excellent Pierrot93

Encore Merci et bonne soirée