format csv

Sub testExportCsv()

'déclaration des variables
Dim derCol As Long, derLig As Long, iL As Long, iC As Long
Dim pathFichierCsv As String, ligneCsv As String
Dim fichierCsv As Object

    'définition du fichier csv destination
    pathFichierCsv = "c:\fichierCsv.csv"
    
    'créer/ouvrir le fichier csv en écriture
    Set fichierCsv = CreateObject("Scripting.FileSystemObject").OpenTextFile(pathFichierCsv, 2, True)
    
    With ThisWorkbook.Sheets("Feuil1")
    
        'claculer le numéro de la dernière colonne
        derCol = .Cells(1, .Columns.Count).End(xlToLeft).Column
        'claculer le numéro de la dernière ligne
        derLig = .Cells(.Rows.Count, 1).End(xlUp).Row
        
        'boucler sur toutes les lignes
        For iL = 1 To derLig
            'initialiser la ligne csv
            ligneCsv = ""
            'boucler sur toutes les colonnes
            For iC = 1 To derCol
                'ajouter l'élément à la ligne csv et un ";"
                ligneCsv = ligneCsv & .Cells(iL, iC).Text & ";"
            Next iC
            'enlever le dernier ";" à la ligne csv
            ligneCsv = Left(ligneCsv, Len(ligneCsv) - 1)
            'écrire la ligne csv dans le fichier csv
            fichierCsv.WriteLine ligneCsv
        Next iL
    End With
        
    'fermer le fichier csv
    fichierCsv.Close: Set fichierCsv = Nothing
End Sub