fonction si

[lucbrady]

Bonjour,
Aidez-moi SVP !
Je souhaite intégrer la fonction si pour établir un barème de 0 à 20 en fonction d’une performance. Or, voilà le message d’Excel « impossible d’entrée la formule car elle utilise plus de niveaux d’imbrication que ne l’autorise le format du fichier actuel ».
Pourriez-vous m’aider à créer ce barème que je souhaiterai terminer ce soir.
MERCI
LUCBRADY
voici la fonction si pour créer mon barème qui ne focntionne pas..
=SI(B13<=21;"0";SI(B13<=22,5;"1";SI(B13<=23,63;"2";SI(B13<=24,73;"3";SI(B13<=25,89;"4";SI(B13<=27,09;"5";SI(B13<=28,36;"6";SI(B13<=29,68;"7";SI(B13<=31,07;"8";SI(B13<=32,52;"9";SI(B13<=34,04;"10";SI(B13<=35,63;"11";SI(B13<=37,30;"12" ; SI(B13<=35,63;"11";SI(B13<=37,30;"12";SI(B13<=39,04;"13" SI(B13<=40,86;"14";SI(B13<=42,77;"15";SI(B13<=44,77;"16";SI(B13<=46,86;"17";SI(B13<=49,05;"18";SI(B13<=51,34;"19";SI(B13<=52,53;"20")))))))))))))))))))))))))))))))))))))

 

[vbacrumble]

Re : fonction si

Bonsoir



Essayes d'adapter cette formule

=SI(OU(A1="";A1=0);0;INDEX({1;2;3;4;5;6;7;8;9;10;11;12;13;14;15;16;17;18;19;20};A1;1))

A+

 

[Cousinhub]

Re : fonction si

Bonsoir,

essaie avec cette formule :

=INDEX({0;1;2;3;4;5;6;7;8;9;10;11;12;13;14;15;16;17;18;19;20};EQUIV(B13;{0;21;22,5;23,63;24,73;25,89;27,09;28,36;29,68;31,07;32,52;34,04;35,63;37,3;39,04;40,86;42,77;44,77;46,86;49,05;51,34;52,53};1))

en supposant que 53,53 est la note maximum, sinon, remplace 52,53 par la note max.....

 

[kjin]

Re : fonction si

Bonsoir,
Avec un tableau intermédiaire permettant de modifier les valeurs de comparaison sans modifier les formules
A+
kjin

 

[Gael]

Re : fonction si

Bonjour à tous,

Même solution que bhbh mais sans la fonction index qui n'est pas utile ici puisque Equiv donne directement le n° de l'intervalle soit:

=EQUIV(B13;{0;21;22,5;23,63;24,73;25,89;27,09;28,36;29,68;31,07;32,52;34,04;35,63;37,3;39,04;40,86;42,77;44,77;46,86;49,05;51,34;52,53};1)-1

Si l'on a un tableau intermédiaire comme l'a proposé Kjin, on peut écrire simplement:

=EQUIV(B13;Val;1)

@+

Gael