Fonction "SI"

[Thong]

Bonjour,

J'ai un petit souci avec la fonction 'si' dans l'excel. Voilà, j'essaie de créer une formule avec plusieurs 'si' imbriqués. Le problème est qu'Excel n'accepte qu'un nombre limité de conditions imbriquées (à savoir 8).

Voici un exemple de ladite formule (la dernière condition ne passe pas !!!):

=SI(B3=S3;T3;SI(B3=S4;T4;SI(B3=S5;T5;SI(B3=S6;T6;SI(B3=S7;T7;SI(B3=S8;T8;SI(B3=S9;T9;SI(B3=S10;T10;SI(B3=S11;T11)))))))))


Auriez-vous une solution pour mon problème ? Merci infiniment.

Thong

 

[ERIC S]

Bonjour

pas trop letemps mais une possibilité sans chercher à utiliser d'autres formules

si chiffres :

=si(gfgf;si(....(si(fdf;vrai;0)+ si(......)
ton premier membre=0 donc ne perturbe pas addition

si texte remplacer 0 par '' (vide) et + par &

A+

 

[andré]

Salut,

Peut-être un peu plus simple :

=(B3=S3)*T3+(B3=S4)*T4+(B3=S5)*T5+(B3=S6)*T6+(B3=S7)*T7+(B3=S8)*T8+(B3=S9)*T9+(B3=S10)*T10+(B3=S11)*T11

Mais il doit encore il y avoir plus simple, du fait qu'on récupère une donnée sur la même ligne que le critère.
Je regarde et te dis quoi.

Â+

 

[andré]

Resalut,

Mais c'est évident !

=RECHERCHEV(B3;S3:T11;2;0)

Â+

 

[andré]

Re:Fonction \"SI\"

Rere,

Et une variante pour ceux qui n'aiment pas le RECHERCHEV :

=INDEX(T3:T11;EQUIV(B3;S3:S11))

Â+

EDITION :
Oups, le smiley !
=INDEX(T3:T11;EQUIV(B3;S3: S11))
Il faut enlever l'espace après le :

Message édité par: andré, à: 03/03/2006 09:49