Find ,Methode et Plage MultiCellules

ChTi160 · 5 Juin 2005

bonjour le Forum
par ce Dimanche pas très Clair
une Question qui j'espère le sera(Claire) Lol
j'ai eu à rechercher dans une plage (Range('A2:B10'))

une valeur qui est la Concaténation de Deux valeurs Toto &' '& Tutu.
au lieu d'utiliser la boucle for each cellule en colonne A if Cellule ='Toto'and Cellule.Offset(0,1)='Tutu' then ListBox1.....Etc
j'ai pensé utilisé la méthode Find
exemple
maplage=Range('A2:B10')
maVar= Toto&' '&Tutu
rep=maplage.Find(maVar) sachant que A3=Toto et B3=Tutu

pensez vous que celà soit possible ?
et si Oui Comment (biensûr) Lol

Merci d'avance

Message édité par: chti160, à: 05/06/2005 16:32

Robert · 5 Juin 2005

Bonsoir Jean Marie, bonsoir le forum,

Cette macro devrait t'aider :

Sub Macro1()
Dim maplage As Range 'déclare la variable maplage
Dim maVar As String 'décalre la variable maVar
Dim c As Range 'déclare la variable c
Set maplage = Range('A2:B10') 'définit la variable maplage
maVar = 'Toto' & ' ' & 'Tutu' 'définit la variable maVar
With maplage
Set c = .Find(maVar, , xlValues) 'définit la variable c (recherche maVar dans les valeurs de la plage)
If Not c Is Nothing Then 'si il existe au moins une occurence
c.Select 'sélectionne la cellule (place ici ton code)
End If
End With
End Sub

ChTi160 · 6 Juin 2005

Salut Robert
Bonjour le Forum

je te remercie pour l’intérêt que tu as porté à ma Question mais la l’aide que tu m’as apportée ne me permet pas d’arriver à ce que je voulais
si je recherche dans maplage
la Concaténation des deux Variables rien, car je ne sais pas si la recherche peut se faire sur une plage Multiple ici 2 cellules Contiguës contenants pour la première
Toto et pour la deuxième tutu
j’ai donc essayé de faire

Code:

With Worksheets ('Feuil1')
Set maplage = .Range ('A2:A10') 'définit la variable maplage 
maVar = 'Toto'  '& Tutu 'définit la variable maVar
maVar2 = 'Tutu''définit la variable maVar2
End With
With maplage
Set c = .Find (maVar, , xlValues) 'définit la variable c (recherche maVar dans les valeurs de la plage)
If Not c Is Nothing And c.Offset (0, 1) = maVar2 Then   'si il existe au moins une occurrence
  
 FirstAddress = c.Address
        Do
     MsgBox maVar & ' ' & maVar2 & ' Ligne' & c.Row 'Affichage
            Set c = .FindNext(c)
        Loop While Not c Is Nothing And c.Address <> FirstAddress
 
 End If

End With

mais si il y a Toto et quelque chose qui n’est pas Tutu la macro ne retourne rien si le premier Toto et associé à Tutu alors là la macro me renvoie les différentes Occurrences
je tente de chercher sur le Net mais rien
Merci encore
Bonne Journée

Robert · 6 Juin 2005

Bonjour Jean Marie, bonjour le forum,

Je t'avoue que je ne comprends pas très bien. Ce qui me gêne c'est la plage de la recherche A2:B10 dans laquelle tu recherche une concaténation de A et B ???
Je te propose cette nouvelle macro en aveugle en espérant qu'elle te convienne ou te permete d'arriver à tes fins.

Sub Macro1()
Dim maplage As Range 'déclare la variable maplage
Dim maVar1 As String 'décalre la variable maVar1
Dim maVar2 As String 'déclare la variable maVar2
Dim c1 As Range 'déclare la variable c1
Dim c2 As Range 'déclare la variable c2
Set maplage = Range('A2:B10') 'définit la variable maplage
maVar1 = 'Toto'
With maplage
Set c1 = .Find(maVar1, , xlValues) 'définit la variable c (recherche maVar1 dans les valeurs de la plage)
If Not c1 Is Nothing Then 'si il existe au moins une occurence
maVar2 = maVar1 & ' ' & c1.Offset(0, 1).Value
Set c2 = .Find(maVar2, , xlValues) 'définit la variable c2 (recherche maVar2 dans les valeurs de la plage)
If Not c2 Is Nothing Then
c2.Select
End If
End If
End With
End Sub

ChTi160 · 6 Juin 2005

re Robert
bon je ne voudrais pas de perturber en début de semaine lol c'est pas bon
donc je tente de t'expliquer
j'essaye d'approvisionner une listeBox d'après deux critères
dans un combobox je sélectionne un nom et la recherche se lance
colonne 1 de ma Combobox nom colonne 2 de ma Combobox La Date
j'obtiens maVar= CmbB.columns(1,cmbB.ListIndex)&''&CmbB.Columns(2,CmbB.ListIndex) en simplifié Lol
ex le nom(qui se trouve en colonne A de ma plage'A2:B10' et le mois de la date qui se trouve dans la colonne B de ma

plage 'A2:B10' soit si j'ai nom & '' & moisDate je remplie les colonnes de ma listbox avec les données de la ligne ou se trouvent à la fois en A nom et en B moisDate sur la m^eme ligne je pensais augmenter la rapidité en passant par la méthode Find plutôt que de passer en revue des centaines de lignes et ainsi aller à l'essentiel QUOI Lol Mais bon
je regarde ta nouvelle Macro
Encore Merci

Message édité par: Chti160, à: 06/06/2005 11:19

michel_m · 6 Juin 2005

Salut Jean Marie, Robert

Si j’ai piger ton pb, chose exceptionnelle un Lundi

La fonction Find fonctionne sur une cellule or tes 2 variables accupent chacune une cellule

Tu pourrais essayer avec 2 fonctions find

Toto=ton combo colonne1
Tata= toncombocolonne2

Find commence à chercher APRES la première cellule

On error resume next
LigA=columns(1).find(toto,range(“A1”),,,xlbyrows).row
LigB=columns(2).find(tata,range(“B1”),,,xlbyrows).row
If error>0 then
Msgbox “ inconnu”
Exit sub
End if
IF ligA<>ligb then
Msgbox “ personne”
Else
Tes instructions
End if

Syntaxe « error » à vérifier

A+

Michel (at work)

ChTi160 · 6 Juin 2005

Salut michel
Content de te rencontrer Bravo encore pour tes Apports au Forum (concernant un domaine que je ne maîtrise pas, mais très instructif)
bon pour mon problème j’ai essayé cette possibilité mais y a un problème de coordination entre les deux méthodes Find
quand Find « Toto » est true en colonne A ligne 2 et que Find Tutu est bon en colonne 5 donc pas sur la même ligne ça Fonctionne pas même si en colonne A ligne 5, j’ai Toto
Enfin je vais regarder ce que tu m’as proposé et je ne manque pas d’informer le Fil
Merci encore

myDearFriend! · 6 Juin 2005

Bonsoir Chti160, Robert, michel_m,

Jean-Marie, tu y étais presque à mon avis, j'ai repris ta dernière proposition et j'ai fait ceci qui semble fonctionner :

Sub Traitement()
Dim maplage As Range, C As Range
Dim maVar As String, maVar2 As String, FirstAddress As String
      With Worksheets('Feuil1')
            Set maplage = .Range('A2:A50000')   'définit la variable maplage
            maVar = 'toto'
            maVar2 = 'tutu'
      End With
      With maplage
            Set C = .Find(maVar, , xlValues)   'définit la variable c (recherche maVar dans la plage)
            If Not C Is Nothing Then        'si il existe au moins une occurrence

                  FirstAddress = C.Address
                  Do
                        If C.Offset(0, 1) = maVar2 Then
                              MsgBox maVar & ' ' & maVar2 & ' Ligne' & C.Row 'Affichage
                        End If
                        Set C = .FindNext(C)
                  Loop While Not C Is Nothing And C.Address <> FirstAddress

            End If
      End With
End Sub

Cela dit, j'ai essayé aussi d'une autre façon qui, après test sur 50000 lignes (en supprimant le msgbox bloquant pour les 2), est 20 fois plus rapide car travaillant directement sur un tableau variant (et non sur les ranges de la feuille) :

Sub Traitement2()
Dim TabTemp As Variant
Dim L As Long
Dim maVar As String, maVar2 As String
With Worksheets('Feuil1')
      maVar = 'toto'
      maVar2 = 'tutu'
      L = .Range('A65536').End(xlUp).Row
      TabTemp = .Range(.Cells(1, 1), .Cells(L, 2)).Value
      For L = 1 To UBound(TabTemp, 1)
            If TabTemp(L, 1) & ' ' & TabTemp(L, 2) = maVar & ' ' & maVar2 Then
                  MsgBox maVar & ' ' & maVar2 & ' Ligne' & L        'Affichage
            End If
      Next L
End With
End Sub

En espérant que cela puisse t'aider...

Cordialement,

ChTi160 · 7 Juin 2005

Salut Didier
Je pense que tu as répondu à mon attente et dès demain je fais des essais
(Je n'ai pas encore testé) mais je te connais, jamais au Hasard lol
je n'ai pas malgré tes Leçons, essayé les tableaux alors que ce soir dans un autre domaine je l'ai fait, Arf:: y a tellement de chose à disposition que je ne sais plus lol
Merci encore pour ton aide et ton enseignement
Bonne Journée et à bientôt

Find ,Methode et Plage MultiCellules

ChTi160

XLDnaute Barbatruc

Robert

XLDnaute Barbatruc

ChTi160

XLDnaute Barbatruc

Robert

XLDnaute Barbatruc

ChTi160

XLDnaute Barbatruc

michel_m

Guest

ChTi160

XLDnaute Barbatruc

myDearFriend!

XLDnaute Barbatruc

ChTi160

XLDnaute Barbatruc