Formule dans cellule

[KTM]

Salut chers tous
Cela fait des heures que je teste cette macro mais elle bute au niveau de ( cel.Formula = "=" & cel )
Je ne comprends pas. Quelqu'un pourrait il me corriger ? Merci

Sub Reinitialiser_Base()

Application.ScreenUpdating = False
With Sheets("Base")
.Range("E7:E37").Value = .Range("K7:K37").Value
.Range("N7:W37") = ""
.Range("J7:J37").Value = 0
For Each cel In .Range("E7:E37,M7:M37,J7:J37")
cel.Formula = "=" & cel
Next cel
End With
Application.ScreenUpdating = True

End Sub

 

[job75]

Bonjour KTM, le forum,

For Each cel In .Range("E7:E37,M7:M37,J7:J37")
If IsNumeric(CStr(cel)) Then cel.FormulaLocal = "=" & cel Else cel.Formula = "=""" & cel & """"
Next cel

Bonne journée.

 

[KTM]

Bonjour Job75
Si on ne vous l'a jamais dit , je confesse que vous êtes un savant , un AS du VBA.
Merci infiniment et durablement.
Que les dieux du VBA vous protègent!!!!!
A+

 

[KTM]

Pouvez vous apporter des explications au code ?
C'est fort pour moi
Merci Encore

 

[job75]

Ceci est encore plus fort car on traite aussi les valeurs logiques et les valeurs d'erreur :

For Each cel In .Range("E7:E37,M7:M37,J7:J37")
    If IsNumeric(CStr(cel)) Then
        cel.FormulaLocal = "=" & cel
    ElseIf CStr(cel) = "" Or Application.IsText(cel) Then
        cel.Formula = "=""" & cel & """"
    ElseIf Application.IsLogical(cel) Or IsError(cel) Then
        cel.FormulaLocal = "=" & cel.Text
    End If
Next cel

 

[job75]

Ce qu'il faut bien comprendre :

- IsNumeric(cel) renvoie True si cel est vide c'est pour cela que j'utilise CStr

- CStr évite aussi un bug si cel est une valeur d'erreur

- FormulaLocal conserve les propriétés de l'ordinateur : séparateur décimal, langue.

 

[KTM]

Bien compris Bénédiction à vous !