Fonction SI imbriquée avec OU <>

[Pixakilla]

Bonjour,

Pourriez-vous m'aider à faire fonctionner une formule sous excel2003 XP.

En K9 le résultat est donné:

-Si dans les 3 tests le numéro de série n'est pas trouvé: "voir produit"
-Si les résultats des 3 tests est "OK": "OK selon les tests"

Le reste des passibilités est qu'il y ait un ou plusieurs des tests qui ont échoués.

Je voudrais faire la distinction entre un échec du test "TT" en H9 et celui d'un test "MT" (avec ou non un échec du test "SMT") ou encore de l'échec du seul test "SMT")

Voila la formule qui fonctionne en K9 mais qui ne fait pas la distinction entre l'echec ou les echecs des différents tests.

=SI(ESTVIDE(A9);"";SI(ET(H9="**SN not in TT**";F9="**SN not in MT**";D9="**SN not in SMT**");"See adhesive on the product";SI(ET(H9="OK",F9="OK",D9="OK");"No failure according to tests";"one or several tests failed")))

Voici ce que je n'arrive pas à mettre à la place de "one or several tests failed":

SI(OU(H9<>"**SN not in TT**";H9<>"OK");"TT failed";SI(OU(F9<>"**SN not in MT**";F9<>"OK");"MT failed",SI(OU(D9<>"**SN not in SMT**";D9<>"OK");"SMT failed")))

Merci d'avance.

 

[Samantha]

Re : Fonction SI imbriquée avec OU <>

Bonjour,

Essayes ça :

=SI(ESTVIDE(A9);"";SI(ET(H9="**SN not in TT**";F9="**SN not in MT**";D9="**SN not in SMT**");"See adhesive on the product";SI(ET(H9="OK";F9="OK";D9="OK");"No failure according to tests";SI(OU(H9<>"**SN not in TT**";H9<>"OK");"TT failed";SI(OU(F9<>"**SN not in MT**";F9<>"OK");"MT failed";SI(OU(D9<>"**SN not in SMT**";D9<>"OK");"SMT failed"))))))

Chez moi ça donne "TT failed" il y avait une virgule à la place du ";" quelquepart 😉

A te lire


Sam

 

[abc]

Re : Fonction SI imbriquée avec OU <>

Bonsoir Samantha
je pense que la question n'est pas la.
Sa formule fonctionne,mais elle demande
=si(ou(h9<>"...".h9<>".....".Si(ou( f9<>"...";F9<>"...." qui à mon avis,demande trop de conditions.
Pourquoi faire facile lorsque l'on peut faire compliqué
A+

 

[Pixakilla]

Re : Fonction SI imbriquée avec OU <>

Merci pour ta réponse Samantha,

mais j'avais déja tenté en K9:

=SI(ESTVIDE(A9);"";SI(ET(H9="**SN not in TT**";F9="**SN not in MT**";D9="**SN not in SMT**");"See adhesive on the product";SI(ET(H9="OK";F9="OK";D9="OK");"No failure according to tests";SI(OU(H9<>"**SN not in TT**";H9<>"OK");"TT failed";SI(OU(F9<>"**SN not in MT**";F9<>"OK");"MT failed";SI(OU(D9<>"**SN not in SMT**";D9<>"OK");"SMT failed"))))))

malheureusement la réponse pour n'importe quelle condition qui ne satisfait pas les 3 premiers SI, la réponse est "TT failed", même si cela devrait plutôt être un "MT failed" en K12.

Salut abc,

Je ne crois pas que ce soit la multitude des SI imbriqués qui constitue le problème; car même en proposant une colonne séparée qui déterminerait le test incriminé, il n'y a malheureusement que la valeur si vrai du premier SI qui est reportée en résultat ("TT failed" dans ce cas si).

Merci pour vos propositions

 

[abc]

Re : Fonction SI imbriquée avec OU <>

Bonsoir,
merci de me répondre,cela fait plus de deux heures que je retourne ta formule.
il ya peut être une solution,mais la je bloque.
Il y a tellement de possibilité H9= si f9= ou h9.....etc
A+

 

[Pixakilla]

Re : Fonction SI imbriquée avec OU <>

Croyant que ce soit un problème de hiérarchie, j'ai tenté l'inversion des 3 SI concernant l'identification du test non réussi: sans succès.
J'ai aussi tenté d'utiliser la formule ...OU(NOT(H9="**SN not in TT**");NOT(H9="OK")) à la place de ...OU(H9<>"**SN not in TT**";H9<>"OK"), mais ça ne fonctionne pas mieux.

 

[abc]

Re : Fonction SI imbriquée avec OU <>

Bonjour,
essaie un peu,j'ai mis des mots érroné car anglais me trouble.
La formule est en K5
A +

 

[Pixakilla]

Re : Fonction SI imbriquée avec OU <>

Bonjour abc,

Merci pour ta proposition, je l'ai adaptée et j'obtiens un meilleur degrès de précision.
Malheureusement je ne peux qu'éliminer (du fait des 2 conditions d'égalité au lieux des 2 de négation) un des tests de l'équation et pas pointer le test incriminé selon une hiérarchie prédéfinie.

Formule en K9:

=IF(ISBLANK(A9),"",IF(AND(H9="**SN not in TT**",F9="**SN not in MT**",D9="**SN not in SMT**"),"See adhesive on the product",IF(AND(H9="OK",F9="OK",D9="OK"),"No failure according to tests",IF(OR(H9={"**SN not in TT**","OK"}),"MT or SMT failed",IF(OR(F9={"**SN not in MT**","OK"}),"TT or SMT failed",IF(OR(D9={"**SN not in SMT**","OK"}),"MT or SMT failed","All tests failed"))))))

Pour obtenir encore un meilleur degrès de précision j'ai du (peut-être les limites d'Excel aurait été atteintes 😕 ) rajouter 3 autres colonnes relatives à la réussite ou non des tests effectués.😱

Merci abc

 

[abc]

Re : Fonction SI imbriquée avec OU <>

Bonsoir,
effectivement,j'en était arrivé à la même conclusion que toi.
Donc de rajouter 3 colonnes supplémentaire et de partir de la.
A +

 

[abc]

Re : Fonction SI imbriquée avec OU <>

Bonsoir,
un petit coup de pouce serait le bien venu.
La déese des formules pourrait elle jeter un coup d'oeil.
Je cela ne se fait pas mais ......
Pour ma satisfaction personnel.
Voir le fil
Merci
A +

 

[Gael]

Re : Fonction SI imbriquée avec OU <>

Bonjour Pixakilla, Samantha, Abc,

Peut-être avec la formule suivante:

=SI(ET(H9<>"**SN not in TT**";H9<>"OK");"TT failed";SI(ET(F9<>"**SN not in MT**";F9<>"OK");"MT failed";SI(ET(D9<>"**SN not in SMT**";D9<>"OK");"SMT failed";"Tests OK")))

j'ai remplacé les "OU" par des "ET" sinon la première condition est toujours vrai puisque H9 sera toujours différents de l'une ou l'autre valeur et j'ai rajouté "Tests OK" si aucune des conditions "failed" n'est rencontrée.

@+

Gael

Pixakilla, dans ta formule précédente "que tu avais déjà tenté en K9", Si tu remplaces les "OU" par des "ET", cela devrait marcher.

Gael

 

[Pixakilla]

Fonction SI imbriqués avec OU et ET <>

Merci Gael, abc

je viens de tester et cela marche. 🙂

La hiérarchie peut même être modifiée. Les 3 colonnes résumant la situation ne devrait plus être nécessaires (si l'issue d'un test réussi après l'échec d'un autre importe peut).😉

Bon week-end à tous.

Greetings from Belgium