Fonctions MIN, SI et ET imbriquées.

J

JHA

XLDnaute Barbatruc

• 10 Avril 2019

• #2

Bonjour à tous,

Avec des plages nommées dynamiques et la formule min() en matricielle
Exemple de formule, avec "CA<>0" pour éviter les zéros

VB:

=MIN(SI((Nom=$K6)*(CA>=50)*(CA<90)*(DOB=$M6)*(Ville=$N6)*(CA<>0);CA))

JHA

 

Pièces jointes

• Exercices Excel.xlsx

  33 KB · Affichages: 5

Vote positif 0 Vote négatif

Jocelyn

XLDnaute Barbatruc

• 10 Avril 2019

• #3

Bonjour le Forum,
Bonjour Matt68524, l'ami JHA,

pour tenir compte des et qui dans la formule doivent se transformer en ou puisqu'une même cellule ne peut pas etre a la fois - Années : 1979 et 1980 et même chose concernant les villes - Villes : Lyon et Lille.

La formule deviendrait en matricielle bien sur

VB:

=MIN(SI(($F$2:$F$51="Martin")*(($I$2:$I$51="Lyon")+($I$2:$I$51="Lille"))*(($H$2:$H$51=1979)+($H$2:$H$51=1980))*($G$2:$G$51>50)*($G$2:$G51<=75);$G$2:$G$51))

explication

cette partie de formule ($F$2:$F$51="Martin")*(($I$2:$I$51="Lyon")+($I$2:$I$51="Lille")) signifie = martin et (=Lyon ou lille)

Cordialement

 

Vote positif 0 Vote négatif

M

Matt68524

XLDnaute Nouveau

• 29 Avril 2019

• #4

Bonjour,

Dans ma formule en L12, j'essaie de trouver le C.A. minimum qui respecte les conditions suivantes : Martin, 75>=C.A.>25, 1979, Nancy.

Ma formule me renvoie la valeur zéro (alors qu'en conditions je lui spécifie 25>C.A.>=75). Mais lorsqu'à la place de Nancy je mets Lyon ou Lille, la formule fonctionne et me renvoie une valeur correcte ! Je ne comprends pas ce qu'il se passe, pouvez-vous m'aider ? Merci...

Edit: La particularité quand je mets Nancy au lieu de Lyon ou Lille, c'est qu'il n'y a pas de cellules en G2:G51 qui satisfassent toutes les conditions. Mais même en rajoutant "-" à la fin de fonction SI, ma formule me renvoie toujours 0 comme valeur (au lieu de "-")...

 

Pièces jointes

• Exercices Excel.xlsx

  31.7 KB · Affichages: 4

Dernière édition: 29 Avril 2019

Vote positif 0 Vote négatif

J

JHA

XLDnaute Barbatruc

• 29 Avril 2019

• #5

Bonjour à tous,

C'est juste d'avoir 0 car Martin et Nancy le CA = 79 alors que tu demandes <=75

JHA

 

Pièces jointes

• Exercices Excel.xlsx

  34.1 KB · Affichages: 5

Vote positif 0 Vote négatif

M

Matt68524

XLDnaute Nouveau

• 29 Avril 2019

• #6

Je demande >25 et <=75...

 

Vote positif 0 Vote négatif

J

JHA

XLDnaute Barbatruc

• 29 Avril 2019

• #7

Bonjour à tous,

Regardes le filtre

JHA

 

Vote positif 0 Vote négatif

M

Matt68524

XLDnaute Nouveau

• 29 Avril 2019

• #8

C'est à dire ?

 

Vote positif 0 Vote négatif

J

JHA

XLDnaute Barbatruc

• 29 Avril 2019

• #9

Bonjour à tous,

79 est plus grand que 75 donc pas pris en compte.

JHA

 

Vote positif 0 Vote négatif

M

Matt68524

XLDnaute Nouveau

• 29 Avril 2019

• #10

Ma formule: =MIN(SI((F2:F51=F2)*(G2:G51>25)*(G2:G51<=75)*(H2:H51=1979)*(I2:I51="Nancy");G2:G51;"-"))

Je demande la valeur la plus basse en G2:G51, qui satisfait toutes les autres conditions (dont : G2:G51>25 et G2:G51<=75), autrement je demande de me renvoyer "-". C'est pourquoi je ne comprends pas pourquoi la formule me renvoie 0.

 

Vote positif 0 Vote négatif

J

JHA

XLDnaute Barbatruc

• 29 Avril 2019

• #11

Bonjour à tous,

VB:

=SI(MIN(SI((F2:F51=F2)*(G2:G51>25)*(G2:G51<=75)*(H2:H51=1979)*(I2:I51="Nancy");G2:G51))=0;"-";MIN(SI((F2:F51=F2)*(G2:G51>25)*(G2:G51<=75)*(H2:H51=1979)*(I2:I51="Nancy");G2:G51)))

JHA

 

Vote positif 0 Vote négatif

M

Matt68524

XLDnaute Nouveau

• 29 Avril 2019

• #12

Il semblerait que votre formule ne soit pas bonne non plus ar quand je change "Nancy" en "Lyon" votre formule me renvoie toujours 0, alors qu'elle devrait me retourner 58...

 

Vote positif 0 Vote négatif

Jocelyn

XLDnaute Barbatruc

• 29 Avril 2019

• #13

Bonjour le Forum,
Bonjour Matt68524,l'ami JHA ,

Première info quand le min ne trouve rien il renvoie 0,

Alors pour éviter de faire une formule si avec 2 fois la formule min(si( je préfère une formule petite.valeur(si( qui elle enverra une valeur d'erreur au cas ou rien ne correspond de la on utilise sierreur() en matricielle bien sur

VB:

=SIERREUR(PETITE.VALEUR(SI((F2:F51=F2)*(G2:G51>25)*(G2:G51<=75)*(H2:H51=1979)*(I2:I51="Nancy");G2:G51);1);"-")

Voir fichier joint

Cordialement

PS : la formule de JHA fonctionne très bien a priori

 

Pièces jointes

• Exercices Excel.xlsx

  32 KB · Affichages: 6

Vote positif 0 Vote négatif

M

Matt68524

XLDnaute Nouveau

• 30 Avril 2019

• #14

Merci !

Effectivement la formule de JHA fonctionne très bien... my mistake...

 

Vote positif 0 Vote négatif

M

Matt68524

XLDnaute Nouveau

• 1 Mai 2019

• #15

Bonjour les gourous,

Question 1 :

La solution de JHA était :
=SI(MIN(SI((F2:F51=F2)*(G2:G51>25)*(G2:G51<=75)*(H2:H51=1979)*(I2:I51="Nancy");G2:G51))=0;"-";MIN(SI((F2:F51=F2)*(G2:G51>25)*(G2:G51<=75)*(H2:H51=1979)*(I2:I51="Nancy");G2:G51))).

J'aurais voulu savoir comment on nomme une erreur dans excel, de manière à ce que je puisse remplacer MIN(SI( ,dans la formule de JHA, par PETITE.VALEUR(SI( :
=SI(PETITE.VALEUR(SI((F2:F51=F2)*(G2:G51>25)*(G2:G51<=75)*(H2:H51=1979)*(I2:I51="Nancy");G2:G51))="erreur";
"-";PETITE.VALEUR(SI((F2:F51=F2)*(G2:G51>25)*(G2:G51<=75)*(H2:H51=1979)*(I2:I51="Nancy");G2:G51))).

Question 2 :

Et pour faire l'inverse, si dans la formule de Jocelyn,... :
=SIERREUR(PETITE.VALEUR(SI((F2:F51=F2)*(G2:G51>25)*(G2:G51<=75)*(H2:H51=1979)*(I2:I51="Nancy");G2:G51);1);"-")
...je souhaite remplacer PETITE.VALEUR par MIN, est-ce-qu'il y a une possibilité pour déclarer la valeur 0 (quand MIN ne trouve rien) comme
une erreur ?

Merci pour tous vos conseils...

 

Vote positif 0 Vote négatif